config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         WITH_DEBUG="true"
  15         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  16
  17         KERNEL_DEBUG_CFLAGS="-Werror"
  18         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  19 ])
  20
  21 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  22         DEBUG_CFLAGS=""
  23         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  24         DEBUG_LDFLAGS=""
  25         DEBUG_ZFS="_without_debug"
  26         WITH_DEBUG=""
  27
  28         KERNEL_DEBUG_CFLAGS=""
  29         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  30 ])
  31
  32 dnl #
  33 dnl # When debugging is enabled:
  34 dnl # - Enable all ASSERTs (-DDEBUG)
  35 dnl # - Promote all compiler warnings to errors (-Werror)
  36 dnl #
  37 dnl # (If INVARIANTS is detected, we need to force DEBUG, or strange panics
  38 dnl # can ensue.)
  39 dnl #
  40 AC_DEFUN([ZFS_AC_DEBUG], [
  41         AC_MSG_CHECKING([whether assertion support will be enabled])
  42         AC_ARG_ENABLE([debug],
  43                 [AS_HELP_STRING([--enable-debug],
  44                 [Enable compiler and code assertions @<:@default=no@:>@])],
  45                 [],
  46                 [enable_debug=no])
  47
  48         AS_CASE(["x$enable_debug"],
  49                 ["xyes"],
  50                 [ZFS_AC_DEBUG_ENABLE],
  51                 ["xno"],
  52                 [ZFS_AC_DEBUG_DISABLE],
  53                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  54
  55         AS_CASE(["x$enable_invariants"],
  56                 ["xyes"],
  57                 [],
  58                 ["xno"],
  59                 [],
  60                 [ZFS_AC_DEBUG_INVARIANTS_DETECT])
  61
  62         AS_CASE(["x$enable_invariants"],
  63                 ["xyes"],
  64                 [ZFS_AC_DEBUG_ENABLE],
  65                 ["xno"],
  66                 [],
  67                 [AC_MSG_ERROR([Unknown option $enable_invariants])])
  68
  69         AC_SUBST(DEBUG_CFLAGS)
  70         AC_SUBST(DEBUG_CPPFLAGS)
  71         AC_SUBST(DEBUG_LDFLAGS)
  72         AC_SUBST(DEBUG_ZFS)
  73         AC_SUBST(WITH_DEBUG)
  74
  75         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  76         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  77
  78         AC_MSG_RESULT([$enable_debug])
  79 ])
  80
  81 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  82         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
  83
  84         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $NO_IPA_SRA"
  85         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  86
  87         DEBUGINFO_ZFS="_with_debuginfo"
  88 ])
  89
  90 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  91         DEBUGINFO_ZFS="_without_debuginfo"
  92 ])
  93
  94 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  95         AC_MSG_CHECKING([whether debuginfo support will be forced])
  96         AC_ARG_ENABLE([debuginfo],
  97                 [AS_HELP_STRING([--enable-debuginfo],
  98                 [Force generation of debuginfo @<:@default=no@:>@])],
  99                 [],
 100                 [enable_debuginfo=no])
 101
 102         AS_CASE(["x$enable_debuginfo"],
 103                 ["xyes"],
 104                 [ZFS_AC_DEBUGINFO_ENABLE],
 105                 ["xno"],
 106                 [ZFS_AC_DEBUGINFO_DISABLE],
 107                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
 108
 109         AC_SUBST(DEBUG_CFLAGS)
 110         AC_SUBST(DEBUGINFO_ZFS)
 111
 112         AC_SUBST(KERNEL_DEBUG_CFLAGS)
 113         AC_SUBST(KERNEL_MAKE)
 114
 115         AC_MSG_RESULT([$enable_debuginfo])
 116 ])
 117
 118 dnl #
 119 dnl # Disabled by default, provides basic memory tracking.  Track the total
 120 dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
 121 dnl # Then at module unload time if any bytes were leaked it will be reported
 122 dnl # on the console.
 123 dnl #
 124 AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
 125         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 126         AC_ARG_ENABLE([debug-kmem],
 127                 [AS_HELP_STRING([--enable-debug-kmem],
 128                 [Enable basic kmem accounting @<:@default=no@:>@])],
 129                 [],
 130                 [enable_debug_kmem=no])
 131
 132         AS_IF([test "x$enable_debug_kmem" = xyes], [
 133                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM"
 134                 DEBUG_KMEM_ZFS="_with_debug_kmem"
 135         ], [
 136                 DEBUG_KMEM_ZFS="_without_debug_kmem"
 137         ])
 138
 139         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 140         AC_SUBST(DEBUG_KMEM_ZFS)
 141
 142         AC_MSG_RESULT([$enable_debug_kmem])
 143 ])
 144
 145 dnl #
 146 dnl # Disabled by default, provides detailed memory tracking.  This feature
 147 dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
 148 dnl # total bytes be tracked but also the location of every kmem_alloc() and
 149 dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
 150 dnl # and where they were allocated will be dumped to the console.  Enabling
 151 dnl # this feature has a significant impact on performance but it makes finding
 152 dnl # memory leaks straight forward.
 153 dnl #
 154 AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
 155         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 156         AC_ARG_ENABLE([debug-kmem-tracking],
 157                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 158                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 159                 [],
 160                 [enable_debug_kmem_tracking=no])
 161
 162         AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
 163                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM_TRACKING"
 164                 DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
 165         ], [
 166                 DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
 167         ])
 168
 169         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 170         AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
 171
 172         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 173 ])
 174
 175 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD], [
 176         AS_IF([sysctl -n kern.conftxt | grep -Fqx $'options\tINVARIANTS'],
 177                 [enable_invariants="yes"],
 178                 [enable_invariants="no"])
 179 ])
 180
 181 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT], [
 182         AM_COND_IF([BUILD_FREEBSD],
 183                 [ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD],
 184                 [enable_invariants="no"])
 185 ])
 186
 187 dnl #
 188 dnl # Detected for the running kernel by default, enables INVARIANTS features
 189 dnl # in the FreeBSD kernel module.  This feature must be used when building
 190 dnl # for a FreeBSD kernel with "options INVARIANTS" in the KERNCONF and must
 191 dnl # not be used when the INVARIANTS option is absent.
 192 dnl #
 193 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS], [
 194         AC_MSG_CHECKING([whether FreeBSD kernel INVARIANTS checks are enabled])
 195         AC_ARG_ENABLE([invariants],
 196                 [AS_HELP_STRING([--enable-invariants],
 197                 [Enable FreeBSD kernel INVARIANTS checks [[default: detect]]])],
 198                 [], [ZFS_AC_DEBUG_INVARIANTS_DETECT])
 199
 200         AS_IF([test "x$enable_invariants" = xyes],
 201                 [WITH_INVARIANTS="true"],
 202                 [WITH_INVARIANTS=""])
 203         AC_SUBST(WITH_INVARIANTS)
 204
 205         AC_MSG_RESULT([$enable_invariants])
 206 ])
 207
 208 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 209         AX_COUNT_CPUS([])
 210         AC_SUBST(CPU_COUNT)
 211
 212         ZFS_AC_CONFIG_ALWAYS_CC_NO_CLOBBERED
 213         ZFS_AC_CONFIG_ALWAYS_CC_IMPLICIT_FALLTHROUGH
 214         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 215         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 216         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
 217         ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
 218         ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
 219         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 220         ZFS_AC_CONFIG_ALWAYS_CC_UBSAN
 221         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 222         ZFS_AC_CONFIG_ALWAYS_SYSTEM
 223         ZFS_AC_CONFIG_ALWAYS_ARCH
 224         ZFS_AC_CONFIG_ALWAYS_PYTHON
 225         ZFS_AC_CONFIG_ALWAYS_PYZFS
 226         ZFS_AC_CONFIG_ALWAYS_SED
 227         ZFS_AC_CONFIG_ALWAYS_CPPCHECK
 228         ZFS_AC_CONFIG_ALWAYS_SHELLCHECK
 229         ZFS_AC_CONFIG_ALWAYS_PARALLEL
 230 ])
 231
 232 AC_DEFUN([ZFS_AC_CONFIG], [
 233
 234         dnl # Remove the previous build test directory.
 235         rm -Rf build
 236
 237         ZFS_CONFIG=all
 238         AC_ARG_WITH([config],
 239                 AS_HELP_STRING([--with-config=CONFIG],
 240                 [Config file 'kernel|user|all|srpm']),
 241                 [ZFS_CONFIG="$withval"])
 242         AC_ARG_ENABLE([linux-builtin],
 243                 [AS_HELP_STRING([--enable-linux-builtin],
 244                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 245                 [],
 246                 [enable_linux_builtin=no])
 247
 248         AC_MSG_CHECKING([zfs config])
 249         AC_MSG_RESULT([$ZFS_CONFIG]);
 250         AC_SUBST(ZFS_CONFIG)
 251
 252         ZFS_AC_CONFIG_ALWAYS
 253
 254         AM_COND_IF([BUILD_LINUX], [
 255                 AC_ARG_VAR([TEST_JOBS], [simultaneous jobs during configure])
 256                 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 257                         TEST_JOBS=$CPU_COUNT
 258                 fi
 259                 AC_SUBST(TEST_JOBS)
 260         ])
 261
 262         ZFS_INIT_SYSV=
 263         ZFS_INIT_SYSTEMD=
 264         ZFS_WANT_MODULES_LOAD_D=
 265
 266         case "$ZFS_CONFIG" in
 267                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 268                 user)   ZFS_AC_CONFIG_USER   ;;
 269                 all)    ZFS_AC_CONFIG_USER
 270                         ZFS_AC_CONFIG_KERNEL ;;
 271                 srpm)                        ;;
 272                 *)
 273                 AC_MSG_RESULT([Error!])
 274                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 275                               user kernel|user|all|srpm]) ;;
 276         esac
 277
 278         AM_CONDITIONAL([INIT_SYSV],           [test "x$ZFS_INIT_SYSV" = "xyes"])
 279         AM_CONDITIONAL([INIT_SYSTEMD],        [test "x$ZFS_INIT_SYSTEMD" = "xyes"])
 280         AM_CONDITIONAL([WANT_MODULES_LOAD_D], [test "x$ZFS_WANT_MODULES_LOAD_D" = "xyes"])
 281
 282         AM_CONDITIONAL([CONFIG_USER],
 283             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 284         AM_CONDITIONAL([CONFIG_KERNEL],
 285             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 286             [test "x$enable_linux_builtin" != xyes ])
 287         AM_CONDITIONAL([CONFIG_QAT],
 288             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 289             [test "x$qatsrc" != x ])
 290         AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
 291         AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
 292         AM_CONDITIONAL([PAM_ZFS_ENABLED], [test "x$enable_pam" = xyes])
 293 ])
 294
 295 dnl #
 296 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 297 dnl # are missing it is non-fatal but you will not be able to build
 298 dnl # RPM packages and will be warned if you try too.
 299 dnl #
 300 dnl # By default the generic spec file will be used because it requires
 301 dnl # minimal dependencies.  Distribution specific spec files can be
 302 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 303 dnl # the --with-spec=<distribution> configure option.
 304 dnl #
 305 AC_DEFUN([ZFS_AC_RPM], [
 306         RPM=rpm
 307         RPMBUILD=rpmbuild
 308
 309         AC_MSG_CHECKING([whether $RPM is available])
 310         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 311                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 312                 HAVE_RPM=yes
 313                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 314         ],[
 315                 HAVE_RPM=no
 316                 AC_MSG_RESULT([$HAVE_RPM])
 317         ])
 318
 319         AC_MSG_CHECKING([whether $RPMBUILD is available])
 320         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 321                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 322                 HAVE_RPMBUILD=yes
 323                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 324         ],[
 325                 HAVE_RPMBUILD=no
 326                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 327         ])
 328
 329         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 330         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUGINFO_ZFS) 1"'
 331         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_ZFS) 1"'
 332         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
 333         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(ASAN_ZFS) 1"'
 334         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(UBSAN_ZFS) 1"'
 335
 336         AS_IF([test "x$enable_debuginfo" = xyes], [
 337                 RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "__strip /bin/true"'
 338         ])
 339
 340         RPM_DEFINE_UTIL=' --define "_initconfdir $(initconfdir)"'
 341
 342         dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
 343         dnl # their values may not be set when running:
 344         dnl #
 345         dnl #   ./configure --with-config=srpm
 346         dnl #
 347         AS_IF([test -n "$dracutdir" ], [
 348                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_dracutdir $(dracutdir)"'
 349         ])
 350         AS_IF([test -n "$udevdir" ], [
 351                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevdir $(udevdir)"'
 352         ])
 353         AS_IF([test -n "$udevruledir" ], [
 354                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevruledir $(udevruledir)"'
 355         ])
 356         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_SYSTEMD)'
 357         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYZFS)'
 358         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PAM)'
 359         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_VERSION)'
 360         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_PKG_VERSION)'
 361
 362         dnl # Override default lib directory on Debian/Ubuntu systems.  The
 363         dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
 364         dnl # specify the correct path for multiarch systems as described
 365         dnl # by the packaging guidelines.
 366         dnl #
 367         dnl # https://wiki.ubuntu.com/MultiarchSpec
 368         dnl # https://wiki.debian.org/Multiarch/Implementation
 369         dnl #
 370         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 371                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 372                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_lib $(MULTIARCH_LIBDIR)"'
 373                 AC_SUBST(MULTIARCH_LIBDIR)
 374         ])
 375
 376         dnl # Make RPM_DEFINE_KMOD additions conditional on CONFIG_KERNEL,
 377         dnl # since the values will not be set otherwise. The spec files
 378         dnl # provide defaults for them.
 379         dnl #
 380         RPM_DEFINE_KMOD='--define "_wrong_version_format_terminate_build 0"'
 381         AM_COND_IF([CONFIG_KERNEL], [
 382                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernels $(LINUX_VERSION)"'
 383                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "ksrc $(LINUX)"'
 384                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kobj $(LINUX_OBJ)"'
 385                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_cc KERNEL_CC=$(KERNEL_CC)"'
 386                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_ld KERNEL_LD=$(KERNEL_LD)"'
 387                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_llvm KERNEL_LLVM=$(KERNEL_LLVM)"'
 388         ])
 389
 390         RPM_DEFINE_DKMS=''
 391
 392         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 393         SRPM_DEFINE_UTIL=
 394         SRPM_DEFINE_KMOD=
 395         SRPM_DEFINE_DKMS=
 396
 397         RPM_SPEC_DIR="rpm/generic"
 398         AC_ARG_WITH([spec],
 399                 AS_HELP_STRING([--with-spec=SPEC],
 400                 [Spec files 'generic|redhat']),
 401                 [RPM_SPEC_DIR="rpm/$withval"])
 402
 403         AC_MSG_CHECKING([whether spec files are available])
 404         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 405
 406         AC_SUBST(HAVE_RPM)
 407         AC_SUBST(RPM)
 408         AC_SUBST(RPM_VERSION)
 409
 410         AC_SUBST(HAVE_RPMBUILD)
 411         AC_SUBST(RPMBUILD)
 412         AC_SUBST(RPMBUILD_VERSION)
 413
 414         AC_SUBST(RPM_SPEC_DIR)
 415         AC_SUBST(RPM_DEFINE_UTIL)
 416         AC_SUBST(RPM_DEFINE_KMOD)
 417         AC_SUBST(RPM_DEFINE_DKMS)
 418         AC_SUBST(RPM_DEFINE_COMMON)
 419         AC_SUBST(SRPM_DEFINE_UTIL)
 420         AC_SUBST(SRPM_DEFINE_KMOD)
 421         AC_SUBST(SRPM_DEFINE_DKMS)
 422         AC_SUBST(SRPM_DEFINE_COMMON)
 423 ])
 424
 425 dnl #
 426 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 427 dnl # tools are missing it is non-fatal but you will not be able to build
 428 dnl # DEB packages and will be warned if you try too.
 429 dnl #
 430 AC_DEFUN([ZFS_AC_DPKG], [
 431         DPKG=dpkg
 432         DPKGBUILD=dpkg-buildpackage
 433
 434         AC_MSG_CHECKING([whether $DPKG is available])
 435         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 436                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 437                 HAVE_DPKG=yes
 438                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 439         ],[
 440                 HAVE_DPKG=no
 441                 AC_MSG_RESULT([$HAVE_DPKG])
 442         ])
 443
 444         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 445         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 446                 DPKGBUILD_VERSION=$(echo $tmp | \
 447                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 448                 HAVE_DPKGBUILD=yes
 449                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 450         ],[
 451                 HAVE_DPKGBUILD=no
 452                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 453         ])
 454
 455         AC_SUBST(HAVE_DPKG)
 456         AC_SUBST(DPKG)
 457         AC_SUBST(DPKG_VERSION)
 458
 459         AC_SUBST(HAVE_DPKGBUILD)
 460         AC_SUBST(DPKGBUILD)
 461         AC_SUBST(DPKGBUILD_VERSION)
 462 ])
 463
 464 dnl #
 465 dnl # Until native packaging for various different packing systems
 466 dnl # can be added the least we can do is attempt to use alien to
 467 dnl # convert the RPM packages to the needed package type.  This is
 468 dnl # a hack but so far it has worked reasonable well.
 469 dnl #
 470 AC_DEFUN([ZFS_AC_ALIEN], [
 471         ALIEN=alien
 472
 473         AC_MSG_CHECKING([whether $ALIEN is available])
 474         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 475                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 476                 ALIEN_MAJOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[1] }')
 477                 ALIEN_MINOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[2] }')
 478                 ALIEN_POINT=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[3] }')
 479                 HAVE_ALIEN=yes
 480                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 481         ],[
 482                 HAVE_ALIEN=no
 483                 AC_MSG_RESULT([$HAVE_ALIEN])
 484         ])
 485
 486         AC_SUBST(HAVE_ALIEN)
 487         AC_SUBST(ALIEN)
 488         AC_SUBST(ALIEN_VERSION)
 489         AC_SUBST(ALIEN_MAJOR)
 490         AC_SUBST(ALIEN_MINOR)
 491         AC_SUBST(ALIEN_POINT)
 492 ])
 493
 494 dnl #
 495 dnl # Using the VENDOR tag from config.guess set the default
 496 dnl # package type for 'make pkg': (rpm | deb | tgz)
 497 dnl #
 498 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 499         AC_MSG_CHECKING([os distribution])
 500         AC_ARG_WITH([vendor],
 501                 [AS_HELP_STRING([--with-vendor],
 502                         [Distribution vendor @<:@default=check@:>@])],
 503                 [with_vendor=$withval],
 504                 [with_vendor=check])
 505         AS_IF([test "x$with_vendor" = "xcheck"],[
 506                 if test -f /etc/toss-release ; then
 507                         VENDOR=toss ;
 508                 elif test -f /etc/fedora-release ; then
 509                         VENDOR=fedora ;
 510                 elif test -f /etc/redhat-release ; then
 511                         VENDOR=redhat ;
 512                 elif test -f /etc/gentoo-release ; then
 513                         VENDOR=gentoo ;
 514                 elif test -f /etc/arch-release ; then
 515                         VENDOR=arch ;
 516                 elif test -f /etc/SuSE-release ; then
 517                         VENDOR=sles ;
 518                 elif test -f /etc/slackware-version ; then
 519                         VENDOR=slackware ;
 520                 elif test -f /etc/lunar.release ; then
 521                         VENDOR=lunar ;
 522                 elif test -f /etc/lsb-release ; then
 523                         VENDOR=ubuntu ;
 524                 elif test -f /etc/debian_version ; then
 525                         VENDOR=debian ;
 526                 elif test -f /etc/alpine-release ; then
 527                         VENDOR=alpine ;
 528                 elif test -f /bin/freebsd-version ; then
 529                         VENDOR=freebsd ;
 530                 else
 531                         VENDOR= ;
 532                 fi],
 533                 [ test "x${with_vendor}" != x],[
 534                         VENDOR="$with_vendor" ],
 535                 [ VENDOR= ; ]
 536         )
 537         AC_MSG_RESULT([$VENDOR])
 538         AC_SUBST(VENDOR)
 539
 540         AC_MSG_CHECKING([default package type])
 541         case "$VENDOR" in
 542                 toss)       DEFAULT_PACKAGE=rpm  ;;
 543                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 544                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 545                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 546                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 547                 arch)       DEFAULT_PACKAGE=tgz  ;;
 548                 sles)       DEFAULT_PACKAGE=rpm  ;;
 549                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 550                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 551                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 552                 debian)     DEFAULT_PACKAGE=deb  ;;
 553                 freebsd)    DEFAULT_PACKAGE=pkg  ;;
 554                 *)          DEFAULT_PACKAGE=rpm  ;;
 555         esac
 556         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 557         AC_SUBST(DEFAULT_PACKAGE)
 558
 559         AC_MSG_CHECKING([default init directory])
 560         case "$VENDOR" in
 561                 freebsd)    initdir=$sysconfdir/rc.d  ;;
 562                 *)          initdir=$sysconfdir/init.d;;
 563         esac
 564         AC_MSG_RESULT([$initdir])
 565         AC_SUBST(initdir)
 566
 567         AC_MSG_CHECKING([default init script type and shell])
 568         case "$VENDOR" in
 569                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 570                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 571                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 572                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 573                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 574                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 575                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 576                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 577                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 578                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 579                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 580                 freebsd)    DEFAULT_INIT_SCRIPT=freebsd;;
 581                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 582         esac
 583
 584         case "$VENDOR" in
 585                 gentoo)     DEFAULT_INIT_SHELL="/sbin/openrc-run";;
 586                 alpine)     DEFAULT_INIT_SHELL="/sbin/openrc-run";;
 587                 *)          DEFAULT_INIT_SHELL="/bin/sh"         ;;
 588         esac
 589
 590         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT:$DEFAULT_INIT_SHELL])
 591         AC_SUBST(DEFAULT_INIT_SCRIPT)
 592         AC_SUBST(DEFAULT_INIT_SHELL)
 593
 594         AC_MSG_CHECKING([default nfs server init script])
 595         AS_IF([test "$VENDOR" = "debian"],
 596                 [DEFAULT_INIT_NFS_SERVER="nfs-kernel-server"],
 597                 [DEFAULT_INIT_NFS_SERVER="nfs"]
 598         )
 599         AC_MSG_RESULT([$DEFAULT_INIT_NFS_SERVER])
 600         AC_SUBST(DEFAULT_INIT_NFS_SERVER)
 601
 602         AC_MSG_CHECKING([default init config directory])
 603         case "$VENDOR" in
 604                 alpine)     initconfdir=/etc/conf.d    ;;
 605                 gentoo)     initconfdir=/etc/conf.d    ;;
 606                 toss)       initconfdir=/etc/sysconfig ;;
 607                 redhat)     initconfdir=/etc/sysconfig ;;
 608                 fedora)     initconfdir=/etc/sysconfig ;;
 609                 sles)       initconfdir=/etc/sysconfig ;;
 610                 ubuntu)     initconfdir=/etc/default   ;;
 611                 debian)     initconfdir=/etc/default   ;;
 612                 freebsd)    initconfdir=$sysconfdir/rc.conf.d;;
 613                 *)          initconfdir=/etc/default   ;;
 614         esac
 615         AC_MSG_RESULT([$initconfdir])
 616         AC_SUBST(initconfdir)
 617
 618         AC_MSG_CHECKING([whether initramfs-tools is available])
 619         if test -d /usr/share/initramfs-tools ; then
 620                 RPM_DEFINE_INITRAMFS='--define "_initramfs 1"'
 621                 AC_MSG_RESULT([yes])
 622         else
 623                 RPM_DEFINE_INITRAMFS=''
 624                 AC_MSG_RESULT([no])
 625         fi
 626         AC_SUBST(RPM_DEFINE_INITRAMFS)
 627 ])
 628
 629 dnl #
 630 dnl # Default ZFS package configuration
 631 dnl #
 632 AC_DEFUN([ZFS_AC_PACKAGE], [
 633         ZFS_AC_DEFAULT_PACKAGE
 634         AS_IF([test x$VENDOR != xfreebsd], [
 635                 ZFS_AC_RPM
 636                 ZFS_AC_DPKG
 637                 ZFS_AC_ALIEN
 638         ])
 639 ])