config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  15
  16         KERNEL_DEBUG_CFLAGS="-Werror"
  17         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  18 ])
  19
  20 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  21         DEBUG_CFLAGS=""
  22         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  23         DEBUG_LDFLAGS=""
  24         DEBUG_ZFS="_without_debug"
  25
  26         KERNEL_DEBUG_CFLAGS=""
  27         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  28 ])
  29
  30 dnl #
  31 dnl # When debugging is enabled:
  32 dnl # - Enable all ASSERTs (-DDEBUG)
  33 dnl # - Promote all compiler warnings to errors (-Werror)
  34 dnl #
  35 AC_DEFUN([ZFS_AC_DEBUG], [
  36         AC_MSG_CHECKING([whether assertion support will be enabled])
  37         AC_ARG_ENABLE([debug],
  38                 [AS_HELP_STRING([--enable-debug],
  39                 [Enable compiler and code assertions @<:@default=no@:>@])],
  40                 [],
  41                 [enable_debug=no])
  42
  43         AS_CASE(["x$enable_debug"],
  44                 ["xyes"],
  45                 [ZFS_AC_DEBUG_ENABLE],
  46                 ["xno"],
  47                 [ZFS_AC_DEBUG_DISABLE],
  48                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  49
  50         AC_SUBST(DEBUG_CFLAGS)
  51         AC_SUBST(DEBUG_CPPFLAGS)
  52         AC_SUBST(DEBUG_LDFLAGS)
  53         AC_SUBST(DEBUG_ZFS)
  54
  55         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  56         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  57
  58         AC_MSG_RESULT([$enable_debug])
  59 ])
  60
  61 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  62         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
  63
  64         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $NO_IPA_SRA"
  65         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  66
  67         DEBUGINFO_ZFS="_with_debuginfo"
  68 ])
  69
  70 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  71         DEBUGINFO_ZFS="_without_debuginfo"
  72 ])
  73
  74 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  75         AC_MSG_CHECKING([whether debuginfo support will be forced])
  76         AC_ARG_ENABLE([debuginfo],
  77                 [AS_HELP_STRING([--enable-debuginfo],
  78                 [Force generation of debuginfo @<:@default=no@:>@])],
  79                 [],
  80                 [enable_debuginfo=no])
  81
  82         AS_CASE(["x$enable_debuginfo"],
  83                 ["xyes"],
  84                 [ZFS_AC_DEBUGINFO_ENABLE],
  85                 ["xno"],
  86                 [ZFS_AC_DEBUGINFO_DISABLE],
  87                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
  88
  89         AC_SUBST(DEBUG_CFLAGS)
  90         AC_SUBST(DEBUGINFO_ZFS)
  91
  92         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  93         AC_SUBST(KERNEL_MAKE)
  94
  95         AC_MSG_RESULT([$enable_debuginfo])
  96 ])
  97
  98 dnl #
  99 dnl # Disabled by default, provides basic memory tracking.  Track the total
 100 dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
 101 dnl # Then at module unload time if any bytes were leaked it will be reported
 102 dnl # on the console.
 103 dnl #
 104 AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
 105         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 106         AC_ARG_ENABLE([debug-kmem],
 107                 [AS_HELP_STRING([--enable-debug-kmem],
 108                 [Enable basic kmem accounting @<:@default=no@:>@])],
 109                 [],
 110                 [enable_debug_kmem=no])
 111
 112         AS_IF([test "x$enable_debug_kmem" = xyes], [
 113                 KERNEL_DEBUG_CPPFLAGS+=" -DDEBUG_KMEM"
 114                 DEBUG_KMEM_ZFS="_with_debug_kmem"
 115         ], [
 116                 DEBUG_KMEM_ZFS="_without_debug_kmem"
 117         ])
 118
 119         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 120         AC_SUBST(DEBUG_KMEM_ZFS)
 121
 122         AC_MSG_RESULT([$enable_debug_kmem])
 123 ])
 124
 125 dnl #
 126 dnl # Disabled by default, provides detailed memory tracking.  This feature
 127 dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
 128 dnl # total bytes be tracked but also the location of every kmem_alloc() and
 129 dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
 130 dnl # and where they were allocated will be dumped to the console.  Enabling
 131 dnl # this feature has a significant impact on performance but it makes finding
 132 dnl # memory leaks straight forward.
 133 dnl #
 134 AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
 135         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 136         AC_ARG_ENABLE([debug-kmem-tracking],
 137                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 138                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 139                 [],
 140                 [enable_debug_kmem_tracking=no])
 141
 142         AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
 143                 KERNEL_DEBUG_CPPFLAGS+=" -DDEBUG_KMEM_TRACKING"
 144                 DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
 145         ], [
 146                 DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
 147         ])
 148
 149         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 150         AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
 151
 152         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 153 ])
 154
 155 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 156         ZFS_AC_CONFIG_ALWAYS_CC_NO_UNUSED_BUT_SET_VARIABLE
 157         ZFS_AC_CONFIG_ALWAYS_CC_NO_BOOL_COMPARE
 158         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 159         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 160         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
 161         ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
 162         ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
 163         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 164         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 165         ZFS_AC_CONFIG_ALWAYS_SYSTEM
 166         ZFS_AC_CONFIG_ALWAYS_ARCH
 167         ZFS_AC_CONFIG_ALWAYS_PYTHON
 168         ZFS_AC_CONFIG_ALWAYS_PYZFS
 169         ZFS_AC_CONFIG_ALWAYS_SED
 170 ])
 171
 172 AC_DEFUN([ZFS_AC_CONFIG], [
 173
 174         dnl # Remove the previous build test directory.
 175         rm -Rf build
 176
 177         ZFS_CONFIG=all
 178         AC_ARG_WITH([config],
 179                 AS_HELP_STRING([--with-config=CONFIG],
 180                 [Config file 'kernel|user|all|srpm']),
 181                 [ZFS_CONFIG="$withval"])
 182         AC_ARG_ENABLE([linux-builtin],
 183                 [AC_HELP_STRING([--enable-linux-builtin],
 184                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 185                 [],
 186                 [enable_linux_builtin=no])
 187
 188         AC_MSG_CHECKING([zfs config])
 189         AC_MSG_RESULT([$ZFS_CONFIG]);
 190         AC_SUBST(ZFS_CONFIG)
 191
 192         ZFS_AC_CONFIG_ALWAYS
 193
 194
 195         AM_COND_IF([BUILD_LINUX], [
 196                 AC_ARG_VAR([TEST_JOBS],
 197                     [simultaneous jobs during configure (defaults to $(nproc))])
 198                 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 199                         TEST_JOBS=$(nproc)
 200                 fi
 201                 AC_SUBST(TEST_JOBS)
 202         ])
 203
 204         case "$ZFS_CONFIG" in
 205                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 206                 user)   ZFS_AC_CONFIG_USER   ;;
 207                 all)    ZFS_AC_CONFIG_USER
 208                         ZFS_AC_CONFIG_KERNEL ;;
 209                 srpm)                        ;;
 210                 *)
 211                 AC_MSG_RESULT([Error!])
 212                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 213                               user kernel|user|all|srpm]) ;;
 214         esac
 215
 216         AM_CONDITIONAL([CONFIG_USER],
 217             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 218         AM_CONDITIONAL([CONFIG_KERNEL],
 219             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 220             [test "x$enable_linux_builtin" != xyes ])
 221         AM_CONDITIONAL([CONFIG_QAT],
 222             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 223             [test "x$qatsrc" != x ])
 224         AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
 225         AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
 226 ])
 227
 228 dnl #
 229 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 230 dnl # are missing it is non-fatal but you will not be able to build
 231 dnl # RPM packages and will be warned if you try too.
 232 dnl #
 233 dnl # By default the generic spec file will be used because it requires
 234 dnl # minimal dependencies.  Distribution specific spec files can be
 235 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 236 dnl # the --with-spec=<distribution> configure option.
 237 dnl #
 238 AC_DEFUN([ZFS_AC_RPM], [
 239         RPM=rpm
 240         RPMBUILD=rpmbuild
 241
 242         AC_MSG_CHECKING([whether $RPM is available])
 243         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 244                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 245                 HAVE_RPM=yes
 246                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 247         ],[
 248                 HAVE_RPM=no
 249                 AC_MSG_RESULT([$HAVE_RPM])
 250         ])
 251
 252         AC_MSG_CHECKING([whether $RPMBUILD is available])
 253         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 254                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 255                 HAVE_RPMBUILD=yes
 256                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 257         ],[
 258                 HAVE_RPMBUILD=no
 259                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 260         ])
 261
 262         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 263         RPM_DEFINE_COMMON+=' --define "$(DEBUG_KMEM_ZFS) 1"'
 264         RPM_DEFINE_COMMON+=' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
 265         RPM_DEFINE_COMMON+=' --define "$(DEBUGINFO_ZFS) 1"'
 266         RPM_DEFINE_COMMON+=' --define "$(ASAN_ZFS) 1"'
 267
 268         RPM_DEFINE_UTIL=' --define "_initconfdir $(DEFAULT_INITCONF_DIR)"'
 269
 270         dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
 271         dnl # their values may not be set when running:
 272         dnl #
 273         dnl #   ./configure --with-config=srpm
 274         dnl #
 275         AS_IF([test -n "$dracutdir" ], [
 276                 RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)"'
 277         ])
 278         AS_IF([test -n "$udevdir" ], [
 279                 RPM_DEFINE_UTIL+=' --define "_udevdir $(udevdir)"'
 280         ])
 281         AS_IF([test -n "$udevruledir" ], [
 282                 RPM_DEFINE_UTIL+=' --define "_udevdir $(udevruledir)"'
 283         ])
 284         RPM_DEFINE_UTIL+=' $(DEFINE_INITRAMFS)'
 285         RPM_DEFINE_UTIL+=' $(DEFINE_SYSTEMD)'
 286         RPM_DEFINE_UTIL+=' $(DEFINE_PYZFS)'
 287         RPM_DEFINE_UTIL+=' $(DEFINE_PYTHON_VERSION)'
 288         RPM_DEFINE_UTIL+=' $(DEFINE_PYTHON_PKG_VERSION)'
 289
 290         dnl # Override default lib directory on Debian/Ubuntu systems.  The
 291         dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
 292         dnl # specify the correct path for multiarch systems as described
 293         dnl # by the packaging guidelines.
 294         dnl #
 295         dnl # https://wiki.ubuntu.com/MultiarchSpec
 296         dnl # https://wiki.debian.org/Multiarch/Implementation
 297         dnl #
 298         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 299                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 300                 RPM_DEFINE_UTIL+=' --define "_lib $(MULTIARCH_LIBDIR)"'
 301                 AC_SUBST(MULTIARCH_LIBDIR)
 302         ])
 303
 304         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 305         RPM_DEFINE_KMOD+=' --define "ksrc $(LINUX)"'
 306         RPM_DEFINE_KMOD+=' --define "kobj $(LINUX_OBJ)"'
 307         RPM_DEFINE_KMOD+=' --define "_wrong_version_format_terminate_build 0"'
 308
 309         RPM_DEFINE_DKMS=''
 310
 311         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 312         SRPM_DEFINE_UTIL=
 313         SRPM_DEFINE_KMOD=
 314         SRPM_DEFINE_DKMS=
 315
 316         RPM_SPEC_DIR="rpm/generic"
 317         AC_ARG_WITH([spec],
 318                 AS_HELP_STRING([--with-spec=SPEC],
 319                 [Spec files 'generic|redhat']),
 320                 [RPM_SPEC_DIR="rpm/$withval"])
 321
 322         AC_MSG_CHECKING([whether spec files are available])
 323         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 324
 325         AC_SUBST(HAVE_RPM)
 326         AC_SUBST(RPM)
 327         AC_SUBST(RPM_VERSION)
 328
 329         AC_SUBST(HAVE_RPMBUILD)
 330         AC_SUBST(RPMBUILD)
 331         AC_SUBST(RPMBUILD_VERSION)
 332
 333         AC_SUBST(RPM_SPEC_DIR)
 334         AC_SUBST(RPM_DEFINE_UTIL)
 335         AC_SUBST(RPM_DEFINE_KMOD)
 336         AC_SUBST(RPM_DEFINE_DKMS)
 337         AC_SUBST(RPM_DEFINE_COMMON)
 338         AC_SUBST(SRPM_DEFINE_UTIL)
 339         AC_SUBST(SRPM_DEFINE_KMOD)
 340         AC_SUBST(SRPM_DEFINE_DKMS)
 341         AC_SUBST(SRPM_DEFINE_COMMON)
 342 ])
 343
 344 dnl #
 345 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 346 dnl # tools are missing it is non-fatal but you will not be able to build
 347 dnl # DEB packages and will be warned if you try too.
 348 dnl #
 349 AC_DEFUN([ZFS_AC_DPKG], [
 350         DPKG=dpkg
 351         DPKGBUILD=dpkg-buildpackage
 352
 353         AC_MSG_CHECKING([whether $DPKG is available])
 354         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 355                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 356                 HAVE_DPKG=yes
 357                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 358         ],[
 359                 HAVE_DPKG=no
 360                 AC_MSG_RESULT([$HAVE_DPKG])
 361         ])
 362
 363         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 364         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 365                 DPKGBUILD_VERSION=$(echo $tmp | \
 366                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 367                 HAVE_DPKGBUILD=yes
 368                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 369         ],[
 370                 HAVE_DPKGBUILD=no
 371                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 372         ])
 373
 374         AC_SUBST(HAVE_DPKG)
 375         AC_SUBST(DPKG)
 376         AC_SUBST(DPKG_VERSION)
 377
 378         AC_SUBST(HAVE_DPKGBUILD)
 379         AC_SUBST(DPKGBUILD)
 380         AC_SUBST(DPKGBUILD_VERSION)
 381 ])
 382
 383 dnl #
 384 dnl # Until native packaging for various different packing systems
 385 dnl # can be added the least we can do is attempt to use alien to
 386 dnl # convert the RPM packages to the needed package type.  This is
 387 dnl # a hack but so far it has worked reasonable well.
 388 dnl #
 389 AC_DEFUN([ZFS_AC_ALIEN], [
 390         ALIEN=alien
 391
 392         AC_MSG_CHECKING([whether $ALIEN is available])
 393         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 394                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 395                 HAVE_ALIEN=yes
 396                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 397         ],[
 398                 HAVE_ALIEN=no
 399                 AC_MSG_RESULT([$HAVE_ALIEN])
 400         ])
 401
 402         AC_SUBST(HAVE_ALIEN)
 403         AC_SUBST(ALIEN)
 404         AC_SUBST(ALIEN_VERSION)
 405 ])
 406
 407 dnl #
 408 dnl # Using the VENDOR tag from config.guess set the default
 409 dnl # package type for 'make pkg': (rpm | deb | tgz)
 410 dnl #
 411 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 412         AC_MSG_CHECKING([os distribution])
 413         if test -f /etc/toss-release ; then
 414                 VENDOR=toss ;
 415         elif test -f /etc/fedora-release ; then
 416                 VENDOR=fedora ;
 417         elif test -f /etc/redhat-release ; then
 418                 VENDOR=redhat ;
 419         elif test -f /etc/gentoo-release ; then
 420                 VENDOR=gentoo ;
 421         elif test -f /etc/arch-release ; then
 422                 VENDOR=arch ;
 423         elif test -f /etc/SuSE-release ; then
 424                 VENDOR=sles ;
 425         elif test -f /etc/slackware-version ; then
 426                 VENDOR=slackware ;
 427         elif test -f /etc/lunar.release ; then
 428                 VENDOR=lunar ;
 429         elif test -f /etc/lsb-release ; then
 430                 VENDOR=ubuntu ;
 431         elif test -f /etc/debian_version ; then
 432                 VENDOR=debian ;
 433         elif test -f /etc/alpine-release ; then
 434                 VENDOR=alpine ;
 435         elif test -f /bin/freebsd-version ; then
 436                 VENDOR=freebsd ;
 437         else
 438                 VENDOR= ;
 439         fi
 440         AC_MSG_RESULT([$VENDOR])
 441         AC_SUBST(VENDOR)
 442
 443         AC_MSG_CHECKING([default package type])
 444         case "$VENDOR" in
 445                 toss)       DEFAULT_PACKAGE=rpm  ;;
 446                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 447                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 448                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 449                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 450                 arch)       DEFAULT_PACKAGE=tgz  ;;
 451                 sles)       DEFAULT_PACKAGE=rpm  ;;
 452                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 453                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 454                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 455                 debian)     DEFAULT_PACKAGE=deb  ;;
 456                 freebsd)    DEFAULT_PACKAGE=pkg  ;;
 457                 *)          DEFAULT_PACKAGE=rpm  ;;
 458         esac
 459         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 460         AC_SUBST(DEFAULT_PACKAGE)
 461
 462         AC_MSG_CHECKING([default init directory])
 463         case "$VENDOR" in
 464                 freebsd)    DEFAULT_INIT_DIR=$sysconfdir/rc.d  ;;
 465                 *)          DEFAULT_INIT_DIR=$sysconfdir/init.d;;
 466         esac
 467         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 468         AC_SUBST(DEFAULT_INIT_DIR)
 469
 470         AC_MSG_CHECKING([default init script type])
 471         case "$VENDOR" in
 472                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 473                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 474                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 475                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 476                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 477                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 478                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 479                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 480                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 481                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 482                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 483                 freebsd)    DEFAULT_INIT_SCRIPT=freebsd;;
 484                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 485         esac
 486         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 487         AC_SUBST(DEFAULT_INIT_SCRIPT)
 488
 489         AC_MSG_CHECKING([default init config directory])
 490         case "$VENDOR" in
 491                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 492                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 493                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 494                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 495                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 496                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 497                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 498                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 499                 freebsd)    DEFAULT_INITCONF_DIR=$sysconfdir/rc.conf.d;;
 500                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 501         esac
 502         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 503         AC_SUBST(DEFAULT_INITCONF_DIR)
 504
 505         AC_MSG_CHECKING([whether initramfs-tools is available])
 506         if test -d /usr/share/initramfs-tools ; then
 507                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 508                 AC_MSG_RESULT([yes])
 509         else
 510                 DEFINE_INITRAMFS=''
 511                 AC_MSG_RESULT([no])
 512         fi
 513         AC_SUBST(DEFINE_INITRAMFS)
 514 ])
 515
 516 dnl #
 517 dnl # Default ZFS package configuration
 518 dnl #
 519 AC_DEFUN([ZFS_AC_PACKAGE], [
 520         ZFS_AC_DEFAULT_PACKAGE
 521         AS_IF([test x$VENDOR != xfreebsd], [
 522                 ZFS_AC_RPM
 523                 ZFS_AC_DPKG
 524                 ZFS_AC_ALIEN
 525         ])
 526 ])