config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  11         ZFS_AC_KERNEL_TYPE_FMODE_T
  12         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  13         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  14         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  15         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  16         ZFS_AC_KERNEL_LOOKUP_BDEV
  17         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  18         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  20         ZFS_AC_KERNEL_BIO_BVEC_ITER
  21         ZFS_AC_KERNEL_BIO_FAILFAST
  22         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  23         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  24         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  25         ZFS_AC_KERNEL_BIO_RW_SYNC
  26         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  27         ZFS_AC_KERNEL_REQ_SYNC
  28         ZFS_AC_KERNEL_BLK_END_REQUEST
  29         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  31         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  32         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  33         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  34         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  35         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  36         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  37         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  38         ZFS_AC_KERNEL_BLK_RQ_BYTES
  39         ZFS_AC_KERNEL_BLK_RQ_POS
  40         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  41         ZFS_AC_KERNEL_GET_DISK_RO
  42         ZFS_AC_KERNEL_GET_GENDISK
  43         ZFS_AC_KERNEL_RQ_IS_SYNC
  44         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  45         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  46         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  47         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  48         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  49         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  50         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  51         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  52         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  53         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  54         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  55         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  61         ZFS_AC_KERNEL_CURRENT_UMASK
  62         ZFS_AC_KERNEL_SHOW_OPTIONS
  63         ZFS_AC_KERNEL_FSYNC
  64         ZFS_AC_KERNEL_EVICT_INODE
  65         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  66         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  67         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  68         ZFS_AC_KERNEL_FALLOCATE
  69         ZFS_AC_KERNEL_MKDIR_UMODE_T
  70         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  71         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  72         ZFS_AC_KERNEL_TRUNCATE_RANGE
  73         ZFS_AC_KERNEL_AUTOMOUNT
  74         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  75         ZFS_AC_KERNEL_COMMIT_METADATA
  76         ZFS_AC_KERNEL_CLEAR_INODE
  77         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  78         ZFS_AC_KERNEL_D_MAKE_ROOT
  79         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  80         ZFS_AC_KERNEL_D_SET_D_OP
  81         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  82         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  83         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  84         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  85         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  86         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  87         ZFS_AC_KERNEL_MOUNT_NODEV
  88         ZFS_AC_KERNEL_SHRINK
  89         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  90         ZFS_AC_KERNEL_S_D_OP
  91         ZFS_AC_KERNEL_BDI
  92         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  93         ZFS_AC_KERNEL_SET_NLINK
  94         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  95         ZFS_AC_KERNEL_5ARG_SGET
  96         ZFS_AC_KERNEL_LSEEK_EXECUTE
  97         ZFS_AC_KERNEL_VFS_ITERATE
  98
  99         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 100                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 101         ])
 102         AC_SUBST(KERNELMAKE_PARAMS)
 103
 104
 105         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 106         dnl # compiler options are added by the kernel build system.
 107         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 108         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 109         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 110
 111         AC_SUBST(KERNELCPPFLAGS)
 112 ])
 113
 114 dnl #
 115 dnl # Detect name used for Module.symvers file in kernel
 116 dnl #
 117 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 118         modpost=$LINUX/scripts/Makefile.modpost
 119         AC_MSG_CHECKING([kernel file name for module symbols])
 120         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 121                 AS_IF([grep -q Modules.symvers $modpost], [
 122                         LINUX_SYMBOLS=Modules.symvers
 123                 ], [
 124                         LINUX_SYMBOLS=Module.symvers
 125                 ])
 126
 127                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 128                         AC_MSG_ERROR([
 129         *** Please make sure the kernel devel package for your distribution
 130         *** is installed.  If you are building with a custom kernel, make sure the
 131         *** kernel is configured, built, and the '--with-linux=PATH' configure
 132         *** option refers to the location of the kernel source.])
 133                 ])
 134         ], [
 135                 LINUX_SYMBOLS=NONE
 136         ])
 137         AC_MSG_RESULT($LINUX_SYMBOLS)
 138         AC_SUBST(LINUX_SYMBOLS)
 139 ])
 140
 141 dnl #
 142 dnl # Detect the kernel to be built against
 143 dnl #
 144 AC_DEFUN([ZFS_AC_KERNEL], [
 145         AC_ARG_WITH([linux],
 146                 AS_HELP_STRING([--with-linux=PATH],
 147                 [Path to kernel source]),
 148                 [kernelsrc="$withval"])
 149
 150         AC_ARG_WITH(linux-obj,
 151                 AS_HELP_STRING([--with-linux-obj=PATH],
 152                 [Path to kernel build objects]),
 153                 [kernelbuild="$withval"])
 154
 155         AC_MSG_CHECKING([kernel source directory])
 156         AS_IF([test -z "$kernelsrc"], [
 157                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 158                         headersdir="/lib/modules/$(uname -r)/source"
 159                         sourcelink=$(readlink -f "$headersdir")
 160                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 161                         headersdir="/lib/modules/$(uname -r)/build"
 162                         sourcelink=$(readlink -f "$headersdir")
 163                 ], [
 164                         sourcelink=$(ls -1d /usr/src/kernels/* \
 165                                      /usr/src/linux-* \
 166                                      2>/dev/null | grep -v obj | tail -1)
 167                 ])
 168
 169                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 170                         kernelsrc=`readlink -f ${sourcelink}`
 171                 ], [
 172                         kernelsrc="[Not found]"
 173                 ])
 174         ], [
 175                 AS_IF([test "$kernelsrc" = "NONE"], [
 176                         kernsrcver=NONE
 177                 ])
 178         ])
 179
 180         AC_MSG_RESULT([$kernelsrc])
 181         AS_IF([test ! -d "$kernelsrc"], [
 182                 AC_MSG_ERROR([
 183         *** Please make sure the kernel devel package for your distribution
 184         *** is installed and then try again.  If that fails, you can specify the
 185         *** location of the kernel source with the '--with-linux=PATH' option.])
 186         ])
 187
 188         AC_MSG_CHECKING([kernel build directory])
 189         AS_IF([test -z "$kernelbuild"], [
 190                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 191                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 192                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 193                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 194                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 195                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 196                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 197                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 198                 ], [
 199                         kernelbuild=${kernelsrc}
 200                 ])
 201         ])
 202         AC_MSG_RESULT([$kernelbuild])
 203
 204         AC_MSG_CHECKING([kernel source version])
 205         utsrelease1=$kernelbuild/include/linux/version.h
 206         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 207         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 208         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 209                 utsrelease=linux/version.h
 210         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 211                 utsrelease=linux/utsrelease.h
 212         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 213                 utsrelease=generated/utsrelease.h
 214         ])
 215
 216         AS_IF([test "$utsrelease"], [
 217                 kernsrcver=`(echo "#include <$utsrelease>";
 218                              echo "kernsrcver=UTS_RELEASE") |
 219                              cpp -I $kernelbuild/include |
 220                              grep "^kernsrcver=" | cut -d \" -f 2`
 221
 222                 AS_IF([test -z "$kernsrcver"], [
 223                         AC_MSG_RESULT([Not found])
 224                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 225                 ])
 226         ], [
 227                 AC_MSG_RESULT([Not found])
 228                 if test "x$enable_linux_builtin" != xyes; then
 229                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 230                 else
 231                         AC_MSG_ERROR([
 232         *** Cannot find UTS_RELEASE definition.
 233         *** Please run 'make prepare' inside the kernel source tree.])
 234                 fi
 235         ])
 236
 237         AC_MSG_RESULT([$kernsrcver])
 238
 239         LINUX=${kernelsrc}
 240         LINUX_OBJ=${kernelbuild}
 241         LINUX_VERSION=${kernsrcver}
 242
 243         AC_SUBST(LINUX)
 244         AC_SUBST(LINUX_OBJ)
 245         AC_SUBST(LINUX_VERSION)
 246
 247         ZFS_AC_MODULE_SYMVERS
 248 ])
 249
 250
 251 dnl #
 252 dnl # Detect the SPL module to be built against
 253 dnl #
 254 AC_DEFUN([ZFS_AC_SPL], [
 255         AC_ARG_WITH([spl],
 256                 AS_HELP_STRING([--with-spl=PATH],
 257                 [Path to spl source]),
 258                 [splsrc="$withval"])
 259
 260         AC_ARG_WITH([spl-obj],
 261                 AS_HELP_STRING([--with-spl-obj=PATH],
 262                 [Path to spl build objects]),
 263                 [splbuild="$withval"])
 264
 265         AC_ARG_WITH([spl-timeout],
 266                 AS_HELP_STRING([--with-spl-timeout=SECS],
 267                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 268                 [timeout="$withval"], [timeout=0])
 269
 270         dnl #
 271         dnl # The existence of spl.release.in is used to identify a valid
 272         dnl # source directory.  In order of preference:
 273         dnl #
 274         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 275         splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 276         splsrc2="/usr/src/spl-${VERSION}"
 277         splsrc3="../spl/"
 278         splsrc4="$LINUX"
 279
 280         AC_MSG_CHECKING([spl source directory])
 281         AS_IF([test -z "${splsrc}"], [
 282                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 283                         splsrc=${splsrc0}
 284                 ], [ test -e "${splsrc1}/spl.release.in"], [
 285                         splsrc=${splsrc1}
 286                 ], [ test -e "${splsrc2}/spl.release.in"], [
 287                         splsrc=${splsrc2}
 288                 ], [ test -e "${splsrc3}/spl.release.in"], [
 289                         splsrc=$(readlink -f "${splsrc3}")
 290                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 291                         splsrc=${splsrc4}
 292                 ], [
 293                         splsrc="[Not found]"
 294                 ])
 295         ], [
 296                 AS_IF([test "$splsrc" = "NONE"], [
 297                         splbuild=NONE
 298                         splsrcver=NONE
 299                 ])
 300         ])
 301
 302         AC_MSG_RESULT([$splsrc])
 303         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 304                 AC_MSG_ERROR([
 305         *** Please make sure the kmod spl devel package for your distribution
 306         *** is installed then try again.  If that fails you can specify the
 307         *** location of the spl source with the '--with-spl=PATH' option.])
 308         ])
 309
 310         dnl #
 311         dnl # The existence of the spl_config.h is used to identify a valid
 312         dnl # spl object directory.  In many cases the object and source
 313         dnl # directory are the same, however the objects may also reside
 314         dnl # is a subdirectory named after the kernel version.
 315         dnl #
 316         dnl # This file is supposed to be available after DKMS finishes
 317         dnl # building the SPL kernel module for the target kernel.  The
 318         dnl # '--with-spl-timeout' option can be passed to pause here,
 319         dnl # waiting for the file to appear from a concurrently building
 320         dnl # SPL package.
 321         dnl #
 322         AC_MSG_CHECKING([spl build directory])
 323         while true; do
 324                 AS_IF([test -z "$splbuild"], [
 325                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 326                                 splbuild="${splsrc}/${LINUX_VERSION}"
 327                         ], [ test -e "${splsrc}/spl_config.h" ], [
 328                                 splbuild="${splsrc}"
 329                         ], [
 330                                 splbuild="[Not found]"
 331                         ])
 332                 ])
 333                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 334                         break;
 335                 ], [
 336                         sleep 1
 337                         timeout=$((timeout-1))
 338                 ])
 339         done
 340
 341         AC_MSG_RESULT([$splbuild])
 342         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 343                 AC_MSG_ERROR([
 344         *** Please make sure the kmod spl devel <kernel> package for your
 345         *** distribution is installed then try again.  If that fails you
 346         *** can specify the location of the spl objects with the
 347         *** '--with-spl-obj=PATH' option.])
 348         ])
 349
 350         AC_MSG_CHECKING([spl source version])
 351         AS_IF([test -r $splbuild/spl_config.h &&
 352                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 353
 354                 splsrcver=`(echo "#include <spl_config.h>";
 355                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 356                             cpp -I $splbuild |
 357                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 358         ])
 359
 360         AS_IF([test -z "$splsrcver"], [
 361                 AC_MSG_RESULT([Not found])
 362                 AC_MSG_ERROR([
 363         *** Cannot determine the version of the spl source.
 364         *** Please prepare the spl source before running this script])
 365         ])
 366
 367         AC_MSG_RESULT([$splsrcver])
 368
 369         SPL=${splsrc}
 370         SPL_OBJ=${splbuild}
 371         SPL_VERSION=${splsrcver}
 372
 373         AC_SUBST(SPL)
 374         AC_SUBST(SPL_OBJ)
 375         AC_SUBST(SPL_VERSION)
 376
 377         dnl #
 378         dnl # Detect the name used for the SPL Module.symvers file.  If one
 379         dnl # does not exist this is likely because the SPL has been configured
 380         dnl # but not built.  The '--with-spl-timeout' option can be passed
 381         dnl # to pause here, waiting for the file to appear from a concurrently
 382         dnl # building SPL package.  If the file does not appear in time, a good
 383         dnl # guess is made as to what this file will be named based on what it
 384         dnl # is named in the kernel build products.  This file will first be
 385         dnl # used at link time so if the guess is wrong the build will fail
 386         dnl # then.  This unfortunately means the ZFS package does not contain a
 387         dnl # reliable mechanism to detect symbols exported by the SPL at
 388         dnl # configure time.
 389         dnl #
 390         AC_MSG_CHECKING([spl file name for module symbols])
 391         SPL_SYMBOLS=NONE
 392
 393         while true; do
 394                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 395                         SPL_SYMBOLS=Module.symvers
 396                 ], [test -r $SPL_OBJ/Modules.symvers], [
 397                         SPL_SYMBOLS=Modules.symvers
 398                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 399                         SPL_SYMBOLS=Module.symvers
 400                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 401                         SPL_SYMBOLS=Modules.symvers
 402                 ])
 403
 404                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 405                         break;
 406                 ], [
 407                         sleep 1
 408                         timeout=$((timeout-1))
 409                 ])
 410         done
 411
 412         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 413                 SPL_SYMBOLS=$LINUX_SYMBOLS
 414         ])
 415
 416         AC_MSG_RESULT([$SPL_SYMBOLS])
 417         AC_SUBST(SPL_SYMBOLS)
 418 ])
 419
 420 dnl #
 421 dnl # Basic toolchain sanity check.
 422 dnl #
 423 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 424         AC_MSG_CHECKING([whether modules can be built])
 425         ZFS_LINUX_TRY_COMPILE([],[],[
 426                 AC_MSG_RESULT([yes])
 427         ],[
 428                 AC_MSG_RESULT([no])
 429                 if test "x$enable_linux_builtin" != xyes; then
 430                         AC_MSG_ERROR([*** Unable to build an empty module.])
 431                 else
 432                         AC_MSG_ERROR([
 433         *** Unable to build an empty module.
 434         *** Please run 'make scripts' inside the kernel source tree.])
 435                 fi
 436         ])
 437 ])
 438
 439 dnl #
 440 dnl # Certain kernel build options are not supported.  These must be
 441 dnl # detected at configure time and cause a build failure.  Otherwise
 442 dnl # modules may be successfully built that behave incorrectly.
 443 dnl #
 444 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 445         AC_RUN_IFELSE([
 446                 AC_LANG_PROGRAM([
 447                         #include "$LINUX/include/linux/license.h"
 448                 ], [
 449                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 450                 ])
 451         ], [
 452                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 453                     [Define to 1 if GPL-only symbols can be used])
 454         ], [
 455         ])
 456
 457         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 458 ])
 459
 460 dnl #
 461 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 462 dnl #
 463 dnl # This is typically only set for debug kernels because it comes with
 464 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 465 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 466 dnl # This will cause a failure at link time which we'd rather know about
 467 dnl # at compile time.
 468 dnl #
 469 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 470 dnl # with the upstream community we add a check to detect this case.
 471 dnl #
 472 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 473
 474         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 475                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 476                 tmp_flags="$EXTRA_KCFLAGS"
 477                 ZFS_LINUX_TRY_COMPILE([
 478                         #include <linux/module.h>
 479                         #include <linux/mutex.h>
 480
 481                         MODULE_LICENSE("$ZFS_META_LICENSE");
 482                 ],[
 483                         struct mutex lock;
 484
 485                         mutex_init(&lock);
 486                         mutex_lock(&lock);
 487                         mutex_unlock(&lock);
 488                 ],[
 489                         AC_MSG_RESULT(no)
 490                 ],[
 491                         AC_MSG_RESULT(yes)
 492                         AC_MSG_ERROR([
 493         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 494         *** with the CDDL license and will prevent the module linking stage
 495         *** from succeeding.  You must rebuild your kernel without this
 496         *** option enabled.])
 497                 ])
 498                 EXTRA_KCFLAGS="$tmp_flags"
 499         ], [])
 500 ])
 501
 502 dnl #
 503 dnl # ZFS_LINUX_CONFTEST
 504 dnl #
 505 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 506 cat confdefs.h - <<_ACEOF >conftest.c
 507 $1
 508 _ACEOF
 509 ])
 510
 511 dnl #
 512 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 513 dnl #
 514 m4_define([ZFS_LANG_PROGRAM], [
 515 $1
 516 int
 517 main (void)
 518 {
 519 dnl Do *not* indent the following line: there may be CPP directives.
 520 dnl Don't move the `;' right after for the same reason.
 521 $2
 522   ;
 523   return 0;
 524 }
 525 ])
 526
 527 dnl #
 528 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 529 dnl #
 530 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 531         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 532         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 533         echo "obj-m := conftest.o" >build/Makefile
 534         modpost_flag=''
 535         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 536         AS_IF(
 537                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 538                 [$4],
 539                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 540         )
 541         rm -Rf build
 542 ])
 543
 544 dnl #
 545 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 546 dnl #
 547 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 548         [ZFS_LINUX_COMPILE_IFELSE(
 549         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 550         [modules],
 551         [test -s build/conftest.o],
 552         [$3], [$4])
 553 ])
 554
 555 dnl #
 556 dnl # ZFS_LINUX_CONFIG
 557 dnl #
 558 AC_DEFUN([ZFS_LINUX_CONFIG],
 559         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 560         ZFS_LINUX_TRY_COMPILE([
 561                 #include <linux/module.h>
 562         ],[
 563                 #ifndef CONFIG_$1
 564                 #error CONFIG_$1 not #defined
 565                 #endif
 566         ],[
 567                 AC_MSG_RESULT([yes])
 568                 $2
 569         ],[
 570                 AC_MSG_RESULT([no])
 571                 $3
 572         ])
 573 ])
 574
 575 dnl #
 576 dnl # ZFS_CHECK_SYMBOL_EXPORT
 577 dnl # check symbol exported or not
 578 dnl #
 579 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 580         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 581                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 582         rc=$?
 583         if test $rc -ne 0; then
 584                 export=0
 585                 for file in $2; do
 586                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 587                                 "$LINUX/$file" 2>/dev/null
 588                         rc=$?
 589                         if test $rc -eq 0; then
 590                                 export=1
 591                                 break;
 592                         fi
 593                 done
 594                 if test $export -eq 0; then :
 595                         $4
 596                 else :
 597                         $3
 598                 fi
 599         else :
 600                 $3
 601         fi
 602 ])
 603
 604 dnl #
 605 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 606 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 607 dnl # is called if not compiling for builtin
 608 dnl #
 609 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 610         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 611         if test $rc -ne 0; then :
 612                 $6
 613         else
 614                 if test "x$enable_linux_builtin" != xyes; then
 615                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 616                 fi
 617                 if test $rc -ne 0; then :
 618                         $6
 619                 else :
 620                         $5
 621                 fi
 622         fi
 623 ])