config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         WITH_DEBUG="true"
  15         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  16
  17         KERNEL_DEBUG_CFLAGS="-Werror"
  18         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  19 ])
  20
  21 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  22         DEBUG_CFLAGS=""
  23         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  24         DEBUG_LDFLAGS=""
  25         DEBUG_ZFS="_without_debug"
  26         WITH_DEBUG=""
  27
  28         KERNEL_DEBUG_CFLAGS=""
  29         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  30 ])
  31
  32 dnl #
  33 dnl # When debugging is enabled:
  34 dnl # - Enable all ASSERTs (-DDEBUG)
  35 dnl # - Promote all compiler warnings to errors (-Werror)
  36 dnl #
  37 dnl # (If INVARIANTS is detected, we need to force DEBUG, or strange panics
  38 dnl # can ensue.)
  39 dnl #
  40 AC_DEFUN([ZFS_AC_DEBUG], [
  41         AC_MSG_CHECKING([whether assertion support will be enabled])
  42         AC_ARG_ENABLE([debug],
  43                 [AS_HELP_STRING([--enable-debug],
  44                 [Enable compiler and code assertions @<:@default=no@:>@])],
  45                 [],
  46                 [enable_debug=no])
  47
  48         AS_CASE(["x$enable_debug"],
  49                 ["xyes"],
  50                 [ZFS_AC_DEBUG_ENABLE],
  51                 ["xno"],
  52                 [ZFS_AC_DEBUG_DISABLE],
  53                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  54
  55         AS_CASE(["x$enable_invariants"],
  56                 ["xyes"],
  57                 [],
  58                 ["xno"],
  59                 [],
  60                 [ZFS_AC_DEBUG_INVARIANTS_DETECT])
  61
  62         AS_CASE(["x$enable_invariants"],
  63                 ["xyes"],
  64                 [ZFS_AC_DEBUG_ENABLE],
  65                 ["xno"],
  66                 [],
  67                 [AC_MSG_ERROR([Unknown option $enable_invariants])])
  68
  69         AC_SUBST(DEBUG_CFLAGS)
  70         AC_SUBST(DEBUG_CPPFLAGS)
  71         AC_SUBST(DEBUG_LDFLAGS)
  72         AC_SUBST(DEBUG_ZFS)
  73         AC_SUBST(WITH_DEBUG)
  74
  75         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  76         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  77
  78         AC_MSG_RESULT([$enable_debug])
  79 ])
  80
  81 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  82         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
  83
  84         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $NO_IPA_SRA"
  85         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  86
  87         DEBUGINFO_ZFS="_with_debuginfo"
  88 ])
  89
  90 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  91         DEBUGINFO_ZFS="_without_debuginfo"
  92 ])
  93
  94 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  95         AC_MSG_CHECKING([whether debuginfo support will be forced])
  96         AC_ARG_ENABLE([debuginfo],
  97                 [AS_HELP_STRING([--enable-debuginfo],
  98                 [Force generation of debuginfo @<:@default=no@:>@])],
  99                 [],
 100                 [enable_debuginfo=no])
 101
 102         AS_CASE(["x$enable_debuginfo"],
 103                 ["xyes"],
 104                 [ZFS_AC_DEBUGINFO_ENABLE],
 105                 ["xno"],
 106                 [ZFS_AC_DEBUGINFO_DISABLE],
 107                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
 108
 109         AC_SUBST(DEBUG_CFLAGS)
 110         AC_SUBST(DEBUGINFO_ZFS)
 111
 112         AC_SUBST(KERNEL_DEBUG_CFLAGS)
 113         AC_SUBST(KERNEL_MAKE)
 114
 115         AC_MSG_RESULT([$enable_debuginfo])
 116 ])
 117
 118 dnl #
 119 dnl # Disabled by default, provides basic memory tracking.  Track the total
 120 dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
 121 dnl # Then at module unload time if any bytes were leaked it will be reported
 122 dnl # on the console.
 123 dnl #
 124 AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
 125         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 126         AC_ARG_ENABLE([debug-kmem],
 127                 [AS_HELP_STRING([--enable-debug-kmem],
 128                 [Enable basic kmem accounting @<:@default=no@:>@])],
 129                 [],
 130                 [enable_debug_kmem=no])
 131
 132         AS_IF([test "x$enable_debug_kmem" = xyes], [
 133                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM"
 134                 DEBUG_KMEM_ZFS="_with_debug_kmem"
 135         ], [
 136                 DEBUG_KMEM_ZFS="_without_debug_kmem"
 137         ])
 138
 139         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 140         AC_SUBST(DEBUG_KMEM_ZFS)
 141
 142         AC_MSG_RESULT([$enable_debug_kmem])
 143 ])
 144
 145 dnl #
 146 dnl # Disabled by default, provides detailed memory tracking.  This feature
 147 dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
 148 dnl # total bytes be tracked but also the location of every kmem_alloc() and
 149 dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
 150 dnl # and where they were allocated will be dumped to the console.  Enabling
 151 dnl # this feature has a significant impact on performance but it makes finding
 152 dnl # memory leaks straight forward.
 153 dnl #
 154 AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
 155         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 156         AC_ARG_ENABLE([debug-kmem-tracking],
 157                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 158                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 159                 [],
 160                 [enable_debug_kmem_tracking=no])
 161
 162         AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
 163                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM_TRACKING"
 164                 DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
 165         ], [
 166                 DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
 167         ])
 168
 169         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 170         AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
 171
 172         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 173 ])
 174
 175 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD], [
 176         AS_IF([sysctl -n kern.conftxt | grep -Fqx $'options\tINVARIANTS'],
 177                 [enable_invariants="yes"],
 178                 [enable_invariants="no"])
 179 ])
 180
 181 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT], [
 182         AM_COND_IF([BUILD_FREEBSD],
 183                 [ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD],
 184                 [enable_invariants="no"])
 185 ])
 186
 187 dnl #
 188 dnl # Detected for the running kernel by default, enables INVARIANTS features
 189 dnl # in the FreeBSD kernel module.  This feature must be used when building
 190 dnl # for a FreeBSD kernel with "options INVARIANTS" in the KERNCONF and must
 191 dnl # not be used when the INVARIANTS option is absent.
 192 dnl #
 193 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS], [
 194         AC_MSG_CHECKING([whether FreeBSD kernel INVARIANTS checks are enabled])
 195         AC_ARG_ENABLE([invariants],
 196                 [AS_HELP_STRING([--enable-invariants],
 197                 [Enable FreeBSD kernel INVARIANTS checks [[default: detect]]])],
 198                 [], [ZFS_AC_DEBUG_INVARIANTS_DETECT])
 199
 200         AS_IF([test "x$enable_invariants" = xyes],
 201                 [WITH_INVARIANTS="true"],
 202                 [WITH_INVARIANTS=""])
 203         AC_SUBST(WITH_INVARIANTS)
 204
 205         AC_MSG_RESULT([$enable_invariants])
 206 ])
 207
 208 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 209         AX_COUNT_CPUS([])
 210         AC_SUBST(CPU_COUNT)
 211
 212         ZFS_AC_CONFIG_ALWAYS_CC_NO_CLOBBERED
 213         ZFS_AC_CONFIG_ALWAYS_CC_IMPLICIT_FALLTHROUGH
 214         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 215         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 216         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
 217         ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
 218         ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
 219         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 220         ZFS_AC_CONFIG_ALWAYS_CC_UBSAN
 221         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 222         ZFS_AC_CONFIG_ALWAYS_SYSTEM
 223         ZFS_AC_CONFIG_ALWAYS_ARCH
 224         ZFS_AC_CONFIG_ALWAYS_PYTHON
 225         ZFS_AC_CONFIG_ALWAYS_PYZFS
 226         ZFS_AC_CONFIG_ALWAYS_SED
 227         ZFS_AC_CONFIG_ALWAYS_CPPCHECK
 228         ZFS_AC_CONFIG_ALWAYS_SHELLCHECK
 229         ZFS_AC_CONFIG_ALWAYS_PARALLEL
 230 ])
 231
 232 AC_DEFUN([ZFS_AC_CONFIG], [
 233
 234         dnl # Remove the previous build test directory.
 235         rm -Rf build
 236
 237         ZFS_CONFIG=all
 238         AC_ARG_WITH([config],
 239                 AS_HELP_STRING([--with-config=CONFIG],
 240                 [Config file 'kernel|user|all|srpm']),
 241                 [ZFS_CONFIG="$withval"])
 242         AC_ARG_ENABLE([linux-builtin],
 243                 [AS_HELP_STRING([--enable-linux-builtin],
 244                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 245                 [],
 246                 [enable_linux_builtin=no])
 247
 248         AC_MSG_CHECKING([zfs config])
 249         AC_MSG_RESULT([$ZFS_CONFIG]);
 250         AC_SUBST(ZFS_CONFIG)
 251
 252         ZFS_AC_CONFIG_ALWAYS
 253
 254         AM_COND_IF([BUILD_LINUX], [
 255                 AC_ARG_VAR([TEST_JOBS], [simultaneous jobs during configure])
 256                 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 257                         TEST_JOBS=$CPU_COUNT
 258                 fi
 259                 AC_SUBST(TEST_JOBS)
 260         ])
 261
 262         ZFS_INIT_SYSV=
 263         ZFS_INIT_SYSTEMD=
 264         ZFS_WANT_MODULES_LOAD_D=
 265
 266         case "$ZFS_CONFIG" in
 267                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 268                 user)   ZFS_AC_CONFIG_USER   ;;
 269                 all)    ZFS_AC_CONFIG_USER
 270                         ZFS_AC_CONFIG_KERNEL ;;
 271                 srpm)                        ;;
 272                 *)
 273                 AC_MSG_RESULT([Error!])
 274                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 275                               user kernel|user|all|srpm]) ;;
 276         esac
 277
 278         AM_CONDITIONAL([INIT_SYSV],           [test "x$ZFS_INIT_SYSV" = "xyes"])
 279         AM_CONDITIONAL([INIT_SYSTEMD],        [test "x$ZFS_INIT_SYSTEMD" = "xyes"])
 280         AM_CONDITIONAL([WANT_MODULES_LOAD_D], [test "x$ZFS_WANT_MODULES_LOAD_D" = "xyes"])
 281
 282         AM_CONDITIONAL([CONFIG_USER],
 283             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 284         AM_CONDITIONAL([CONFIG_KERNEL],
 285             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 286             [test "x$enable_linux_builtin" != xyes ])
 287         AM_CONDITIONAL([CONFIG_QAT],
 288             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 289             [test "x$qatsrc" != x ])
 290         AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
 291         AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
 292         AM_CONDITIONAL([PAM_ZFS_ENABLED], [test "x$enable_pam" = xyes])
 293 ])
 294
 295 dnl #
 296 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 297 dnl # are missing it is non-fatal but you will not be able to build
 298 dnl # RPM packages and will be warned if you try too.
 299 dnl #
 300 dnl # By default the generic spec file will be used because it requires
 301 dnl # minimal dependencies.  Distribution specific spec files can be
 302 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 303 dnl # the --with-spec=<distribution> configure option.
 304 dnl #
 305 AC_DEFUN([ZFS_AC_RPM], [
 306         RPM=rpm
 307         RPMBUILD=rpmbuild
 308
 309         AC_MSG_CHECKING([whether $RPM is available])
 310         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 311                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 312                 HAVE_RPM=yes
 313                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 314         ],[
 315                 HAVE_RPM=no
 316                 AC_MSG_RESULT([$HAVE_RPM])
 317         ])
 318
 319         AC_MSG_CHECKING([whether $RPMBUILD is available])
 320         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 321                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 322                 HAVE_RPMBUILD=yes
 323                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 324         ],[
 325                 HAVE_RPMBUILD=no
 326                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 327         ])
 328
 329         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 330         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUGINFO_ZFS) 1"'
 331         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_ZFS) 1"'
 332         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
 333         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(ASAN_ZFS) 1"'
 334         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(UBSAN_ZFS) 1"'
 335
 336         RPM_DEFINE_UTIL=' --define "_initconfdir $(initconfdir)"'
 337
 338         dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
 339         dnl # their values may not be set when running:
 340         dnl #
 341         dnl #   ./configure --with-config=srpm
 342         dnl #
 343         AS_IF([test -n "$dracutdir" ], [
 344                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_dracutdir $(dracutdir)"'
 345         ])
 346         AS_IF([test -n "$udevdir" ], [
 347                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevdir $(udevdir)"'
 348         ])
 349         AS_IF([test -n "$udevruledir" ], [
 350                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevruledir $(udevruledir)"'
 351         ])
 352         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_SYSTEMD)'
 353         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYZFS)'
 354         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PAM)'
 355         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_VERSION)'
 356         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_PKG_VERSION)'
 357
 358         dnl # Override default lib directory on Debian/Ubuntu systems.  The
 359         dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
 360         dnl # specify the correct path for multiarch systems as described
 361         dnl # by the packaging guidelines.
 362         dnl #
 363         dnl # https://wiki.ubuntu.com/MultiarchSpec
 364         dnl # https://wiki.debian.org/Multiarch/Implementation
 365         dnl #
 366         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 367                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 368                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_lib $(MULTIARCH_LIBDIR)"'
 369                 AC_SUBST(MULTIARCH_LIBDIR)
 370         ])
 371
 372         dnl # Make RPM_DEFINE_KMOD additions conditional on CONFIG_KERNEL,
 373         dnl # since the values will not be set otherwise. The spec files
 374         dnl # provide defaults for them.
 375         dnl #
 376         RPM_DEFINE_KMOD='--define "_wrong_version_format_terminate_build 0"'
 377         AM_COND_IF([CONFIG_KERNEL], [
 378                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernels $(LINUX_VERSION)"'
 379                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "ksrc $(LINUX)"'
 380                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kobj $(LINUX_OBJ)"'
 381                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_cc KERNEL_CC=$(KERNEL_CC)"'
 382                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_ld KERNEL_LD=$(KERNEL_LD)"'
 383                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_llvm KERNEL_LLVM=$(KERNEL_LLVM)"'
 384         ])
 385
 386         RPM_DEFINE_DKMS=''
 387
 388         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 389         SRPM_DEFINE_UTIL=
 390         SRPM_DEFINE_KMOD=
 391         SRPM_DEFINE_DKMS=
 392
 393         RPM_SPEC_DIR="rpm/generic"
 394         AC_ARG_WITH([spec],
 395                 AS_HELP_STRING([--with-spec=SPEC],
 396                 [Spec files 'generic|redhat']),
 397                 [RPM_SPEC_DIR="rpm/$withval"])
 398
 399         AC_MSG_CHECKING([whether spec files are available])
 400         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 401
 402         AC_SUBST(HAVE_RPM)
 403         AC_SUBST(RPM)
 404         AC_SUBST(RPM_VERSION)
 405
 406         AC_SUBST(HAVE_RPMBUILD)
 407         AC_SUBST(RPMBUILD)
 408         AC_SUBST(RPMBUILD_VERSION)
 409
 410         AC_SUBST(RPM_SPEC_DIR)
 411         AC_SUBST(RPM_DEFINE_UTIL)
 412         AC_SUBST(RPM_DEFINE_KMOD)
 413         AC_SUBST(RPM_DEFINE_DKMS)
 414         AC_SUBST(RPM_DEFINE_COMMON)
 415         AC_SUBST(SRPM_DEFINE_UTIL)
 416         AC_SUBST(SRPM_DEFINE_KMOD)
 417         AC_SUBST(SRPM_DEFINE_DKMS)
 418         AC_SUBST(SRPM_DEFINE_COMMON)
 419 ])
 420
 421 dnl #
 422 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 423 dnl # tools are missing it is non-fatal but you will not be able to build
 424 dnl # DEB packages and will be warned if you try too.
 425 dnl #
 426 AC_DEFUN([ZFS_AC_DPKG], [
 427         DPKG=dpkg
 428         DPKGBUILD=dpkg-buildpackage
 429
 430         AC_MSG_CHECKING([whether $DPKG is available])
 431         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 432                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 433                 HAVE_DPKG=yes
 434                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 435         ],[
 436                 HAVE_DPKG=no
 437                 AC_MSG_RESULT([$HAVE_DPKG])
 438         ])
 439
 440         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 441         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 442                 DPKGBUILD_VERSION=$(echo $tmp | \
 443                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 444                 HAVE_DPKGBUILD=yes
 445                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 446         ],[
 447                 HAVE_DPKGBUILD=no
 448                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 449         ])
 450
 451         AC_SUBST(HAVE_DPKG)
 452         AC_SUBST(DPKG)
 453         AC_SUBST(DPKG_VERSION)
 454
 455         AC_SUBST(HAVE_DPKGBUILD)
 456         AC_SUBST(DPKGBUILD)
 457         AC_SUBST(DPKGBUILD_VERSION)
 458 ])
 459
 460 dnl #
 461 dnl # Until native packaging for various different packing systems
 462 dnl # can be added the least we can do is attempt to use alien to
 463 dnl # convert the RPM packages to the needed package type.  This is
 464 dnl # a hack but so far it has worked reasonable well.
 465 dnl #
 466 AC_DEFUN([ZFS_AC_ALIEN], [
 467         ALIEN=alien
 468
 469         AC_MSG_CHECKING([whether $ALIEN is available])
 470         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 471                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 472                 ALIEN_MAJOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[1] }')
 473                 ALIEN_MINOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[2] }')
 474                 ALIEN_POINT=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[3] }')
 475                 HAVE_ALIEN=yes
 476                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 477         ],[
 478                 HAVE_ALIEN=no
 479                 AC_MSG_RESULT([$HAVE_ALIEN])
 480         ])
 481
 482         AC_SUBST(HAVE_ALIEN)
 483         AC_SUBST(ALIEN)
 484         AC_SUBST(ALIEN_VERSION)
 485         AC_SUBST(ALIEN_MAJOR)
 486         AC_SUBST(ALIEN_MINOR)
 487         AC_SUBST(ALIEN_POINT)
 488 ])
 489
 490 dnl #
 491 dnl # Using the VENDOR tag from config.guess set the default
 492 dnl # package type for 'make pkg': (rpm | deb | tgz)
 493 dnl #
 494 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 495         AC_MSG_CHECKING([os distribution])
 496         AC_ARG_WITH([vendor],
 497                 [AS_HELP_STRING([--with-vendor],
 498                         [Distribution vendor @<:@default=check@:>@])],
 499                 [with_vendor=$withval],
 500                 [with_vendor=check])
 501         AS_IF([test "x$with_vendor" = "xcheck"],[
 502                 if test -f /etc/toss-release ; then
 503                         VENDOR=toss ;
 504                 elif test -f /etc/fedora-release ; then
 505                         VENDOR=fedora ;
 506                 elif test -f /etc/redhat-release ; then
 507                         VENDOR=redhat ;
 508                 elif test -f /etc/gentoo-release ; then
 509                         VENDOR=gentoo ;
 510                 elif test -f /etc/arch-release ; then
 511                         VENDOR=arch ;
 512                 elif test -f /etc/SuSE-release ; then
 513                         VENDOR=sles ;
 514                 elif test -f /etc/slackware-version ; then
 515                         VENDOR=slackware ;
 516                 elif test -f /etc/lunar.release ; then
 517                         VENDOR=lunar ;
 518                 elif test -f /etc/lsb-release ; then
 519                         VENDOR=ubuntu ;
 520                 elif test -f /etc/debian_version ; then
 521                         VENDOR=debian ;
 522                 elif test -f /etc/alpine-release ; then
 523                         VENDOR=alpine ;
 524                 elif test -f /bin/freebsd-version ; then
 525                         VENDOR=freebsd ;
 526                 else
 527                         VENDOR= ;
 528                 fi],
 529                 [ test "x${with_vendor}" != x],[
 530                         VENDOR="$with_vendor" ],
 531                 [ VENDOR= ; ]
 532         )
 533         AC_MSG_RESULT([$VENDOR])
 534         AC_SUBST(VENDOR)
 535
 536         AC_MSG_CHECKING([default package type])
 537         case "$VENDOR" in
 538                 toss)       DEFAULT_PACKAGE=rpm  ;;
 539                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 540                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 541                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 542                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 543                 arch)       DEFAULT_PACKAGE=tgz  ;;
 544                 sles)       DEFAULT_PACKAGE=rpm  ;;
 545                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 546                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 547                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 548                 debian)     DEFAULT_PACKAGE=deb  ;;
 549                 freebsd)    DEFAULT_PACKAGE=pkg  ;;
 550                 *)          DEFAULT_PACKAGE=rpm  ;;
 551         esac
 552         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 553         AC_SUBST(DEFAULT_PACKAGE)
 554
 555         AC_MSG_CHECKING([default init directory])
 556         case "$VENDOR" in
 557                 freebsd)    initdir=$sysconfdir/rc.d  ;;
 558                 *)          initdir=$sysconfdir/init.d;;
 559         esac
 560         AC_MSG_RESULT([$initdir])
 561         AC_SUBST(initdir)
 562
 563         AC_MSG_CHECKING([default init script type and shell])
 564         case "$VENDOR" in
 565                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 566                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 567                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 568                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 569                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 570                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 571                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 572                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 573                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 574                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 575                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 576                 freebsd)    DEFAULT_INIT_SCRIPT=freebsd;;
 577                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 578         esac
 579
 580         case "$VENDOR" in
 581                 gentoo)     DEFAULT_INIT_SHELL="/sbin/openrc-run";;
 582                 alpine)     DEFAULT_INIT_SHELL="/sbin/openrc-run";;
 583                 *)          DEFAULT_INIT_SHELL="/bin/sh"         ;;
 584         esac
 585
 586         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT:$DEFAULT_INIT_SHELL])
 587         AC_SUBST(DEFAULT_INIT_SCRIPT)
 588         AC_SUBST(DEFAULT_INIT_SHELL)
 589
 590         AC_MSG_CHECKING([default nfs server init script])
 591         AS_IF([test "$VENDOR" = "debian"],
 592                 [DEFAULT_INIT_NFS_SERVER="nfs-kernel-server"],
 593                 [DEFAULT_INIT_NFS_SERVER="nfs"]
 594         )
 595         AC_MSG_RESULT([$DEFAULT_INIT_NFS_SERVER])
 596         AC_SUBST(DEFAULT_INIT_NFS_SERVER)
 597
 598         AC_MSG_CHECKING([default init config directory])
 599         case "$VENDOR" in
 600                 alpine)     initconfdir=/etc/conf.d    ;;
 601                 gentoo)     initconfdir=/etc/conf.d    ;;
 602                 toss)       initconfdir=/etc/sysconfig ;;
 603                 redhat)     initconfdir=/etc/sysconfig ;;
 604                 fedora)     initconfdir=/etc/sysconfig ;;
 605                 sles)       initconfdir=/etc/sysconfig ;;
 606                 ubuntu)     initconfdir=/etc/default   ;;
 607                 debian)     initconfdir=/etc/default   ;;
 608                 freebsd)    initconfdir=$sysconfdir/rc.conf.d;;
 609                 *)          initconfdir=/etc/default   ;;
 610         esac
 611         AC_MSG_RESULT([$initconfdir])
 612         AC_SUBST(initconfdir)
 613
 614         AC_MSG_CHECKING([whether initramfs-tools is available])
 615         if test -d /usr/share/initramfs-tools ; then
 616                 RPM_DEFINE_INITRAMFS='--define "_initramfs 1"'
 617                 AC_MSG_RESULT([yes])
 618         else
 619                 RPM_DEFINE_INITRAMFS=''
 620                 AC_MSG_RESULT([no])
 621         fi
 622         AC_SUBST(RPM_DEFINE_INITRAMFS)
 623 ])
 624
 625 dnl #
 626 dnl # Default ZFS package configuration
 627 dnl #
 628 AC_DEFUN([ZFS_AC_PACKAGE], [
 629         ZFS_AC_DEFAULT_PACKAGE
 630         AS_IF([test x$VENDOR != xfreebsd], [
 631                 ZFS_AC_RPM
 632                 ZFS_AC_DPKG
 633                 ZFS_AC_ALIEN
 634         ])
 635 ])