config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  15         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  16         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  17         ZFS_AC_KERNEL_LOOKUP_BDEV
  18         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  19         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  20         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BIO_BVEC_ITER
  22         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  23         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  24         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  25         ZFS_AC_KERNEL_BIO_RW_BARRIER
  26         ZFS_AC_KERNEL_BIO_RW_DISCARD
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  31         ZFS_AC_KERNEL_GET_DISK_RO
  32         ZFS_AC_KERNEL_GET_GENDISK
  33         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  34         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  35         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  36         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  37         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  38         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  39         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  40         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  41         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  42         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  43         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  44         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  45         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  46         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  47         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  48         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  49         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  50         ZFS_AC_KERNEL_CURRENT_UMASK
  51         ZFS_AC_KERNEL_SHOW_OPTIONS
  52         ZFS_AC_KERNEL_FILE_INODE
  53         ZFS_AC_KERNEL_FSYNC
  54         ZFS_AC_KERNEL_EVICT_INODE
  55         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  56         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  57         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  58         ZFS_AC_KERNEL_FALLOCATE
  59         ZFS_AC_KERNEL_MKDIR_UMODE_T
  60         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  61         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  62         ZFS_AC_KERNEL_GET_LINK
  63         ZFS_AC_KERNEL_PUT_LINK
  64         ZFS_AC_KERNEL_TRUNCATE_RANGE
  65         ZFS_AC_KERNEL_AUTOMOUNT
  66         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  67         ZFS_AC_KERNEL_COMMIT_METADATA
  68         ZFS_AC_KERNEL_CLEAR_INODE
  69         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  70         ZFS_AC_KERNEL_D_MAKE_ROOT
  71         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  72         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  73         ZFS_AC_KERNEL_D_SET_D_OP
  74         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  75         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  76         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  77         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  78         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  79         ZFS_AC_KERNEL_MOUNT_NODEV
  80         ZFS_AC_KERNEL_SHRINK
  81         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  82         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  83         ZFS_AC_KERNEL_S_D_OP
  84         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  85         ZFS_AC_KERNEL_SET_NLINK
  86         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  87         ZFS_AC_KERNEL_5ARG_SGET
  88         ZFS_AC_KERNEL_LSEEK_EXECUTE
  89         ZFS_AC_KERNEL_VFS_ITERATE
  90         ZFS_AC_KERNEL_VFS_RW_ITERATE
  91         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  92         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
  93         ZFS_AC_KERNEL_MAKE_REQUEST_FN
  94         ZFS_AC_KERNEL_GENERIC_IO_ACCT
  95         ZFS_AC_KERNEL_FPU
  96         ZFS_AC_KERNEL_KUID_HELPERS
  97
  98         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  99                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 100         ])
 101         AC_SUBST(KERNELMAKE_PARAMS)
 102
 103
 104         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 105         dnl # compiler options are added by the kernel build system.
 106         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 107         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 108         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 109         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 110
 111         AC_SUBST(KERNELCPPFLAGS)
 112 ])
 113
 114 dnl #
 115 dnl # Detect name used for Module.symvers file in kernel
 116 dnl #
 117 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 118         modpost=$LINUX/scripts/Makefile.modpost
 119         AC_MSG_CHECKING([kernel file name for module symbols])
 120         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 121                 AS_IF([grep -q Modules.symvers $modpost], [
 122                         LINUX_SYMBOLS=Modules.symvers
 123                 ], [
 124                         LINUX_SYMBOLS=Module.symvers
 125                 ])
 126
 127                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 128                         AC_MSG_ERROR([
 129         *** Please make sure the kernel devel package for your distribution
 130         *** is installed.  If you are building with a custom kernel, make sure the
 131         *** kernel is configured, built, and the '--with-linux=PATH' configure
 132         *** option refers to the location of the kernel source.])
 133                 ])
 134         ], [
 135                 LINUX_SYMBOLS=NONE
 136         ])
 137         AC_MSG_RESULT($LINUX_SYMBOLS)
 138         AC_SUBST(LINUX_SYMBOLS)
 139 ])
 140
 141 dnl #
 142 dnl # Detect the kernel to be built against
 143 dnl #
 144 AC_DEFUN([ZFS_AC_KERNEL], [
 145         AC_ARG_WITH([linux],
 146                 AS_HELP_STRING([--with-linux=PATH],
 147                 [Path to kernel source]),
 148                 [kernelsrc="$withval"])
 149
 150         AC_ARG_WITH(linux-obj,
 151                 AS_HELP_STRING([--with-linux-obj=PATH],
 152                 [Path to kernel build objects]),
 153                 [kernelbuild="$withval"])
 154
 155         AC_MSG_CHECKING([kernel source directory])
 156         AS_IF([test -z "$kernelsrc"], [
 157                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 158                         headersdir="/lib/modules/$(uname -r)/source"
 159                         sourcelink=$(readlink -f "$headersdir")
 160                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 161                         headersdir="/lib/modules/$(uname -r)/build"
 162                         sourcelink=$(readlink -f "$headersdir")
 163                 ], [
 164                         sourcelink=$(ls -1d /usr/src/kernels/* \
 165                                      /usr/src/linux-* \
 166                                      2>/dev/null | grep -v obj | tail -1)
 167                 ])
 168
 169                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 170                         kernelsrc=`readlink -f ${sourcelink}`
 171                 ], [
 172                         kernelsrc="[Not found]"
 173                 ])
 174         ], [
 175                 AS_IF([test "$kernelsrc" = "NONE"], [
 176                         kernsrcver=NONE
 177                 ])
 178         ])
 179
 180         AC_MSG_RESULT([$kernelsrc])
 181         AS_IF([test ! -d "$kernelsrc"], [
 182                 AC_MSG_ERROR([
 183         *** Please make sure the kernel devel package for your distribution
 184         *** is installed and then try again.  If that fails, you can specify the
 185         *** location of the kernel source with the '--with-linux=PATH' option.])
 186         ])
 187
 188         AC_MSG_CHECKING([kernel build directory])
 189         AS_IF([test -z "$kernelbuild"], [
 190                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 191                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 192                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 193                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 194                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 195                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 196                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 197                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 198                 ], [
 199                         kernelbuild=${kernelsrc}
 200                 ])
 201         ])
 202         AC_MSG_RESULT([$kernelbuild])
 203
 204         AC_MSG_CHECKING([kernel source version])
 205         utsrelease1=$kernelbuild/include/linux/version.h
 206         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 207         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 208         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 209                 utsrelease=linux/version.h
 210         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 211                 utsrelease=linux/utsrelease.h
 212         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 213                 utsrelease=generated/utsrelease.h
 214         ])
 215
 216         AS_IF([test "$utsrelease"], [
 217                 kernsrcver=`(echo "#include <$utsrelease>";
 218                              echo "kernsrcver=UTS_RELEASE") |
 219                              cpp -I $kernelbuild/include |
 220                              grep "^kernsrcver=" | cut -d \" -f 2`
 221
 222                 AS_IF([test -z "$kernsrcver"], [
 223                         AC_MSG_RESULT([Not found])
 224                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 225                 ])
 226         ], [
 227                 AC_MSG_RESULT([Not found])
 228                 if test "x$enable_linux_builtin" != xyes; then
 229                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 230                 else
 231                         AC_MSG_ERROR([
 232         *** Cannot find UTS_RELEASE definition.
 233         *** Please run 'make prepare' inside the kernel source tree.])
 234                 fi
 235         ])
 236
 237         AC_MSG_RESULT([$kernsrcver])
 238
 239         LINUX=${kernelsrc}
 240         LINUX_OBJ=${kernelbuild}
 241         LINUX_VERSION=${kernsrcver}
 242
 243         AC_SUBST(LINUX)
 244         AC_SUBST(LINUX_OBJ)
 245         AC_SUBST(LINUX_VERSION)
 246
 247         ZFS_AC_MODULE_SYMVERS
 248 ])
 249
 250
 251 dnl #
 252 dnl # Detect the SPL module to be built against
 253 dnl #
 254 AC_DEFUN([ZFS_AC_SPL], [
 255         AC_ARG_WITH([spl],
 256                 AS_HELP_STRING([--with-spl=PATH],
 257                 [Path to spl source]),
 258                 AS_IF([test "$withval" = "yes"],
 259                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 260                         [splsrc="$withval"]))
 261
 262         AC_ARG_WITH([spl-obj],
 263                 AS_HELP_STRING([--with-spl-obj=PATH],
 264                 [Path to spl build objects]),
 265                 [splbuild="$withval"])
 266
 267         AC_ARG_WITH([spl-timeout],
 268                 AS_HELP_STRING([--with-spl-timeout=SECS],
 269                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 270                 [timeout="$withval"], [timeout=0])
 271
 272         dnl #
 273         dnl # The existence of spl.release.in is used to identify a valid
 274         dnl # source directory.  In order of preference:
 275         dnl #
 276         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 277         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 278         splsrc2="/usr/local/src/spl-${VERSION}"
 279         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 280         splsrc4="/usr/src/spl-${VERSION}"
 281         splsrc5="../spl/"
 282         splsrc6="$LINUX"
 283
 284         AC_MSG_CHECKING([spl source directory])
 285         AS_IF([test -z "${splsrc}"], [
 286                 [all_spl_sources="
 287                 ${splsrc0}
 288                 ${splsrc1}
 289                 ${splsrc2}
 290                 ${splsrc3}
 291                 ${splsrc4}
 292                 ${splsrc5}
 293                 ${splsrc6}"],
 294                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 295                         splsrc=${splsrc0}
 296                 ], [ test -e "${splsrc1}/spl.release.in"], [
 297                         splsrc=${splsrc1}
 298                 ], [ test -e "${splsrc2}/spl.release.in"], [
 299                         splsrc=${splsrc2}
 300                 ], [ test -e "${splsrc3}/spl.release.in"], [
 301                         splsrc=$(readlink -f "${splsrc3}")
 302                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 303                         splsrc=${splsrc4}
 304                 ], [ test -e "${splsrc5}/spl.release.in"], [
 305                         splsrc=$(readlink -f "${splsrc5}")
 306                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 307                         splsrc=${splsrc6}
 308                 ], [
 309                         splsrc="[Not found]"
 310                 ])
 311         ], [
 312                 [all_spl_sources="$withval"],
 313                 AS_IF([test "$splsrc" = "NONE"], [
 314                         splbuild=NONE
 315                         splsrcver=NONE
 316                 ])
 317         ])
 318
 319         AC_MSG_RESULT([$splsrc])
 320         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 321                 AC_MSG_ERROR([
 322         *** Please make sure the kmod spl devel package for your distribution
 323         *** is installed then try again.  If that fails you can specify the
 324         *** location of the spl source with the '--with-spl=PATH' option.
 325         *** The spl version must match the version of ZFS you are building,
 326         *** ${VERSION}.  Failed to find spl.release.in in the following:
 327         $all_spl_sources])
 328         ])
 329
 330         dnl #
 331         dnl # The existence of the spl_config.h is used to identify a valid
 332         dnl # spl object directory.  In many cases the object and source
 333         dnl # directory are the same, however the objects may also reside
 334         dnl # is a subdirectory named after the kernel version.
 335         dnl #
 336         dnl # This file is supposed to be available after DKMS finishes
 337         dnl # building the SPL kernel module for the target kernel.  The
 338         dnl # '--with-spl-timeout' option can be passed to pause here,
 339         dnl # waiting for the file to appear from a concurrently building
 340         dnl # SPL package.
 341         dnl #
 342         AC_MSG_CHECKING([spl build directory])
 343
 344         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 345         ${splsrc}"
 346
 347         while true; do
 348                 AS_IF([test -z "$splbuild"], [
 349                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 350                                 splbuild="${splsrc}/${LINUX_VERSION}"
 351                         ], [ test -e "${splsrc}/spl_config.h" ], [
 352                                 splbuild="${splsrc}"
 353                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 354                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 355                         ], [
 356                                 splbuild="[Not found]"
 357                         ])
 358                 ])
 359                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 360                         break;
 361                 ], [
 362                         sleep 1
 363                         timeout=$((timeout-1))
 364                 ])
 365         done
 366
 367         AC_MSG_RESULT([$splbuild])
 368         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 369                 AC_MSG_ERROR([
 370         *** Please make sure the kmod spl devel <kernel> package for your
 371         *** distribution is installed then try again.  If that fails you
 372         *** can specify the location of the spl objects with the
 373         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 374         *** any of the following:
 375         $all_spl_config_locs])
 376         ])
 377
 378         AC_MSG_CHECKING([spl source version])
 379         AS_IF([test -r $splbuild/spl_config.h &&
 380                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 381
 382                 splsrcver=`(echo "#include <spl_config.h>";
 383                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 384                             cpp -I $splbuild |
 385                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 386         ])
 387
 388         AS_IF([test -z "$splsrcver"], [
 389                 AC_MSG_RESULT([Not found])
 390                 AC_MSG_ERROR([
 391         *** Cannot determine the version of the spl source.
 392         *** Please prepare the spl source before running this script])
 393         ])
 394
 395         AC_MSG_RESULT([$splsrcver])
 396
 397         SPL=${splsrc}
 398         SPL_OBJ=${splbuild}
 399         SPL_VERSION=${splsrcver}
 400
 401         AC_SUBST(SPL)
 402         AC_SUBST(SPL_OBJ)
 403         AC_SUBST(SPL_VERSION)
 404
 405         dnl #
 406         dnl # Detect the name used for the SPL Module.symvers file.  If one
 407         dnl # does not exist this is likely because the SPL has been configured
 408         dnl # but not built.  The '--with-spl-timeout' option can be passed
 409         dnl # to pause here, waiting for the file to appear from a concurrently
 410         dnl # building SPL package.  If the file does not appear in time, a good
 411         dnl # guess is made as to what this file will be named based on what it
 412         dnl # is named in the kernel build products.  This file will first be
 413         dnl # used at link time so if the guess is wrong the build will fail
 414         dnl # then.  This unfortunately means the ZFS package does not contain a
 415         dnl # reliable mechanism to detect symbols exported by the SPL at
 416         dnl # configure time.
 417         dnl #
 418         AC_MSG_CHECKING([spl file name for module symbols])
 419         SPL_SYMBOLS=NONE
 420
 421         while true; do
 422                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 423                         SPL_SYMBOLS=Module.symvers
 424                 ], [test -r $SPL_OBJ/Modules.symvers], [
 425                         SPL_SYMBOLS=Modules.symvers
 426                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 427                         SPL_SYMBOLS=Module.symvers
 428                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 429                         SPL_SYMBOLS=Modules.symvers
 430                 ])
 431
 432                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 433                         break;
 434                 ], [
 435                         sleep 1
 436                         timeout=$((timeout-1))
 437                 ])
 438         done
 439
 440         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 441                 SPL_SYMBOLS=$LINUX_SYMBOLS
 442         ])
 443
 444         AC_MSG_RESULT([$SPL_SYMBOLS])
 445         AC_SUBST(SPL_SYMBOLS)
 446 ])
 447
 448 dnl #
 449 dnl # Basic toolchain sanity check.
 450 dnl #
 451 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 452         AC_MSG_CHECKING([whether modules can be built])
 453         ZFS_LINUX_TRY_COMPILE([],[],[
 454                 AC_MSG_RESULT([yes])
 455         ],[
 456                 AC_MSG_RESULT([no])
 457                 if test "x$enable_linux_builtin" != xyes; then
 458                         AC_MSG_ERROR([*** Unable to build an empty module.])
 459                 else
 460                         AC_MSG_ERROR([
 461         *** Unable to build an empty module.
 462         *** Please run 'make scripts' inside the kernel source tree.])
 463                 fi
 464         ])
 465 ])
 466
 467 dnl #
 468 dnl # Certain kernel build options are not supported.  These must be
 469 dnl # detected at configure time and cause a build failure.  Otherwise
 470 dnl # modules may be successfully built that behave incorrectly.
 471 dnl #
 472 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 473         AS_IF([test "x$cross_compiling" != xyes], [
 474                 AC_RUN_IFELSE([
 475                         AC_LANG_PROGRAM([
 476                                 #include "$LINUX/include/linux/license.h"
 477                         ], [
 478                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 479                         ])
 480                 ], [
 481                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 482                             [Define to 1 if GPL-only symbols can be used])
 483                 ], [
 484                 ])
 485         ])
 486
 487         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 488         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 489 ])
 490
 491 dnl #
 492 dnl # Check configured THREAD_SIZE
 493 dnl #
 494 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 495 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 496 dnl # on newer kernels and some architectures stack usage optimizations can be
 497 dnl # conditionally applied to improve performance without negatively impacting
 498 dnl # stability.
 499 dnl #
 500 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 501         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 502         ZFS_LINUX_TRY_COMPILE([
 503                 #include <linux/module.h>
 504         ],[
 505                 #if (THREAD_SIZE < 16384)
 506                 #error "THREAD_SIZE is less than 16K"
 507                 #endif
 508         ],[
 509                 AC_MSG_RESULT([yes])
 510                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 511         ],[
 512                 AC_MSG_RESULT([no])
 513         ])
 514 ])
 515
 516 dnl #
 517 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 518 dnl #
 519 dnl # This is typically only set for debug kernels because it comes with
 520 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 521 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 522 dnl # This will cause a failure at link time which we'd rather know about
 523 dnl # at compile time.
 524 dnl #
 525 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 526 dnl # with the upstream community we add a check to detect this case.
 527 dnl #
 528 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 529
 530         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 531                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 532                 tmp_flags="$EXTRA_KCFLAGS"
 533                 ZFS_LINUX_TRY_COMPILE([
 534                         #include <linux/module.h>
 535                         #include <linux/mutex.h>
 536
 537                         MODULE_LICENSE("$ZFS_META_LICENSE");
 538                 ],[
 539                         struct mutex lock;
 540
 541                         mutex_init(&lock);
 542                         mutex_lock(&lock);
 543                         mutex_unlock(&lock);
 544                 ],[
 545                         AC_MSG_RESULT(no)
 546                 ],[
 547                         AC_MSG_RESULT(yes)
 548                         AC_MSG_ERROR([
 549         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 550         *** with the CDDL license and will prevent the module linking stage
 551         *** from succeeding.  You must rebuild your kernel without this
 552         *** option enabled.])
 553                 ])
 554                 EXTRA_KCFLAGS="$tmp_flags"
 555         ], [])
 556 ])
 557
 558 dnl #
 559 dnl # ZFS_LINUX_CONFTEST_H
 560 dnl #
 561 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 562 cat - <<_ACEOF >conftest.h
 563 $1
 564 _ACEOF
 565 ])
 566
 567 dnl #
 568 dnl # ZFS_LINUX_CONFTEST_C
 569 dnl #
 570 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 571 cat confdefs.h - <<_ACEOF >conftest.c
 572 $1
 573 _ACEOF
 574 ])
 575
 576 dnl #
 577 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 578 dnl #
 579 m4_define([ZFS_LANG_PROGRAM], [
 580 $1
 581 int
 582 main (void)
 583 {
 584 dnl Do *not* indent the following line: there may be CPP directives.
 585 dnl Don't move the `;' right after for the same reason.
 586 $2
 587   ;
 588   return 0;
 589 }
 590 ])
 591
 592 dnl #
 593 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 594 dnl #
 595 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 596         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 597         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 598         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 599         echo "obj-m := conftest.o" >build/Makefile
 600         modpost_flag=''
 601         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 602         AS_IF(
 603                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 604                 [$4],
 605                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 606         )
 607         rm -Rf build
 608 ])
 609
 610 dnl #
 611 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 612 dnl #
 613 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 614         [ZFS_LINUX_COMPILE_IFELSE(
 615         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 616         [modules],
 617         [test -s build/conftest.o],
 618         [$3], [$4])
 619 ])
 620
 621 dnl #
 622 dnl # ZFS_LINUX_CONFIG
 623 dnl #
 624 AC_DEFUN([ZFS_LINUX_CONFIG],
 625         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 626         ZFS_LINUX_TRY_COMPILE([
 627                 #include <linux/module.h>
 628         ],[
 629                 #ifndef CONFIG_$1
 630                 #error CONFIG_$1 not #defined
 631                 #endif
 632         ],[
 633                 AC_MSG_RESULT([yes])
 634                 $2
 635         ],[
 636                 AC_MSG_RESULT([no])
 637                 $3
 638         ])
 639 ])
 640
 641 dnl #
 642 dnl # ZFS_CHECK_SYMBOL_EXPORT
 643 dnl # check symbol exported or not
 644 dnl #
 645 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 646         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 647                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 648         rc=$?
 649         if test $rc -ne 0; then
 650                 export=0
 651                 for file in $2; do
 652                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 653                                 "$LINUX/$file" 2>/dev/null
 654                         rc=$?
 655                         if test $rc -eq 0; then
 656                                 export=1
 657                                 break;
 658                         fi
 659                 done
 660                 if test $export -eq 0; then :
 661                         $4
 662                 else :
 663                         $3
 664                 fi
 665         else :
 666                 $3
 667         fi
 668 ])
 669
 670 dnl #
 671 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 672 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 673 dnl # is called if not compiling for builtin
 674 dnl #
 675 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 676         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 677         if test $rc -ne 0; then :
 678                 $6
 679         else
 680                 if test "x$enable_linux_builtin" != xyes; then
 681                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 682                 fi
 683                 if test $rc -ne 0; then :
 684                         $6
 685                 else :
 686                         $5
 687                 fi
 688         fi
 689 ])
 690
 691 dnl #
 692 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 693 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 694 dnl # provided via the fifth parameter
 695 dnl #
 696 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 697         [ZFS_LINUX_COMPILE_IFELSE(
 698         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 699         [modules],
 700         [test -s build/conftest.o],
 701         [$3], [$4], [$5])
 702 ])