config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  27         ZFS_AC_KERNEL_BIO_RW_BARRIER
  28         ZFS_AC_KERNEL_BIO_RW_DISCARD
  29         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  31         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  32         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  33         ZFS_AC_KERNEL_GET_DISK_RO
  34         ZFS_AC_KERNEL_GET_GENDISK
  35         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  36         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  37         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  38         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  39         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  40         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  41         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  42         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  43         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  44         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  45         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  46         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  47         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  48         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  49         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  50         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  51         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  52         ZFS_AC_KERNEL_CURRENT_UMASK
  53         ZFS_AC_KERNEL_SHOW_OPTIONS
  54         ZFS_AC_KERNEL_FILE_INODE
  55         ZFS_AC_KERNEL_FSYNC
  56         ZFS_AC_KERNEL_EVICT_INODE
  57         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  58         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  59         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  60         ZFS_AC_KERNEL_FALLOCATE
  61         ZFS_AC_KERNEL_MKDIR_UMODE_T
  62         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  63         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  64         ZFS_AC_KERNEL_GET_LINK
  65         ZFS_AC_KERNEL_PUT_LINK
  66         ZFS_AC_KERNEL_TRUNCATE_RANGE
  67         ZFS_AC_KERNEL_AUTOMOUNT
  68         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  69         ZFS_AC_KERNEL_COMMIT_METADATA
  70         ZFS_AC_KERNEL_CLEAR_INODE
  71         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  72         ZFS_AC_KERNEL_D_MAKE_ROOT
  73         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  74         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  75         ZFS_AC_KERNEL_D_SET_D_OP
  76         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  77         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  78         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  79         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  80         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  81         ZFS_AC_KERNEL_MOUNT_NODEV
  82         ZFS_AC_KERNEL_SHRINK
  83         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  84         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  85         ZFS_AC_KERNEL_S_D_OP
  86         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  87         ZFS_AC_KERNEL_SET_NLINK
  88         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  89         ZFS_AC_KERNEL_5ARG_SGET
  90         ZFS_AC_KERNEL_LSEEK_EXECUTE
  91         ZFS_AC_KERNEL_VFS_ITERATE
  92         ZFS_AC_KERNEL_VFS_RW_ITERATE
  93         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  94         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
  95         ZFS_AC_KERNEL_MAKE_REQUEST_FN
  96         ZFS_AC_KERNEL_GENERIC_IO_ACCT
  97         ZFS_AC_KERNEL_FPU
  98         ZFS_AC_KERNEL_KUID_HELPERS
  99
 100         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 101                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 102         ])
 103         AC_SUBST(KERNELMAKE_PARAMS)
 104
 105
 106         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 107         dnl # compiler options are added by the kernel build system.
 108         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 109         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 110         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 111         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 112
 113         AC_SUBST(KERNELCPPFLAGS)
 114 ])
 115
 116 dnl #
 117 dnl # Detect name used for Module.symvers file in kernel
 118 dnl #
 119 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 120         modpost=$LINUX/scripts/Makefile.modpost
 121         AC_MSG_CHECKING([kernel file name for module symbols])
 122         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 123                 AS_IF([grep -q Modules.symvers $modpost], [
 124                         LINUX_SYMBOLS=Modules.symvers
 125                 ], [
 126                         LINUX_SYMBOLS=Module.symvers
 127                 ])
 128
 129                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 130                         AC_MSG_ERROR([
 131         *** Please make sure the kernel devel package for your distribution
 132         *** is installed.  If you are building with a custom kernel, make sure the
 133         *** kernel is configured, built, and the '--with-linux=PATH' configure
 134         *** option refers to the location of the kernel source.])
 135                 ])
 136         ], [
 137                 LINUX_SYMBOLS=NONE
 138         ])
 139         AC_MSG_RESULT($LINUX_SYMBOLS)
 140         AC_SUBST(LINUX_SYMBOLS)
 141 ])
 142
 143 dnl #
 144 dnl # Detect the kernel to be built against
 145 dnl #
 146 AC_DEFUN([ZFS_AC_KERNEL], [
 147         AC_ARG_WITH([linux],
 148                 AS_HELP_STRING([--with-linux=PATH],
 149                 [Path to kernel source]),
 150                 [kernelsrc="$withval"])
 151
 152         AC_ARG_WITH(linux-obj,
 153                 AS_HELP_STRING([--with-linux-obj=PATH],
 154                 [Path to kernel build objects]),
 155                 [kernelbuild="$withval"])
 156
 157         AC_MSG_CHECKING([kernel source directory])
 158         AS_IF([test -z "$kernelsrc"], [
 159                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 160                         headersdir="/lib/modules/$(uname -r)/source"
 161                         sourcelink=$(readlink -f "$headersdir")
 162                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 163                         headersdir="/lib/modules/$(uname -r)/build"
 164                         sourcelink=$(readlink -f "$headersdir")
 165                 ], [
 166                         sourcelink=$(ls -1d /usr/src/kernels/* \
 167                                      /usr/src/linux-* \
 168                                      2>/dev/null | grep -v obj | tail -1)
 169                 ])
 170
 171                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 172                         kernelsrc=`readlink -f ${sourcelink}`
 173                 ], [
 174                         kernelsrc="[Not found]"
 175                 ])
 176         ], [
 177                 AS_IF([test "$kernelsrc" = "NONE"], [
 178                         kernsrcver=NONE
 179                 ])
 180         ])
 181
 182         AC_MSG_RESULT([$kernelsrc])
 183         AS_IF([test ! -d "$kernelsrc"], [
 184                 AC_MSG_ERROR([
 185         *** Please make sure the kernel devel package for your distribution
 186         *** is installed and then try again.  If that fails, you can specify the
 187         *** location of the kernel source with the '--with-linux=PATH' option.])
 188         ])
 189
 190         AC_MSG_CHECKING([kernel build directory])
 191         AS_IF([test -z "$kernelbuild"], [
 192                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 193                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 194                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 195                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 196                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 197                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 198                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 199                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 200                 ], [
 201                         kernelbuild=${kernelsrc}
 202                 ])
 203         ])
 204         AC_MSG_RESULT([$kernelbuild])
 205
 206         AC_MSG_CHECKING([kernel source version])
 207         utsrelease1=$kernelbuild/include/linux/version.h
 208         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 209         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 210         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 211                 utsrelease=linux/version.h
 212         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 213                 utsrelease=linux/utsrelease.h
 214         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 215                 utsrelease=generated/utsrelease.h
 216         ])
 217
 218         AS_IF([test "$utsrelease"], [
 219                 kernsrcver=`(echo "#include <$utsrelease>";
 220                              echo "kernsrcver=UTS_RELEASE") |
 221                              cpp -I $kernelbuild/include |
 222                              grep "^kernsrcver=" | cut -d \" -f 2`
 223
 224                 AS_IF([test -z "$kernsrcver"], [
 225                         AC_MSG_RESULT([Not found])
 226                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 227                 ])
 228         ], [
 229                 AC_MSG_RESULT([Not found])
 230                 if test "x$enable_linux_builtin" != xyes; then
 231                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 232                 else
 233                         AC_MSG_ERROR([
 234         *** Cannot find UTS_RELEASE definition.
 235         *** Please run 'make prepare' inside the kernel source tree.])
 236                 fi
 237         ])
 238
 239         AC_MSG_RESULT([$kernsrcver])
 240
 241         LINUX=${kernelsrc}
 242         LINUX_OBJ=${kernelbuild}
 243         LINUX_VERSION=${kernsrcver}
 244
 245         AC_SUBST(LINUX)
 246         AC_SUBST(LINUX_OBJ)
 247         AC_SUBST(LINUX_VERSION)
 248
 249         ZFS_AC_MODULE_SYMVERS
 250 ])
 251
 252
 253 dnl #
 254 dnl # Detect the SPL module to be built against
 255 dnl #
 256 AC_DEFUN([ZFS_AC_SPL], [
 257         AC_ARG_WITH([spl],
 258                 AS_HELP_STRING([--with-spl=PATH],
 259                 [Path to spl source]),
 260                 AS_IF([test "$withval" = "yes"],
 261                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 262                         [splsrc="$withval"]))
 263
 264         AC_ARG_WITH([spl-obj],
 265                 AS_HELP_STRING([--with-spl-obj=PATH],
 266                 [Path to spl build objects]),
 267                 [splbuild="$withval"])
 268
 269         AC_ARG_WITH([spl-timeout],
 270                 AS_HELP_STRING([--with-spl-timeout=SECS],
 271                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 272                 [timeout="$withval"], [timeout=0])
 273
 274         dnl #
 275         dnl # The existence of spl.release.in is used to identify a valid
 276         dnl # source directory.  In order of preference:
 277         dnl #
 278         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 279         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 280         splsrc2="/usr/local/src/spl-${VERSION}"
 281         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 282         splsrc4="/usr/src/spl-${VERSION}"
 283         splsrc5="../spl/"
 284         splsrc6="$LINUX"
 285
 286         AC_MSG_CHECKING([spl source directory])
 287         AS_IF([test -z "${splsrc}"], [
 288                 [all_spl_sources="
 289                 ${splsrc0}
 290                 ${splsrc1}
 291                 ${splsrc2}
 292                 ${splsrc3}
 293                 ${splsrc4}
 294                 ${splsrc5}
 295                 ${splsrc6}"],
 296                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 297                         splsrc=${splsrc0}
 298                 ], [ test -e "${splsrc1}/spl.release.in"], [
 299                         splsrc=${splsrc1}
 300                 ], [ test -e "${splsrc2}/spl.release.in"], [
 301                         splsrc=${splsrc2}
 302                 ], [ test -e "${splsrc3}/spl.release.in"], [
 303                         splsrc=$(readlink -f "${splsrc3}")
 304                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 305                         splsrc=${splsrc4}
 306                 ], [ test -e "${splsrc5}/spl.release.in"], [
 307                         splsrc=$(readlink -f "${splsrc5}")
 308                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 309                         splsrc=${splsrc6}
 310                 ], [
 311                         splsrc="[Not found]"
 312                 ])
 313         ], [
 314                 [all_spl_sources="$withval"],
 315                 AS_IF([test "$splsrc" = "NONE"], [
 316                         splbuild=NONE
 317                         splsrcver=NONE
 318                 ])
 319         ])
 320
 321         AC_MSG_RESULT([$splsrc])
 322         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 323                 AC_MSG_ERROR([
 324         *** Please make sure the kmod spl devel package for your distribution
 325         *** is installed then try again.  If that fails you can specify the
 326         *** location of the spl source with the '--with-spl=PATH' option.
 327         *** The spl version must match the version of ZFS you are building,
 328         *** ${VERSION}.  Failed to find spl.release.in in the following:
 329         $all_spl_sources])
 330         ])
 331
 332         dnl #
 333         dnl # The existence of the spl_config.h is used to identify a valid
 334         dnl # spl object directory.  In many cases the object and source
 335         dnl # directory are the same, however the objects may also reside
 336         dnl # is a subdirectory named after the kernel version.
 337         dnl #
 338         dnl # This file is supposed to be available after DKMS finishes
 339         dnl # building the SPL kernel module for the target kernel.  The
 340         dnl # '--with-spl-timeout' option can be passed to pause here,
 341         dnl # waiting for the file to appear from a concurrently building
 342         dnl # SPL package.
 343         dnl #
 344         AC_MSG_CHECKING([spl build directory])
 345
 346         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 347         ${splsrc}"
 348
 349         while true; do
 350                 AS_IF([test -z "$splbuild"], [
 351                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 352                                 splbuild="${splsrc}/${LINUX_VERSION}"
 353                         ], [ test -e "${splsrc}/spl_config.h" ], [
 354                                 splbuild="${splsrc}"
 355                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 356                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 357                         ], [
 358                                 splbuild="[Not found]"
 359                         ])
 360                 ])
 361                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 362                         break;
 363                 ], [
 364                         sleep 1
 365                         timeout=$((timeout-1))
 366                 ])
 367         done
 368
 369         AC_MSG_RESULT([$splbuild])
 370         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 371                 AC_MSG_ERROR([
 372         *** Please make sure the kmod spl devel <kernel> package for your
 373         *** distribution is installed then try again.  If that fails you
 374         *** can specify the location of the spl objects with the
 375         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 376         *** any of the following:
 377         $all_spl_config_locs])
 378         ])
 379
 380         AC_MSG_CHECKING([spl source version])
 381         AS_IF([test -r $splbuild/spl_config.h &&
 382                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 383
 384                 splsrcver=`(echo "#include <spl_config.h>";
 385                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 386                             cpp -I $splbuild |
 387                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 388         ])
 389
 390         AS_IF([test -z "$splsrcver"], [
 391                 AC_MSG_RESULT([Not found])
 392                 AC_MSG_ERROR([
 393         *** Cannot determine the version of the spl source.
 394         *** Please prepare the spl source before running this script])
 395         ])
 396
 397         AC_MSG_RESULT([$splsrcver])
 398
 399         SPL=${splsrc}
 400         SPL_OBJ=${splbuild}
 401         SPL_VERSION=${splsrcver}
 402
 403         AC_SUBST(SPL)
 404         AC_SUBST(SPL_OBJ)
 405         AC_SUBST(SPL_VERSION)
 406
 407         dnl #
 408         dnl # Detect the name used for the SPL Module.symvers file.  If one
 409         dnl # does not exist this is likely because the SPL has been configured
 410         dnl # but not built.  The '--with-spl-timeout' option can be passed
 411         dnl # to pause here, waiting for the file to appear from a concurrently
 412         dnl # building SPL package.  If the file does not appear in time, a good
 413         dnl # guess is made as to what this file will be named based on what it
 414         dnl # is named in the kernel build products.  This file will first be
 415         dnl # used at link time so if the guess is wrong the build will fail
 416         dnl # then.  This unfortunately means the ZFS package does not contain a
 417         dnl # reliable mechanism to detect symbols exported by the SPL at
 418         dnl # configure time.
 419         dnl #
 420         AC_MSG_CHECKING([spl file name for module symbols])
 421         SPL_SYMBOLS=NONE
 422
 423         while true; do
 424                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 425                         SPL_SYMBOLS=Module.symvers
 426                 ], [test -r $SPL_OBJ/Modules.symvers], [
 427                         SPL_SYMBOLS=Modules.symvers
 428                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 429                         SPL_SYMBOLS=Module.symvers
 430                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 431                         SPL_SYMBOLS=Modules.symvers
 432                 ])
 433
 434                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 435                         break;
 436                 ], [
 437                         sleep 1
 438                         timeout=$((timeout-1))
 439                 ])
 440         done
 441
 442         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 443                 SPL_SYMBOLS=$LINUX_SYMBOLS
 444         ])
 445
 446         AC_MSG_RESULT([$SPL_SYMBOLS])
 447         AC_SUBST(SPL_SYMBOLS)
 448 ])
 449
 450 dnl #
 451 dnl # Basic toolchain sanity check.
 452 dnl #
 453 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 454         AC_MSG_CHECKING([whether modules can be built])
 455         ZFS_LINUX_TRY_COMPILE([],[],[
 456                 AC_MSG_RESULT([yes])
 457         ],[
 458                 AC_MSG_RESULT([no])
 459                 if test "x$enable_linux_builtin" != xyes; then
 460                         AC_MSG_ERROR([*** Unable to build an empty module.])
 461                 else
 462                         AC_MSG_ERROR([
 463         *** Unable to build an empty module.
 464         *** Please run 'make scripts' inside the kernel source tree.])
 465                 fi
 466         ])
 467 ])
 468
 469 dnl #
 470 dnl # Certain kernel build options are not supported.  These must be
 471 dnl # detected at configure time and cause a build failure.  Otherwise
 472 dnl # modules may be successfully built that behave incorrectly.
 473 dnl #
 474 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 475         AS_IF([test "x$cross_compiling" != xyes], [
 476                 AC_RUN_IFELSE([
 477                         AC_LANG_PROGRAM([
 478                                 #include "$LINUX/include/linux/license.h"
 479                         ], [
 480                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 481                         ])
 482                 ], [
 483                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 484                             [Define to 1 if GPL-only symbols can be used])
 485                 ], [
 486                 ])
 487         ])
 488
 489         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 490         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 491 ])
 492
 493 dnl #
 494 dnl # Check configured THREAD_SIZE
 495 dnl #
 496 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 497 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 498 dnl # on newer kernels and some architectures stack usage optimizations can be
 499 dnl # conditionally applied to improve performance without negatively impacting
 500 dnl # stability.
 501 dnl #
 502 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 503         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 504         ZFS_LINUX_TRY_COMPILE([
 505                 #include <linux/module.h>
 506         ],[
 507                 #if (THREAD_SIZE < 16384)
 508                 #error "THREAD_SIZE is less than 16K"
 509                 #endif
 510         ],[
 511                 AC_MSG_RESULT([yes])
 512                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 513         ],[
 514                 AC_MSG_RESULT([no])
 515         ])
 516 ])
 517
 518 dnl #
 519 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 520 dnl #
 521 dnl # This is typically only set for debug kernels because it comes with
 522 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 523 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 524 dnl # This will cause a failure at link time which we'd rather know about
 525 dnl # at compile time.
 526 dnl #
 527 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 528 dnl # with the upstream community we add a check to detect this case.
 529 dnl #
 530 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 531
 532         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 533                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 534                 tmp_flags="$EXTRA_KCFLAGS"
 535                 ZFS_LINUX_TRY_COMPILE([
 536                         #include <linux/module.h>
 537                         #include <linux/mutex.h>
 538
 539                         MODULE_LICENSE("$ZFS_META_LICENSE");
 540                 ],[
 541                         struct mutex lock;
 542
 543                         mutex_init(&lock);
 544                         mutex_lock(&lock);
 545                         mutex_unlock(&lock);
 546                 ],[
 547                         AC_MSG_RESULT(no)
 548                 ],[
 549                         AC_MSG_RESULT(yes)
 550                         AC_MSG_ERROR([
 551         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 552         *** with the CDDL license and will prevent the module linking stage
 553         *** from succeeding.  You must rebuild your kernel without this
 554         *** option enabled.])
 555                 ])
 556                 EXTRA_KCFLAGS="$tmp_flags"
 557         ], [])
 558 ])
 559
 560 dnl #
 561 dnl # ZFS_LINUX_CONFTEST_H
 562 dnl #
 563 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 564 cat - <<_ACEOF >conftest.h
 565 $1
 566 _ACEOF
 567 ])
 568
 569 dnl #
 570 dnl # ZFS_LINUX_CONFTEST_C
 571 dnl #
 572 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 573 cat confdefs.h - <<_ACEOF >conftest.c
 574 $1
 575 _ACEOF
 576 ])
 577
 578 dnl #
 579 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 580 dnl #
 581 m4_define([ZFS_LANG_PROGRAM], [
 582 $1
 583 int
 584 main (void)
 585 {
 586 dnl Do *not* indent the following line: there may be CPP directives.
 587 dnl Don't move the `;' right after for the same reason.
 588 $2
 589   ;
 590   return 0;
 591 }
 592 ])
 593
 594 dnl #
 595 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 596 dnl #
 597 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 598         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 599         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 600         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 601         echo "obj-m := conftest.o" >build/Makefile
 602         modpost_flag=''
 603         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 604         AS_IF(
 605                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 606                 [$4],
 607                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 608         )
 609         rm -Rf build
 610 ])
 611
 612 dnl #
 613 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 614 dnl #
 615 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 616         [ZFS_LINUX_COMPILE_IFELSE(
 617         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 618         [modules],
 619         [test -s build/conftest.o],
 620         [$3], [$4])
 621 ])
 622
 623 dnl #
 624 dnl # ZFS_LINUX_CONFIG
 625 dnl #
 626 AC_DEFUN([ZFS_LINUX_CONFIG],
 627         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 628         ZFS_LINUX_TRY_COMPILE([
 629                 #include <linux/module.h>
 630         ],[
 631                 #ifndef CONFIG_$1
 632                 #error CONFIG_$1 not #defined
 633                 #endif
 634         ],[
 635                 AC_MSG_RESULT([yes])
 636                 $2
 637         ],[
 638                 AC_MSG_RESULT([no])
 639                 $3
 640         ])
 641 ])
 642
 643 dnl #
 644 dnl # ZFS_CHECK_SYMBOL_EXPORT
 645 dnl # check symbol exported or not
 646 dnl #
 647 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 648         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 649                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 650         rc=$?
 651         if test $rc -ne 0; then
 652                 export=0
 653                 for file in $2; do
 654                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 655                                 "$LINUX/$file" 2>/dev/null
 656                         rc=$?
 657                         if test $rc -eq 0; then
 658                                 export=1
 659                                 break;
 660                         fi
 661                 done
 662                 if test $export -eq 0; then :
 663                         $4
 664                 else :
 665                         $3
 666                 fi
 667         else :
 668                 $3
 669         fi
 670 ])
 671
 672 dnl #
 673 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 674 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 675 dnl # is called if not compiling for builtin
 676 dnl #
 677 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 678         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 679         if test $rc -ne 0; then :
 680                 $6
 681         else
 682                 if test "x$enable_linux_builtin" != xyes; then
 683                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 684                 fi
 685                 if test $rc -ne 0; then :
 686                         $6
 687                 else :
 688                         $5
 689                 fi
 690         fi
 691 ])
 692
 693 dnl #
 694 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 695 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 696 dnl # provided via the fifth parameter
 697 dnl #
 698 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 699         [ZFS_LINUX_COMPILE_IFELSE(
 700         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 701         [modules],
 702         [test -s build/conftest.o],
 703         [$3], [$4], [$5])
 704 ])