config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  15
  16         KERNEL_DEBUG_CFLAGS="-Werror"
  17         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  18 ])
  19
  20 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  21         DEBUG_CFLAGS=""
  22         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  23         DEBUG_LDFLAGS=""
  24         DEBUG_ZFS="_without_debug"
  25
  26         KERNEL_DEBUG_CFLAGS=""
  27         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  28 ])
  29
  30 dnl #
  31 dnl # When debugging is enabled:
  32 dnl # - Enable all ASSERTs (-DDEBUG)
  33 dnl # - Promote all compiler warnings to errors (-Werror)
  34 dnl #
  35 AC_DEFUN([ZFS_AC_DEBUG], [
  36         AC_MSG_CHECKING([whether assertion support will be enabled])
  37         AC_ARG_ENABLE([debug],
  38                 [AS_HELP_STRING([--enable-debug],
  39                 [Enable compiler and code assertions @<:@default=no@:>@])],
  40                 [],
  41                 [enable_debug=no])
  42
  43         AS_CASE(["x$enable_debug"],
  44                 ["xyes"],
  45                 [ZFS_AC_DEBUG_ENABLE],
  46                 ["xno"],
  47                 [ZFS_AC_DEBUG_DISABLE],
  48                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  49
  50         AC_SUBST(DEBUG_CFLAGS)
  51         AC_SUBST(DEBUG_CPPFLAGS)
  52         AC_SUBST(DEBUG_LDFLAGS)
  53         AC_SUBST(DEBUG_ZFS)
  54
  55         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  56         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  57
  58         AC_MSG_RESULT([$enable_debug])
  59 ])
  60
  61 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  62         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline"
  63
  64         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline"
  65         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  66
  67         DEBUGINFO_ZFS="_with_debuginfo"
  68 ])
  69
  70 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  71         DEBUGINFO_ZFS="_without_debuginfo"
  72 ])
  73
  74 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  75         AC_MSG_CHECKING([whether debuginfo support will be forced])
  76         AC_ARG_ENABLE([debuginfo],
  77                 [AS_HELP_STRING([--enable-debuginfo],
  78                 [Force generation of debuginfo @<:@default=no@:>@])],
  79                 [],
  80                 [enable_debuginfo=no])
  81
  82         AS_CASE(["x$enable_debuginfo"],
  83                 ["xyes"],
  84                 [ZFS_AC_DEBUGINFO_ENABLE],
  85                 ["xno"],
  86                 [ZFS_AC_DEBUGINFO_DISABLE],
  87                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
  88
  89         AC_SUBST(DEBUG_CFLAGS)
  90         AC_SUBST(DEBUGINFO_ZFS)
  91
  92         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  93         AC_SUBST(KERNEL_MAKE)
  94
  95         AC_MSG_RESULT([$enable_debuginfo])
  96 ])
  97
  98 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  99         ZFS_AC_CONFIG_ALWAYS_CC_NO_UNUSED_BUT_SET_VARIABLE
 100         ZFS_AC_CONFIG_ALWAYS_CC_NO_BOOL_COMPARE
 101         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 102         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 103         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 104         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 105         ZFS_AC_CONFIG_ALWAYS_ARCH
 106 ])
 107
 108 AC_DEFUN([ZFS_AC_CONFIG], [
 109         ZFS_CONFIG=all
 110         AC_ARG_WITH([config],
 111                 AS_HELP_STRING([--with-config=CONFIG],
 112                 [Config file 'kernel|user|all|srpm']),
 113                 [ZFS_CONFIG="$withval"])
 114         AC_ARG_ENABLE([linux-builtin],
 115                 [AC_HELP_STRING([--enable-linux-builtin],
 116                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 117                 [],
 118                 [enable_linux_builtin=no])
 119
 120         AC_MSG_CHECKING([zfs config])
 121         AC_MSG_RESULT([$ZFS_CONFIG]);
 122         AC_SUBST(ZFS_CONFIG)
 123
 124         ZFS_AC_CONFIG_ALWAYS
 125
 126         case "$ZFS_CONFIG" in
 127                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 128                 user)   ZFS_AC_CONFIG_USER   ;;
 129                 all)    ZFS_AC_CONFIG_USER
 130                         ZFS_AC_CONFIG_KERNEL ;;
 131                 srpm)                        ;;
 132                 *)
 133                 AC_MSG_RESULT([Error!])
 134                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 135                               user kernel|user|all|srpm]) ;;
 136         esac
 137
 138         AM_CONDITIONAL([CONFIG_USER],
 139             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 140         AM_CONDITIONAL([CONFIG_KERNEL],
 141             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 142             [test "x$enable_linux_builtin" != xyes ])
 143         AM_CONDITIONAL([WANT_DEVNAME2DEVID],
 144             [test "x$user_libudev" = xyes ])
 145         AM_CONDITIONAL([CONFIG_QAT],
 146             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 147             [test "x$qatsrc" != x ])
 148 ])
 149
 150 dnl #
 151 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 152 dnl # are missing it is non-fatal but you will not be able to build
 153 dnl # RPM packages and will be warned if you try too.
 154 dnl #
 155 dnl # By default the generic spec file will be used because it requires
 156 dnl # minimal dependencies.  Distribution specific spec files can be
 157 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 158 dnl # the --with-spec=<distribution> configure option.
 159 dnl #
 160 AC_DEFUN([ZFS_AC_RPM], [
 161         RPM=rpm
 162         RPMBUILD=rpmbuild
 163
 164         AC_MSG_CHECKING([whether $RPM is available])
 165         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 166                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 167                 HAVE_RPM=yes
 168                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 169         ],[
 170                 HAVE_RPM=no
 171                 AC_MSG_RESULT([$HAVE_RPM])
 172         ])
 173
 174         AC_MSG_CHECKING([whether $RPMBUILD is available])
 175         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 176                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 177                 HAVE_RPMBUILD=yes
 178                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 179         ],[
 180                 HAVE_RPMBUILD=no
 181                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 182         ])
 183
 184         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 185         RPM_DEFINE_COMMON+=' --define "$(DEBUGINFO_ZFS) 1"'
 186         RPM_DEFINE_COMMON+=' --define "$(ASAN_ZFS) 1"'
 187
 188         RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)"'
 189         RPM_DEFINE_UTIL+=' --define "_udevdir $(udevdir)"'
 190         RPM_DEFINE_UTIL+=' --define "_udevruledir $(udevruledir)"'
 191         RPM_DEFINE_UTIL+=' --define "_initconfdir $(DEFAULT_INITCONF_DIR)"'
 192         RPM_DEFINE_UTIL+=' $(DEFINE_INITRAMFS)'
 193         RPM_DEFINE_UTIL+=' $(DEFINE_SYSTEMD)'
 194
 195         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 196         RPM_DEFINE_KMOD+=' --define "require_spldir $(SPL)"'
 197         RPM_DEFINE_KMOD+=' --define "require_splobj $(SPL_OBJ)"'
 198         RPM_DEFINE_KMOD+=' --define "ksrc $(LINUX)"'
 199         RPM_DEFINE_KMOD+=' --define "kobj $(LINUX_OBJ)"'
 200
 201         RPM_DEFINE_DKMS=''
 202
 203         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 204         SRPM_DEFINE_UTIL=
 205         SRPM_DEFINE_KMOD=
 206         SRPM_DEFINE_DKMS=
 207
 208         RPM_SPEC_DIR="rpm/generic"
 209         AC_ARG_WITH([spec],
 210                 AS_HELP_STRING([--with-spec=SPEC],
 211                 [Spec files 'generic|redhat']),
 212                 [RPM_SPEC_DIR="rpm/$withval"])
 213
 214         AC_MSG_CHECKING([whether spec files are available])
 215         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 216
 217         AC_SUBST(HAVE_RPM)
 218         AC_SUBST(RPM)
 219         AC_SUBST(RPM_VERSION)
 220
 221         AC_SUBST(HAVE_RPMBUILD)
 222         AC_SUBST(RPMBUILD)
 223         AC_SUBST(RPMBUILD_VERSION)
 224
 225         AC_SUBST(RPM_SPEC_DIR)
 226         AC_SUBST(RPM_DEFINE_UTIL)
 227         AC_SUBST(RPM_DEFINE_KMOD)
 228         AC_SUBST(RPM_DEFINE_DKMS)
 229         AC_SUBST(RPM_DEFINE_COMMON)
 230         AC_SUBST(SRPM_DEFINE_UTIL)
 231         AC_SUBST(SRPM_DEFINE_KMOD)
 232         AC_SUBST(SRPM_DEFINE_DKMS)
 233         AC_SUBST(SRPM_DEFINE_COMMON)
 234 ])
 235
 236 dnl #
 237 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 238 dnl # tools are missing it is non-fatal but you will not be able to build
 239 dnl # DEB packages and will be warned if you try too.
 240 dnl #
 241 AC_DEFUN([ZFS_AC_DPKG], [
 242         DPKG=dpkg
 243         DPKGBUILD=dpkg-buildpackage
 244
 245         AC_MSG_CHECKING([whether $DPKG is available])
 246         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 247                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 248                 HAVE_DPKG=yes
 249                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 250         ],[
 251                 HAVE_DPKG=no
 252                 AC_MSG_RESULT([$HAVE_DPKG])
 253         ])
 254
 255         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 256         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 257                 DPKGBUILD_VERSION=$(echo $tmp | \
 258                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 259                 HAVE_DPKGBUILD=yes
 260                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 261         ],[
 262                 HAVE_DPKGBUILD=no
 263                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 264         ])
 265
 266         AC_SUBST(HAVE_DPKG)
 267         AC_SUBST(DPKG)
 268         AC_SUBST(DPKG_VERSION)
 269
 270         AC_SUBST(HAVE_DPKGBUILD)
 271         AC_SUBST(DPKGBUILD)
 272         AC_SUBST(DPKGBUILD_VERSION)
 273 ])
 274
 275 dnl #
 276 dnl # Until native packaging for various different packing systems
 277 dnl # can be added the least we can do is attempt to use alien to
 278 dnl # convert the RPM packages to the needed package type.  This is
 279 dnl # a hack but so far it has worked reasonable well.
 280 dnl #
 281 AC_DEFUN([ZFS_AC_ALIEN], [
 282         ALIEN=alien
 283
 284         AC_MSG_CHECKING([whether $ALIEN is available])
 285         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 286                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 287                 HAVE_ALIEN=yes
 288                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 289         ],[
 290                 HAVE_ALIEN=no
 291                 AC_MSG_RESULT([$HAVE_ALIEN])
 292         ])
 293
 294         AC_SUBST(HAVE_ALIEN)
 295         AC_SUBST(ALIEN)
 296         AC_SUBST(ALIEN_VERSION)
 297 ])
 298
 299 dnl #
 300 dnl # Using the VENDOR tag from config.guess set the default
 301 dnl # package type for 'make pkg': (rpm | deb | tgz)
 302 dnl #
 303 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 304         AC_MSG_CHECKING([linux distribution])
 305         if test -f /etc/toss-release ; then
 306                 VENDOR=toss ;
 307         elif test -f /etc/fedora-release ; then
 308                 VENDOR=fedora ;
 309         elif test -f /etc/redhat-release ; then
 310                 VENDOR=redhat ;
 311         elif test -f /etc/gentoo-release ; then
 312                 VENDOR=gentoo ;
 313         elif test -f /etc/arch-release ; then
 314                 VENDOR=arch ;
 315         elif test -f /etc/SuSE-release ; then
 316                 VENDOR=sles ;
 317         elif test -f /etc/slackware-version ; then
 318                 VENDOR=slackware ;
 319         elif test -f /etc/lunar.release ; then
 320                 VENDOR=lunar ;
 321         elif test -f /etc/lsb-release ; then
 322                 VENDOR=ubuntu ;
 323         elif test -f /etc/debian_version ; then
 324                 VENDOR=debian ;
 325         elif test -f /etc/alpine-release ; then
 326                 VENDOR=alpine ;
 327         else
 328                 VENDOR= ;
 329         fi
 330         AC_MSG_RESULT([$VENDOR])
 331         AC_SUBST(VENDOR)
 332
 333         AC_MSG_CHECKING([default package type])
 334         case "$VENDOR" in
 335                 toss)       DEFAULT_PACKAGE=rpm  ;;
 336                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 337                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 338                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 339                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 340                 arch)       DEFAULT_PACKAGE=tgz  ;;
 341                 sles)       DEFAULT_PACKAGE=rpm  ;;
 342                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 343                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 344                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 345                 debian)     DEFAULT_PACKAGE=deb  ;;
 346                 *)          DEFAULT_PACKAGE=rpm  ;;
 347         esac
 348         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 349         AC_SUBST(DEFAULT_PACKAGE)
 350
 351         DEFAULT_INIT_DIR=$sysconfdir/init.d
 352         AC_MSG_CHECKING([default init directory])
 353         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 354         AC_SUBST(DEFAULT_INIT_DIR)
 355
 356         AC_MSG_CHECKING([default init script type])
 357         case "$VENDOR" in
 358                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 359                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 360                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 361                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 362                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 363                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 364                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 365                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 366                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 367                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 368                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 369                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 370         esac
 371         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 372         AC_SUBST(DEFAULT_INIT_SCRIPT)
 373
 374         AC_MSG_CHECKING([default init config direectory])
 375         case "$VENDOR" in
 376                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 377                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 378                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 379                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 380                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 381                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 382                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 383                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 384                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 385         esac
 386         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 387         AC_SUBST(DEFAULT_INITCONF_DIR)
 388
 389         AC_MSG_CHECKING([whether initramfs-tools is available])
 390         if test -d /usr/share/initramfs-tools ; then
 391                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 392                 AC_MSG_RESULT([yes])
 393         else
 394                 DEFINE_INITRAMFS=''
 395                 AC_MSG_RESULT([no])
 396         fi
 397         AC_SUBST(DEFINE_INITRAMFS)
 398 ])
 399
 400 dnl #
 401 dnl # Default ZFS package configuration
 402 dnl #
 403 AC_DEFUN([ZFS_AC_PACKAGE], [
 404         ZFS_AC_DEFAULT_PACKAGE
 405         ZFS_AC_RPM
 406         ZFS_AC_DPKG
 407         ZFS_AC_ALIEN
 408 ])