config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  37         ZFS_AC_KERNEL_GET_DISK_RO
  38         ZFS_AC_KERNEL_GET_GENDISK
  39         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  40         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  41         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  42         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  43         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  45         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  46         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  47         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  48         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  49         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  50         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  51         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  52         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  53         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  54         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  56         ZFS_AC_KERNE_GET_ACL_HANDLE_CACHE
  57         ZFS_AC_KERNEL_SHOW_OPTIONS
  58         ZFS_AC_KERNEL_FILE_INODE
  59         ZFS_AC_KERNEL_FILE_DENTRY
  60         ZFS_AC_KERNEL_FSYNC
  61         ZFS_AC_KERNEL_EVICT_INODE
  62         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  63         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  64         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  65         ZFS_AC_KERNEL_FALLOCATE
  66         ZFS_AC_KERNEL_MKDIR_UMODE_T
  67         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  68         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  69         ZFS_AC_KERNEL_GET_LINK
  70         ZFS_AC_KERNEL_PUT_LINK
  71         ZFS_AC_KERNEL_TRUNCATE_RANGE
  72         ZFS_AC_KERNEL_AUTOMOUNT
  73         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  74         ZFS_AC_KERNEL_COMMIT_METADATA
  75         ZFS_AC_KERNEL_CLEAR_INODE
  76         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  77         ZFS_AC_KERNEL_D_MAKE_ROOT
  78         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  79         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  80         ZFS_AC_KERNEL_D_SET_D_OP
  81         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  82         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  83         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  84         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  85         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  86         ZFS_AC_KERNEL_MOUNT_NODEV
  87         ZFS_AC_KERNEL_SHRINK
  88         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  89         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  90         ZFS_AC_KERNEL_S_D_OP
  91         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  92         ZFS_AC_KERNEL_SET_NLINK
  93         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  94         ZFS_AC_KERNEL_5ARG_SGET
  95         ZFS_AC_KERNEL_LSEEK_EXECUTE
  96         ZFS_AC_KERNEL_VFS_ITERATE
  97         ZFS_AC_KERNEL_VFS_RW_ITERATE
  98         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  99         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 100         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 101         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 102         ZFS_AC_KERNEL_FPU
 103         ZFS_AC_KERNEL_KUID_HELPERS
 104         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 105
 106         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 107                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 108         ])
 109         AC_SUBST(KERNELMAKE_PARAMS)
 110
 111
 112         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 113         dnl # compiler options are added by the kernel build system.
 114         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 115         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 116         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 117         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 118
 119         AC_SUBST(KERNELCPPFLAGS)
 120 ])
 121
 122 dnl #
 123 dnl # Detect name used for Module.symvers file in kernel
 124 dnl #
 125 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 126         modpost=$LINUX/scripts/Makefile.modpost
 127         AC_MSG_CHECKING([kernel file name for module symbols])
 128         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 129                 AS_IF([grep -q Modules.symvers $modpost], [
 130                         LINUX_SYMBOLS=Modules.symvers
 131                 ], [
 132                         LINUX_SYMBOLS=Module.symvers
 133                 ])
 134
 135                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 136                         AC_MSG_ERROR([
 137         *** Please make sure the kernel devel package for your distribution
 138         *** is installed.  If you are building with a custom kernel, make sure the
 139         *** kernel is configured, built, and the '--with-linux=PATH' configure
 140         *** option refers to the location of the kernel source.])
 141                 ])
 142         ], [
 143                 LINUX_SYMBOLS=NONE
 144         ])
 145         AC_MSG_RESULT($LINUX_SYMBOLS)
 146         AC_SUBST(LINUX_SYMBOLS)
 147 ])
 148
 149 dnl #
 150 dnl # Detect the kernel to be built against
 151 dnl #
 152 AC_DEFUN([ZFS_AC_KERNEL], [
 153         AC_ARG_WITH([linux],
 154                 AS_HELP_STRING([--with-linux=PATH],
 155                 [Path to kernel source]),
 156                 [kernelsrc="$withval"])
 157
 158         AC_ARG_WITH(linux-obj,
 159                 AS_HELP_STRING([--with-linux-obj=PATH],
 160                 [Path to kernel build objects]),
 161                 [kernelbuild="$withval"])
 162
 163         AC_MSG_CHECKING([kernel source directory])
 164         AS_IF([test -z "$kernelsrc"], [
 165                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 166                         headersdir="/lib/modules/$(uname -r)/source"
 167                         sourcelink=$(readlink -f "$headersdir")
 168                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 169                         headersdir="/lib/modules/$(uname -r)/build"
 170                         sourcelink=$(readlink -f "$headersdir")
 171                 ], [
 172                         sourcelink=$(ls -1d /usr/src/kernels/* \
 173                                      /usr/src/linux-* \
 174                                      2>/dev/null | grep -v obj | tail -1)
 175                 ])
 176
 177                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 178                         kernelsrc=`readlink -f ${sourcelink}`
 179                 ], [
 180                         kernelsrc="[Not found]"
 181                 ])
 182         ], [
 183                 AS_IF([test "$kernelsrc" = "NONE"], [
 184                         kernsrcver=NONE
 185                 ])
 186         ])
 187
 188         AC_MSG_RESULT([$kernelsrc])
 189         AS_IF([test ! -d "$kernelsrc"], [
 190                 AC_MSG_ERROR([
 191         *** Please make sure the kernel devel package for your distribution
 192         *** is installed and then try again.  If that fails, you can specify the
 193         *** location of the kernel source with the '--with-linux=PATH' option.])
 194         ])
 195
 196         AC_MSG_CHECKING([kernel build directory])
 197         AS_IF([test -z "$kernelbuild"], [
 198                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 199                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 200                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 201                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 202                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 203                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 204                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 205                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 206                 ], [
 207                         kernelbuild=${kernelsrc}
 208                 ])
 209         ])
 210         AC_MSG_RESULT([$kernelbuild])
 211
 212         AC_MSG_CHECKING([kernel source version])
 213         utsrelease1=$kernelbuild/include/linux/version.h
 214         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 215         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 216         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 217                 utsrelease=linux/version.h
 218         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 219                 utsrelease=linux/utsrelease.h
 220         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 221                 utsrelease=generated/utsrelease.h
 222         ])
 223
 224         AS_IF([test "$utsrelease"], [
 225                 kernsrcver=`(echo "#include <$utsrelease>";
 226                              echo "kernsrcver=UTS_RELEASE") |
 227                              cpp -I $kernelbuild/include |
 228                              grep "^kernsrcver=" | cut -d \" -f 2`
 229
 230                 AS_IF([test -z "$kernsrcver"], [
 231                         AC_MSG_RESULT([Not found])
 232                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 233                 ])
 234         ], [
 235                 AC_MSG_RESULT([Not found])
 236                 if test "x$enable_linux_builtin" != xyes; then
 237                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 238                 else
 239                         AC_MSG_ERROR([
 240         *** Cannot find UTS_RELEASE definition.
 241         *** Please run 'make prepare' inside the kernel source tree.])
 242                 fi
 243         ])
 244
 245         AC_MSG_RESULT([$kernsrcver])
 246
 247         LINUX=${kernelsrc}
 248         LINUX_OBJ=${kernelbuild}
 249         LINUX_VERSION=${kernsrcver}
 250
 251         AC_SUBST(LINUX)
 252         AC_SUBST(LINUX_OBJ)
 253         AC_SUBST(LINUX_VERSION)
 254
 255         ZFS_AC_MODULE_SYMVERS
 256 ])
 257
 258
 259 dnl #
 260 dnl # Detect the SPL module to be built against
 261 dnl #
 262 AC_DEFUN([ZFS_AC_SPL], [
 263         AC_ARG_WITH([spl],
 264                 AS_HELP_STRING([--with-spl=PATH],
 265                 [Path to spl source]),
 266                 AS_IF([test "$withval" = "yes"],
 267                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 268                         [splsrc="$withval"]))
 269
 270         AC_ARG_WITH([spl-obj],
 271                 AS_HELP_STRING([--with-spl-obj=PATH],
 272                 [Path to spl build objects]),
 273                 [splbuild="$withval"])
 274
 275         AC_ARG_WITH([spl-timeout],
 276                 AS_HELP_STRING([--with-spl-timeout=SECS],
 277                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 278                 [timeout="$withval"], [timeout=0])
 279
 280         dnl #
 281         dnl # The existence of spl.release.in is used to identify a valid
 282         dnl # source directory.  In order of preference:
 283         dnl #
 284         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 285         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 286         splsrc2="/usr/local/src/spl-${VERSION}"
 287         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 288         splsrc4="/usr/src/spl-${VERSION}"
 289         splsrc5="../spl/"
 290         splsrc6="$LINUX"
 291
 292         AC_MSG_CHECKING([spl source directory])
 293         AS_IF([test -z "${splsrc}"], [
 294                 [all_spl_sources="
 295                 ${splsrc0}
 296                 ${splsrc1}
 297                 ${splsrc2}
 298                 ${splsrc3}
 299                 ${splsrc4}
 300                 ${splsrc5}
 301                 ${splsrc6}"],
 302                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 303                         splsrc=${splsrc0}
 304                 ], [ test -e "${splsrc1}/spl.release.in"], [
 305                         splsrc=${splsrc1}
 306                 ], [ test -e "${splsrc2}/spl.release.in"], [
 307                         splsrc=${splsrc2}
 308                 ], [ test -e "${splsrc3}/spl.release.in"], [
 309                         splsrc=$(readlink -f "${splsrc3}")
 310                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 311                         splsrc=${splsrc4}
 312                 ], [ test -e "${splsrc5}/spl.release.in"], [
 313                         splsrc=$(readlink -f "${splsrc5}")
 314                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 315                         splsrc=${splsrc6}
 316                 ], [
 317                         splsrc="[Not found]"
 318                 ])
 319         ], [
 320                 [all_spl_sources="$withval"],
 321                 AS_IF([test "$splsrc" = "NONE"], [
 322                         splbuild=NONE
 323                         splsrcver=NONE
 324                 ])
 325         ])
 326
 327         AC_MSG_RESULT([$splsrc])
 328         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 329                 AC_MSG_ERROR([
 330         *** Please make sure the kmod spl devel package for your distribution
 331         *** is installed then try again.  If that fails you can specify the
 332         *** location of the spl source with the '--with-spl=PATH' option.
 333         *** The spl version must match the version of ZFS you are building,
 334         *** ${VERSION}.  Failed to find spl.release.in in the following:
 335         $all_spl_sources])
 336         ])
 337
 338         dnl #
 339         dnl # The existence of the spl_config.h is used to identify a valid
 340         dnl # spl object directory.  In many cases the object and source
 341         dnl # directory are the same, however the objects may also reside
 342         dnl # is a subdirectory named after the kernel version.
 343         dnl #
 344         dnl # This file is supposed to be available after DKMS finishes
 345         dnl # building the SPL kernel module for the target kernel.  The
 346         dnl # '--with-spl-timeout' option can be passed to pause here,
 347         dnl # waiting for the file to appear from a concurrently building
 348         dnl # SPL package.
 349         dnl #
 350         AC_MSG_CHECKING([spl build directory])
 351
 352         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 353         ${splsrc}"
 354
 355         while true; do
 356                 AS_IF([test -z "$splbuild"], [
 357                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 358                                 splbuild="${splsrc}/${LINUX_VERSION}"
 359                         ], [ test -e "${splsrc}/spl_config.h" ], [
 360                                 splbuild="${splsrc}"
 361                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 362                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 363                         ], [
 364                                 splbuild="[Not found]"
 365                         ])
 366                 ])
 367                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 368                         break;
 369                 ], [
 370                         sleep 1
 371                         timeout=$((timeout-1))
 372                 ])
 373         done
 374
 375         AC_MSG_RESULT([$splbuild])
 376         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 377                 AC_MSG_ERROR([
 378         *** Please make sure the kmod spl devel <kernel> package for your
 379         *** distribution is installed then try again.  If that fails you
 380         *** can specify the location of the spl objects with the
 381         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 382         *** any of the following:
 383         $all_spl_config_locs])
 384         ])
 385
 386         AC_MSG_CHECKING([spl source version])
 387         AS_IF([test -r $splbuild/spl_config.h &&
 388                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 389
 390                 splsrcver=`(echo "#include <spl_config.h>";
 391                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 392                             cpp -I $splbuild |
 393                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 394         ])
 395
 396         AS_IF([test -z "$splsrcver"], [
 397                 AC_MSG_RESULT([Not found])
 398                 AC_MSG_ERROR([
 399         *** Cannot determine the version of the spl source.
 400         *** Please prepare the spl source before running this script])
 401         ])
 402
 403         AC_MSG_RESULT([$splsrcver])
 404
 405         SPL=${splsrc}
 406         SPL_OBJ=${splbuild}
 407         SPL_VERSION=${splsrcver}
 408
 409         AC_SUBST(SPL)
 410         AC_SUBST(SPL_OBJ)
 411         AC_SUBST(SPL_VERSION)
 412
 413         dnl #
 414         dnl # Detect the name used for the SPL Module.symvers file.  If one
 415         dnl # does not exist this is likely because the SPL has been configured
 416         dnl # but not built.  The '--with-spl-timeout' option can be passed
 417         dnl # to pause here, waiting for the file to appear from a concurrently
 418         dnl # building SPL package.  If the file does not appear in time, a good
 419         dnl # guess is made as to what this file will be named based on what it
 420         dnl # is named in the kernel build products.  This file will first be
 421         dnl # used at link time so if the guess is wrong the build will fail
 422         dnl # then.  This unfortunately means the ZFS package does not contain a
 423         dnl # reliable mechanism to detect symbols exported by the SPL at
 424         dnl # configure time.
 425         dnl #
 426         AC_MSG_CHECKING([spl file name for module symbols])
 427         SPL_SYMBOLS=NONE
 428
 429         while true; do
 430                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 431                         SPL_SYMBOLS=Module.symvers
 432                 ], [test -r $SPL_OBJ/Modules.symvers], [
 433                         SPL_SYMBOLS=Modules.symvers
 434                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 435                         SPL_SYMBOLS=Module.symvers
 436                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 437                         SPL_SYMBOLS=Modules.symvers
 438                 ])
 439
 440                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 441                         break;
 442                 ], [
 443                         sleep 1
 444                         timeout=$((timeout-1))
 445                 ])
 446         done
 447
 448         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 449                 SPL_SYMBOLS=$LINUX_SYMBOLS
 450         ])
 451
 452         AC_MSG_RESULT([$SPL_SYMBOLS])
 453         AC_SUBST(SPL_SYMBOLS)
 454 ])
 455
 456 dnl #
 457 dnl # Basic toolchain sanity check.
 458 dnl #
 459 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 460         AC_MSG_CHECKING([whether modules can be built])
 461         ZFS_LINUX_TRY_COMPILE([],[],[
 462                 AC_MSG_RESULT([yes])
 463         ],[
 464                 AC_MSG_RESULT([no])
 465                 if test "x$enable_linux_builtin" != xyes; then
 466                         AC_MSG_ERROR([*** Unable to build an empty module.])
 467                 else
 468                         AC_MSG_ERROR([
 469         *** Unable to build an empty module.
 470         *** Please run 'make scripts' inside the kernel source tree.])
 471                 fi
 472         ])
 473 ])
 474
 475 dnl #
 476 dnl # Certain kernel build options are not supported.  These must be
 477 dnl # detected at configure time and cause a build failure.  Otherwise
 478 dnl # modules may be successfully built that behave incorrectly.
 479 dnl #
 480 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 481         AS_IF([test "x$cross_compiling" != xyes], [
 482                 AC_RUN_IFELSE([
 483                         AC_LANG_PROGRAM([
 484                                 #include "$LINUX/include/linux/license.h"
 485                         ], [
 486                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 487                         ])
 488                 ], [
 489                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 490                             [Define to 1 if GPL-only symbols can be used])
 491                 ], [
 492                 ])
 493         ])
 494
 495         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 496         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 497 ])
 498
 499 dnl #
 500 dnl # Check configured THREAD_SIZE
 501 dnl #
 502 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 503 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 504 dnl # on newer kernels and some architectures stack usage optimizations can be
 505 dnl # conditionally applied to improve performance without negatively impacting
 506 dnl # stability.
 507 dnl #
 508 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 509         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 510         ZFS_LINUX_TRY_COMPILE([
 511                 #include <linux/module.h>
 512         ],[
 513                 #if (THREAD_SIZE < 16384)
 514                 #error "THREAD_SIZE is less than 16K"
 515                 #endif
 516         ],[
 517                 AC_MSG_RESULT([yes])
 518                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 519         ],[
 520                 AC_MSG_RESULT([no])
 521         ])
 522 ])
 523
 524 dnl #
 525 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 526 dnl #
 527 dnl # This is typically only set for debug kernels because it comes with
 528 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 529 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 530 dnl # This will cause a failure at link time which we'd rather know about
 531 dnl # at compile time.
 532 dnl #
 533 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 534 dnl # with the upstream community we add a check to detect this case.
 535 dnl #
 536 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 537
 538         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 539                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 540                 tmp_flags="$EXTRA_KCFLAGS"
 541                 ZFS_LINUX_TRY_COMPILE([
 542                         #include <linux/module.h>
 543                         #include <linux/mutex.h>
 544
 545                         MODULE_LICENSE("$ZFS_META_LICENSE");
 546                 ],[
 547                         struct mutex lock;
 548
 549                         mutex_init(&lock);
 550                         mutex_lock(&lock);
 551                         mutex_unlock(&lock);
 552                 ],[
 553                         AC_MSG_RESULT(no)
 554                 ],[
 555                         AC_MSG_RESULT(yes)
 556                         AC_MSG_ERROR([
 557         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 558         *** with the CDDL license and will prevent the module linking stage
 559         *** from succeeding.  You must rebuild your kernel without this
 560         *** option enabled.])
 561                 ])
 562                 EXTRA_KCFLAGS="$tmp_flags"
 563         ], [])
 564 ])
 565
 566 dnl #
 567 dnl # ZFS_LINUX_CONFTEST_H
 568 dnl #
 569 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 570 cat - <<_ACEOF >conftest.h
 571 $1
 572 _ACEOF
 573 ])
 574
 575 dnl #
 576 dnl # ZFS_LINUX_CONFTEST_C
 577 dnl #
 578 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 579 cat confdefs.h - <<_ACEOF >conftest.c
 580 $1
 581 _ACEOF
 582 ])
 583
 584 dnl #
 585 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 586 dnl #
 587 m4_define([ZFS_LANG_PROGRAM], [
 588 $1
 589 int
 590 main (void)
 591 {
 592 dnl Do *not* indent the following line: there may be CPP directives.
 593 dnl Don't move the `;' right after for the same reason.
 594 $2
 595   ;
 596   return 0;
 597 }
 598 ])
 599
 600 dnl #
 601 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 602 dnl #
 603 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 604         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 605         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 606         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 607         echo "obj-m := conftest.o" >build/Makefile
 608         modpost_flag=''
 609         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 610         AS_IF(
 611                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 612                 [$4],
 613                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 614         )
 615         rm -Rf build
 616 ])
 617
 618 dnl #
 619 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 620 dnl #
 621 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 622         [ZFS_LINUX_COMPILE_IFELSE(
 623         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 624         [modules],
 625         [test -s build/conftest.o],
 626         [$3], [$4])
 627 ])
 628
 629 dnl #
 630 dnl # ZFS_LINUX_CONFIG
 631 dnl #
 632 AC_DEFUN([ZFS_LINUX_CONFIG],
 633         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 634         ZFS_LINUX_TRY_COMPILE([
 635                 #include <linux/module.h>
 636         ],[
 637                 #ifndef CONFIG_$1
 638                 #error CONFIG_$1 not #defined
 639                 #endif
 640         ],[
 641                 AC_MSG_RESULT([yes])
 642                 $2
 643         ],[
 644                 AC_MSG_RESULT([no])
 645                 $3
 646         ])
 647 ])
 648
 649 dnl #
 650 dnl # ZFS_CHECK_SYMBOL_EXPORT
 651 dnl # check symbol exported or not
 652 dnl #
 653 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 654         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 655                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 656         rc=$?
 657         if test $rc -ne 0; then
 658                 export=0
 659                 for file in $2; do
 660                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 661                                 "$LINUX/$file" 2>/dev/null
 662                         rc=$?
 663                         if test $rc -eq 0; then
 664                                 export=1
 665                                 break;
 666                         fi
 667                 done
 668                 if test $export -eq 0; then :
 669                         $4
 670                 else :
 671                         $3
 672                 fi
 673         else :
 674                 $3
 675         fi
 676 ])
 677
 678 dnl #
 679 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 680 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 681 dnl # is called if not compiling for builtin
 682 dnl #
 683 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 684         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 685         if test $rc -ne 0; then :
 686                 $6
 687         else
 688                 if test "x$enable_linux_builtin" != xyes; then
 689                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 690                 fi
 691                 if test $rc -ne 0; then :
 692                         $6
 693                 else :
 694                         $5
 695                 fi
 696         fi
 697 ])
 698
 699 dnl #
 700 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 701 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 702 dnl # provided via the fifth parameter
 703 dnl #
 704 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 705         [ZFS_LINUX_COMPILE_IFELSE(
 706         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 707         [modules],
 708         [test -s build/conftest.o],
 709         [$3], [$4], [$5])
 710 ])