config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  15         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  16         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  17         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  18         ZFS_AC_KERNEL_LOOKUP_BDEV
  19         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  20         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BIO_BVEC_ITER
  23         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  24         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  25         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  26         ZFS_AC_KERNEL_BIO_RW_BARRIER
  27         ZFS_AC_KERNEL_BIO_RW_DISCARD
  28         ZFS_AC_KERNEL_BIO_RW_SYNC
  29         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  30         ZFS_AC_KERNEL_REQ_SYNC
  31         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  32         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  33         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  34         ZFS_AC_KERNEL_GET_DISK_RO
  35         ZFS_AC_KERNEL_GET_GENDISK
  36         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  37         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  38         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  39         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  40         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  41         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  42         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  43         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  44         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  45         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  46         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  47         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  48         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  49         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  50         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  51         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  52         ZFS_AC_KERNEL_CURRENT_UMASK
  53         ZFS_AC_KERNEL_SHOW_OPTIONS
  54         ZFS_AC_KERNEL_FILE_INODE
  55         ZFS_AC_KERNEL_FSYNC
  56         ZFS_AC_KERNEL_EVICT_INODE
  57         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  58         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  59         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  60         ZFS_AC_KERNEL_FALLOCATE
  61         ZFS_AC_KERNEL_MKDIR_UMODE_T
  62         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  63         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  64         ZFS_AC_KERNEL_FOLLOW_LINK
  65         ZFS_AC_KERNEL_PUT_LINK
  66         ZFS_AC_KERNEL_TRUNCATE_RANGE
  67         ZFS_AC_KERNEL_AUTOMOUNT
  68         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  69         ZFS_AC_KERNEL_COMMIT_METADATA
  70         ZFS_AC_KERNEL_CLEAR_INODE
  71         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  72         ZFS_AC_KERNEL_D_MAKE_ROOT
  73         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  74         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  75         ZFS_AC_KERNEL_D_SET_D_OP
  76         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  77         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  78         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  79         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  80         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  81         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  82         ZFS_AC_KERNEL_MOUNT_NODEV
  83         ZFS_AC_KERNEL_SHRINK
  84         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  85         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  86         ZFS_AC_KERNEL_S_D_OP
  87         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  88         ZFS_AC_KERNEL_SET_NLINK
  89         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  90         ZFS_AC_KERNEL_5ARG_SGET
  91         ZFS_AC_KERNEL_LSEEK_EXECUTE
  92         ZFS_AC_KERNEL_VFS_ITERATE
  93         ZFS_AC_KERNEL_VFS_RW_ITERATE
  94         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  95         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
  96         ZFS_AC_KERNEL_MAKE_REQUEST_FN
  97
  98         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  99                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 100         ])
 101         AC_SUBST(KERNELMAKE_PARAMS)
 102
 103
 104         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 105         dnl # compiler options are added by the kernel build system.
 106         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 107         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 108         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 109         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 110
 111         AC_SUBST(KERNELCPPFLAGS)
 112 ])
 113
 114 dnl #
 115 dnl # Detect name used for Module.symvers file in kernel
 116 dnl #
 117 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 118         modpost=$LINUX/scripts/Makefile.modpost
 119         AC_MSG_CHECKING([kernel file name for module symbols])
 120         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 121                 AS_IF([grep -q Modules.symvers $modpost], [
 122                         LINUX_SYMBOLS=Modules.symvers
 123                 ], [
 124                         LINUX_SYMBOLS=Module.symvers
 125                 ])
 126
 127                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 128                         AC_MSG_ERROR([
 129         *** Please make sure the kernel devel package for your distribution
 130         *** is installed.  If you are building with a custom kernel, make sure the
 131         *** kernel is configured, built, and the '--with-linux=PATH' configure
 132         *** option refers to the location of the kernel source.])
 133                 ])
 134         ], [
 135                 LINUX_SYMBOLS=NONE
 136         ])
 137         AC_MSG_RESULT($LINUX_SYMBOLS)
 138         AC_SUBST(LINUX_SYMBOLS)
 139 ])
 140
 141 dnl #
 142 dnl # Detect the kernel to be built against
 143 dnl #
 144 AC_DEFUN([ZFS_AC_KERNEL], [
 145         AC_ARG_WITH([linux],
 146                 AS_HELP_STRING([--with-linux=PATH],
 147                 [Path to kernel source]),
 148                 [kernelsrc="$withval"])
 149
 150         AC_ARG_WITH(linux-obj,
 151                 AS_HELP_STRING([--with-linux-obj=PATH],
 152                 [Path to kernel build objects]),
 153                 [kernelbuild="$withval"])
 154
 155         AC_MSG_CHECKING([kernel source directory])
 156         AS_IF([test -z "$kernelsrc"], [
 157                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 158                         headersdir="/lib/modules/$(uname -r)/source"
 159                         sourcelink=$(readlink -f "$headersdir")
 160                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 161                         headersdir="/lib/modules/$(uname -r)/build"
 162                         sourcelink=$(readlink -f "$headersdir")
 163                 ], [
 164                         sourcelink=$(ls -1d /usr/src/kernels/* \
 165                                      /usr/src/linux-* \
 166                                      2>/dev/null | grep -v obj | tail -1)
 167                 ])
 168
 169                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 170                         kernelsrc=`readlink -f ${sourcelink}`
 171                 ], [
 172                         kernelsrc="[Not found]"
 173                 ])
 174         ], [
 175                 AS_IF([test "$kernelsrc" = "NONE"], [
 176                         kernsrcver=NONE
 177                 ])
 178         ])
 179
 180         AC_MSG_RESULT([$kernelsrc])
 181         AS_IF([test ! -d "$kernelsrc"], [
 182                 AC_MSG_ERROR([
 183         *** Please make sure the kernel devel package for your distribution
 184         *** is installed and then try again.  If that fails, you can specify the
 185         *** location of the kernel source with the '--with-linux=PATH' option.])
 186         ])
 187
 188         AC_MSG_CHECKING([kernel build directory])
 189         AS_IF([test -z "$kernelbuild"], [
 190                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 191                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 192                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 193                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 194                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 195                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 196                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 197                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 198                 ], [
 199                         kernelbuild=${kernelsrc}
 200                 ])
 201         ])
 202         AC_MSG_RESULT([$kernelbuild])
 203
 204         AC_MSG_CHECKING([kernel source version])
 205         utsrelease1=$kernelbuild/include/linux/version.h
 206         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 207         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 208         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 209                 utsrelease=linux/version.h
 210         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 211                 utsrelease=linux/utsrelease.h
 212         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 213                 utsrelease=generated/utsrelease.h
 214         ])
 215
 216         AS_IF([test "$utsrelease"], [
 217                 kernsrcver=`(echo "#include <$utsrelease>";
 218                              echo "kernsrcver=UTS_RELEASE") |
 219                              cpp -I $kernelbuild/include |
 220                              grep "^kernsrcver=" | cut -d \" -f 2`
 221
 222                 AS_IF([test -z "$kernsrcver"], [
 223                         AC_MSG_RESULT([Not found])
 224                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 225                 ])
 226         ], [
 227                 AC_MSG_RESULT([Not found])
 228                 if test "x$enable_linux_builtin" != xyes; then
 229                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 230                 else
 231                         AC_MSG_ERROR([
 232         *** Cannot find UTS_RELEASE definition.
 233         *** Please run 'make prepare' inside the kernel source tree.])
 234                 fi
 235         ])
 236
 237         AC_MSG_RESULT([$kernsrcver])
 238
 239         LINUX=${kernelsrc}
 240         LINUX_OBJ=${kernelbuild}
 241         LINUX_VERSION=${kernsrcver}
 242
 243         AC_SUBST(LINUX)
 244         AC_SUBST(LINUX_OBJ)
 245         AC_SUBST(LINUX_VERSION)
 246
 247         ZFS_AC_MODULE_SYMVERS
 248 ])
 249
 250
 251 dnl #
 252 dnl # Detect the SPL module to be built against
 253 dnl #
 254 AC_DEFUN([ZFS_AC_SPL], [
 255         AC_ARG_WITH([spl],
 256                 AS_HELP_STRING([--with-spl=PATH],
 257                 [Path to spl source]),
 258                 [splsrc="$withval"])
 259
 260         AC_ARG_WITH([spl-obj],
 261                 AS_HELP_STRING([--with-spl-obj=PATH],
 262                 [Path to spl build objects]),
 263                 [splbuild="$withval"])
 264
 265         AC_ARG_WITH([spl-timeout],
 266                 AS_HELP_STRING([--with-spl-timeout=SECS],
 267                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 268                 [timeout="$withval"], [timeout=0])
 269
 270         dnl #
 271         dnl # The existence of spl.release.in is used to identify a valid
 272         dnl # source directory.  In order of preference:
 273         dnl #
 274         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 275         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 276         splsrc2="/usr/local/src/spl-${VERSION}"
 277         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 278         splsrc4="/usr/src/spl-${VERSION}"
 279         splsrc5="../spl/"
 280         splsrc6="$LINUX"
 281
 282         AC_MSG_CHECKING([spl source directory])
 283         AS_IF([test -z "${splsrc}"], [
 284                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 285                         splsrc=${splsrc0}
 286                 ], [ test -e "${splsrc1}/spl.release.in"], [
 287                         splsrc=${splsrc1}
 288                 ], [ test -e "${splsrc2}/spl.release.in"], [
 289                         splsrc=${splsrc2}
 290                 ], [ test -e "${splsrc3}/spl.release.in"], [
 291                         splsrc=$(readlink -f "${splsrc3}")
 292                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 293                         splsrc=${splsrc4}
 294                 ], [ test -e "${splsrc5}/spl.release.in"], [
 295                         splsrc=$(readlink -f "${splsrc5}")
 296                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 297                         splsrc=${splsrc6}
 298                 ], [
 299                         splsrc="[Not found]"
 300                 ])
 301         ], [
 302                 AS_IF([test "$splsrc" = "NONE"], [
 303                         splbuild=NONE
 304                         splsrcver=NONE
 305                 ])
 306         ])
 307
 308         AC_MSG_RESULT([$splsrc])
 309         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 310                 AC_MSG_ERROR([
 311         *** Please make sure the kmod spl devel package for your distribution
 312         *** is installed then try again.  If that fails you can specify the
 313         *** location of the spl source with the '--with-spl=PATH' option.])
 314         ])
 315
 316         dnl #
 317         dnl # The existence of the spl_config.h is used to identify a valid
 318         dnl # spl object directory.  In many cases the object and source
 319         dnl # directory are the same, however the objects may also reside
 320         dnl # is a subdirectory named after the kernel version.
 321         dnl #
 322         dnl # This file is supposed to be available after DKMS finishes
 323         dnl # building the SPL kernel module for the target kernel.  The
 324         dnl # '--with-spl-timeout' option can be passed to pause here,
 325         dnl # waiting for the file to appear from a concurrently building
 326         dnl # SPL package.
 327         dnl #
 328         AC_MSG_CHECKING([spl build directory])
 329         while true; do
 330                 AS_IF([test -z "$splbuild"], [
 331                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 332                                 splbuild="${splsrc}/${LINUX_VERSION}"
 333                         ], [ test -e "${splsrc}/spl_config.h" ], [
 334                                 splbuild="${splsrc}"
 335                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 336                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 337                         ], [
 338                                 splbuild="[Not found]"
 339                         ])
 340                 ])
 341                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 342                         break;
 343                 ], [
 344                         sleep 1
 345                         timeout=$((timeout-1))
 346                 ])
 347         done
 348
 349         AC_MSG_RESULT([$splbuild])
 350         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 351                 AC_MSG_ERROR([
 352         *** Please make sure the kmod spl devel <kernel> package for your
 353         *** distribution is installed then try again.  If that fails you
 354         *** can specify the location of the spl objects with the
 355         *** '--with-spl-obj=PATH' option.])
 356         ])
 357
 358         AC_MSG_CHECKING([spl source version])
 359         AS_IF([test -r $splbuild/spl_config.h &&
 360                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 361
 362                 splsrcver=`(echo "#include <spl_config.h>";
 363                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 364                             cpp -I $splbuild |
 365                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 366         ])
 367
 368         AS_IF([test -z "$splsrcver"], [
 369                 AC_MSG_RESULT([Not found])
 370                 AC_MSG_ERROR([
 371         *** Cannot determine the version of the spl source.
 372         *** Please prepare the spl source before running this script])
 373         ])
 374
 375         AC_MSG_RESULT([$splsrcver])
 376
 377         SPL=${splsrc}
 378         SPL_OBJ=${splbuild}
 379         SPL_VERSION=${splsrcver}
 380
 381         AC_SUBST(SPL)
 382         AC_SUBST(SPL_OBJ)
 383         AC_SUBST(SPL_VERSION)
 384
 385         dnl #
 386         dnl # Detect the name used for the SPL Module.symvers file.  If one
 387         dnl # does not exist this is likely because the SPL has been configured
 388         dnl # but not built.  The '--with-spl-timeout' option can be passed
 389         dnl # to pause here, waiting for the file to appear from a concurrently
 390         dnl # building SPL package.  If the file does not appear in time, a good
 391         dnl # guess is made as to what this file will be named based on what it
 392         dnl # is named in the kernel build products.  This file will first be
 393         dnl # used at link time so if the guess is wrong the build will fail
 394         dnl # then.  This unfortunately means the ZFS package does not contain a
 395         dnl # reliable mechanism to detect symbols exported by the SPL at
 396         dnl # configure time.
 397         dnl #
 398         AC_MSG_CHECKING([spl file name for module symbols])
 399         SPL_SYMBOLS=NONE
 400
 401         while true; do
 402                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 403                         SPL_SYMBOLS=Module.symvers
 404                 ], [test -r $SPL_OBJ/Modules.symvers], [
 405                         SPL_SYMBOLS=Modules.symvers
 406                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 407                         SPL_SYMBOLS=Module.symvers
 408                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 409                         SPL_SYMBOLS=Modules.symvers
 410                 ])
 411
 412                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 413                         break;
 414                 ], [
 415                         sleep 1
 416                         timeout=$((timeout-1))
 417                 ])
 418         done
 419
 420         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 421                 SPL_SYMBOLS=$LINUX_SYMBOLS
 422         ])
 423
 424         AC_MSG_RESULT([$SPL_SYMBOLS])
 425         AC_SUBST(SPL_SYMBOLS)
 426 ])
 427
 428 dnl #
 429 dnl # Basic toolchain sanity check.
 430 dnl #
 431 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 432         AC_MSG_CHECKING([whether modules can be built])
 433         ZFS_LINUX_TRY_COMPILE([],[],[
 434                 AC_MSG_RESULT([yes])
 435         ],[
 436                 AC_MSG_RESULT([no])
 437                 if test "x$enable_linux_builtin" != xyes; then
 438                         AC_MSG_ERROR([*** Unable to build an empty module.])
 439                 else
 440                         AC_MSG_ERROR([
 441         *** Unable to build an empty module.
 442         *** Please run 'make scripts' inside the kernel source tree.])
 443                 fi
 444         ])
 445 ])
 446
 447 dnl #
 448 dnl # Certain kernel build options are not supported.  These must be
 449 dnl # detected at configure time and cause a build failure.  Otherwise
 450 dnl # modules may be successfully built that behave incorrectly.
 451 dnl #
 452 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 453         AC_RUN_IFELSE([
 454                 AC_LANG_PROGRAM([
 455                         #include "$LINUX/include/linux/license.h"
 456                 ], [
 457                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 458                 ])
 459         ], [
 460                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 461                     [Define to 1 if GPL-only symbols can be used])
 462         ], [
 463         ])
 464
 465         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 466 ])
 467
 468 dnl #
 469 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 470 dnl #
 471 dnl # This is typically only set for debug kernels because it comes with
 472 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 473 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 474 dnl # This will cause a failure at link time which we'd rather know about
 475 dnl # at compile time.
 476 dnl #
 477 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 478 dnl # with the upstream community we add a check to detect this case.
 479 dnl #
 480 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 481
 482         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 483                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 484                 tmp_flags="$EXTRA_KCFLAGS"
 485                 ZFS_LINUX_TRY_COMPILE([
 486                         #include <linux/module.h>
 487                         #include <linux/mutex.h>
 488
 489                         MODULE_LICENSE("$ZFS_META_LICENSE");
 490                 ],[
 491                         struct mutex lock;
 492
 493                         mutex_init(&lock);
 494                         mutex_lock(&lock);
 495                         mutex_unlock(&lock);
 496                 ],[
 497                         AC_MSG_RESULT(no)
 498                 ],[
 499                         AC_MSG_RESULT(yes)
 500                         AC_MSG_ERROR([
 501         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 502         *** with the CDDL license and will prevent the module linking stage
 503         *** from succeeding.  You must rebuild your kernel without this
 504         *** option enabled.])
 505                 ])
 506                 EXTRA_KCFLAGS="$tmp_flags"
 507         ], [])
 508 ])
 509
 510 dnl #
 511 dnl # ZFS_LINUX_CONFTEST_H
 512 dnl #
 513 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 514 cat - <<_ACEOF >conftest.h
 515 $1
 516 _ACEOF
 517 ])
 518
 519 dnl #
 520 dnl # ZFS_LINUX_CONFTEST_C
 521 dnl #
 522 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 523 cat confdefs.h - <<_ACEOF >conftest.c
 524 $1
 525 _ACEOF
 526 ])
 527
 528 dnl #
 529 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 530 dnl #
 531 m4_define([ZFS_LANG_PROGRAM], [
 532 $1
 533 int
 534 main (void)
 535 {
 536 dnl Do *not* indent the following line: there may be CPP directives.
 537 dnl Don't move the `;' right after for the same reason.
 538 $2
 539   ;
 540   return 0;
 541 }
 542 ])
 543
 544 dnl #
 545 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 546 dnl #
 547 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 548         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 549         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 550         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 551         echo "obj-m := conftest.o" >build/Makefile
 552         modpost_flag=''
 553         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 554         AS_IF(
 555                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 556                 [$4],
 557                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 558         )
 559         rm -Rf build
 560 ])
 561
 562 dnl #
 563 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 564 dnl #
 565 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 566         [ZFS_LINUX_COMPILE_IFELSE(
 567         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 568         [modules],
 569         [test -s build/conftest.o],
 570         [$3], [$4])
 571 ])
 572
 573 dnl #
 574 dnl # ZFS_LINUX_CONFIG
 575 dnl #
 576 AC_DEFUN([ZFS_LINUX_CONFIG],
 577         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 578         ZFS_LINUX_TRY_COMPILE([
 579                 #include <linux/module.h>
 580         ],[
 581                 #ifndef CONFIG_$1
 582                 #error CONFIG_$1 not #defined
 583                 #endif
 584         ],[
 585                 AC_MSG_RESULT([yes])
 586                 $2
 587         ],[
 588                 AC_MSG_RESULT([no])
 589                 $3
 590         ])
 591 ])
 592
 593 dnl #
 594 dnl # ZFS_CHECK_SYMBOL_EXPORT
 595 dnl # check symbol exported or not
 596 dnl #
 597 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 598         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 599                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 600         rc=$?
 601         if test $rc -ne 0; then
 602                 export=0
 603                 for file in $2; do
 604                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 605                                 "$LINUX/$file" 2>/dev/null
 606                         rc=$?
 607                         if test $rc -eq 0; then
 608                                 export=1
 609                                 break;
 610                         fi
 611                 done
 612                 if test $export -eq 0; then :
 613                         $4
 614                 else :
 615                         $3
 616                 fi
 617         else :
 618                 $3
 619         fi
 620 ])
 621
 622 dnl #
 623 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 624 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 625 dnl # is called if not compiling for builtin
 626 dnl #
 627 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 628         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 629         if test $rc -ne 0; then :
 630                 $6
 631         else
 632                 if test "x$enable_linux_builtin" != xyes; then
 633                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 634                 fi
 635                 if test $rc -ne 0; then :
 636                         $6
 637                 else :
 638                         $5
 639                 fi
 640         fi
 641 ])
 642
 643 dnl #
 644 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 645 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 646 dnl # provided via the fifth parameter
 647 dnl #
 648 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 649         [ZFS_LINUX_COMPILE_IFELSE(
 650         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 651         [modules],
 652         [test -s build/conftest.o],
 653         [$3], [$4], [$5])
 654 ])