qm

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Getopt::Long;
   5 use Fcntl ':flock';
   6 use File::Path;
   7 use IO::Socket::UNIX;
   8 use IO::Select;
   9
  10 use PVE::Tools qw(extract_param);
  11 use PVE::Cluster;
  12 use PVE::SafeSyslog;
  13 use PVE::INotify;
  14 use PVE::RPCEnvironment;
  15 use PVE::QemuServer;
  16 use PVE::API2::Qemu;
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use Term::ReadLine;
  19
  20 use PVE::CLIHandler;
  21
  22 use base qw(PVE::CLIHandler);
  23
  24 $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
  25
  26 initlog('qm');
  27
  28 die "please run as root\n" if $> != 0;
  29
  30 PVE::INotify::inotify_init();
  31
  32 my $rpcenv = PVE::RPCEnvironment->init('cli');
  33
  34 $rpcenv->init_request();
  35 $rpcenv->set_language($ENV{LANG});
  36 $rpcenv->set_user('root@pam');
  37
  38 my $upid_exit = sub {
  39     my $upid = shift;
  40     my $status = PVE::Tools::upid_read_status($upid);
  41     exit($status eq 'OK' ? 0 : -1);
  42 };
  43
  44 my $nodename = PVE::INotify::nodename();
  45
  46 sub run_vnc_proxy {
  47     my ($vmid) = @_;
  48
  49     my $path = PVE::QemuServer::vnc_socket($vmid);
  50
  51     my $s = IO::Socket::UNIX->new(Peer => $path, Timeout => 120);
  52
  53     die "unable to connect to socket '$path' - $!" if !$s;
  54
  55     my $select = new IO::Select;
  56
  57     $select->add(\*STDIN);
  58     $select->add($s);
  59
  60     my $timeout = 60*15; # 15 minutes
  61
  62     my @handles;
  63     while ($select->count &&
  64            scalar(@handles = $select->can_read ($timeout))) {
  65         foreach my $h (@handles) {
  66             my $buf;
  67             my $n = $h->sysread($buf, 4096);
  68
  69             if ($h == \*STDIN) {
  70                 if ($n) {
  71                     syswrite($s, $buf);
  72                 } else {
  73                     exit(0);
  74                 }
  75             } elsif ($h == $s) {
  76                 if ($n) {
  77                     syswrite(\*STDOUT, $buf);
  78                 } else {
  79                     exit(0);
  80                 }
  81             }
  82         }
  83     }
  84     exit(0);
  85 }
  86
  87 __PACKAGE__->register_method ({
  88     name => 'showcmd',
  89     path => 'showcmd',
  90     method => 'GET',
  91     description => "Show command line which is used to start the VM (debug info).",
  92     parameters => {
  93         additionalProperties => 0,
  94         properties => {
  95             vmid => get_standard_option('pve-vmid'),
  96         },
  97     },
  98     returns => { type => 'null'},
  99     code => sub {
 100         my ($param) = @_;
 101
 102         my $storecfg = PVE::Storage::config();
 103         print PVE::QemuServer::vm_commandline($storecfg, $param->{vmid}) . "\n";
 104
 105         return undef;
 106     }});
 107
 108 __PACKAGE__->register_method ({
 109     name => 'status',
 110     path => 'status',
 111     method => 'GET',
 112     description => "Show VM status.",
 113     parameters => {
 114         additionalProperties => 0,
 115         properties => {
 116             vmid => get_standard_option('pve-vmid'),
 117             verbose => {
 118                 description => "Verbose output format",
 119                 type => 'boolean',
 120                 optional => 1,
 121             }
 122         },
 123     },
 124     returns => { type => 'null'},
 125     code => sub {
 126         my ($param) = @_;
 127
 128         # test if VM exists
 129         my $conf = PVE::QemuServer::load_config ($param->{vmid});
 130
 131         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid});
 132         my $stat = $vmstatus->{$param->{vmid}};
 133         if ($param->{verbose}) {
 134             foreach my $k (sort (keys %$stat)) {
 135                 next if $k eq 'cpu' || $k eq 'relcpu'; # always 0
 136                 my $v = $stat->{$k};
 137                 next if !defined($v);
 138                 print "$k: $v\n";
 139             }
 140         } else {
 141             my $status = $stat->{status} || 'unknown';
 142             print "status: $status\n";
 143         }
 144
 145         return undef;
 146     }});
 147
 148 __PACKAGE__->register_method ({
 149     name => 'vncproxy',
 150     path => 'vncproxy',
 151     method => 'PUT',
 152     description => "Proxy VM VNC traffic to stdin/stdout",
 153     parameters => {
 154         additionalProperties => 0,
 155         properties => {
 156             vmid => get_standard_option('pve-vmid'),
 157         },
 158     },
 159     returns => { type => 'null'},
 160     code => sub {
 161         my ($param) = @_;
 162
 163         my $vmid = $param->{vmid};
 164
 165         run_vnc_proxy ($vmid);
 166
 167         return undef;
 168     }});
 169
 170 __PACKAGE__->register_method ({
 171     name => 'unlock',
 172     path => 'unlock',
 173     method => 'PUT',
 174     description => "Unlock the VM.",
 175     parameters => {
 176         additionalProperties => 0,
 177         properties => {
 178             vmid => get_standard_option('pve-vmid'),
 179         },
 180     },
 181     returns => { type => 'null'},
 182     code => sub {
 183         my ($param) = @_;
 184
 185         my $vmid = $param->{vmid};
 186
 187         PVE::QemuServer::lock_config ($vmid, sub {
 188             PVE::QemuServer::change_config_nolock  ($vmid, {}, { lock => 1 }, 1);
 189         });
 190
 191         return undef;
 192     }});
 193
 194 __PACKAGE__->register_method ({
 195     name => 'mtunnel',
 196     path => 'mtunnel',
 197     method => 'POST',
 198     description => "Used by qmigrate - do not use manually.",
 199     parameters => {
 200         additionalProperties => 0,
 201         properties => {},
 202     },
 203     returns => { type => 'null'},
 204     code => sub {
 205         my ($param) = @_;
 206
 207         if (!PVE::Cluster::check_cfs_quorum(1)) {
 208             print "no quorum\n";
 209             return undef;
 210         }
 211
 212         print "tunnel online\n";
 213         *STDOUT->flush();
 214
 215         while (my $line = <>) {
 216             chomp $line;
 217             last if $line =~ m/^quit$/;
 218         }
 219
 220         return undef;
 221     }});
 222
 223 __PACKAGE__->register_method ({
 224     name => 'startall',
 225     path => 'startall',
 226     method => 'POST',
 227     description => "Start all virtual machines (when onboot=1).",
 228     parameters => {
 229         additionalProperties => 0,
 230         properties => {},
 231     },
 232     returns => { type => 'null'},
 233     code => sub {
 234         my ($param) = @_;
 235
 236         my $vzlist = PVE::QemuServer::vzlist();
 237         my $storecfg = PVE::Storage::config();
 238
 239         PVE::Cluster::check_cfs_quorum();
 240
 241         my $count = 0;
 242         foreach my $vmid (keys %$vzlist) {
 243             next if $vzlist->{$vmid}->{pid}; # already running
 244
 245             sleep(2) if $count != 0; # reduce load
 246             $count++;
 247
 248             PVE::Cluster::check_cfs_quorum(); # abort when we loose quorum
 249
 250             eval {
 251                 my $conf = PVE::QemuServer::load_config($vmid);
 252                 if ($conf->{onboot}) {
 253                     print STDERR "Starting Qemu VM $vmid\n";
 254                     PVE::QemuServer::vm_start($storecfg, $vmid);
 255                 }
 256             };
 257             print STDERR $@ if $@;
 258         }
 259
 260         return undef;
 261     }});
 262
 263 __PACKAGE__->register_method ({
 264     name => 'stopall',
 265     path => 'stopall',
 266     method => 'POST',
 267     description => "Stop all virtual machines.",
 268     parameters => {
 269         additionalProperties => 0,
 270         properties => {
 271             timeout => {
 272                 description => "Timeout in seconds. Default is to wait 3 minutes.",
 273                 type => 'integer',
 274                 minimum => 1,
 275                 optional => 1,
 276             }
 277         },
 278     },
 279     returns => { type => 'null'},
 280     code => sub {
 281         my ($param) = @_;
 282
 283         my $timeout = $param->{timeout};
 284
 285         my $storecfg = PVE::Storage::config();
 286
 287         PVE::QemuServer::vm_stopall($storecfg, $timeout);
 288
 289         return undef;
 290     }});
 291
 292 __PACKAGE__->register_method ({
 293     name => 'wait',
 294     path => 'wait',
 295     method => 'GET',
 296     description => "Wait until the VM is stopped.",
 297     parameters => {
 298         additionalProperties => 0,
 299         properties => {
 300             vmid => get_standard_option('pve-vmid'),
 301             timeout => {
 302                 description => "Timeout in seconds. Default is to wait forever.",
 303                 type => 'integer',
 304                 minimum => 1,
 305                 optional => 1,
 306             }
 307         },
 308     },
 309     returns => { type => 'null'},
 310     code => sub {
 311         my ($param) = @_;
 312
 313         my $vmid = $param->{vmid};
 314         my $timeout = $param->{timeout};
 315
 316         my $pid = PVE::QemuServer::check_running ($vmid);
 317         return if !$pid;
 318
 319         print "waiting until VM $vmid stopps (PID $pid)\n";
 320
 321         my $count = 0;
 322         while ((!$timeout || ($count < $timeout)) && PVE::QemuServer::check_running ($vmid)) {
 323             $count++;
 324             sleep 1;
 325         }
 326
 327         die "wait failed - got timeout\n" if PVE::QemuServer::check_running ($vmid);
 328
 329         return undef;
 330     }});
 331
 332 __PACKAGE__->register_method ({
 333     name => 'monitor',
 334     path => 'monitor',
 335     method => 'POST',
 336     description => "Enter Qemu Monitor interface.",
 337     parameters => {
 338         additionalProperties => 0,
 339         properties => {
 340             vmid => get_standard_option('pve-vmid'),
 341         },
 342     },
 343     returns => { type => 'null'},
 344     code => sub {
 345         my ($param) = @_;
 346
 347         my $vmid = $param->{vmid};
 348
 349         my $conf = PVE::QemuServer::load_config ($vmid); # check if VM exists
 350
 351         print "Entering Qemu Monitor for VM $vmid - type 'help' for help\n";
 352
 353         my $term = new Term::ReadLine ('qm');
 354
 355         my $input;
 356         while (defined ($input = $term->readline('qm> '))) {
 357             chomp $input;
 358
 359             next if $input =~ m/^\s*$/;
 360
 361             last if $input =~ m/^\s*q(uit)?\s*$/;
 362
 363             eval {
 364                 print PVE::QemuServer::vm_monitor_command ($vmid, $input);
 365             };
 366             print "ERROR: $@" if $@;
 367         }
 368
 369         return undef;
 370
 371     }});
 372
 373 my $cmddef = {
 374     list => [ "PVE::API2::Qemu", 'vmlist', [],
 375              { node => $nodename }, sub {
 376                  my $vmlist = shift;
 377
 378                  exit 0 if (!scalar(@$vmlist));
 379
 380                  printf "%10s %-20s %-10s %-10s %12s %-10s\n",
 381                  qw(VMID NAME STATUS MEM(MB) BOOTDISK(GB) PID);
 382
 383                  foreach my $rec (sort { $a->{vmid} <=> $b->{vmid} } @$vmlist) {
 384                      printf "%10s %-20s %-10s %-10s %12.2f %-10s\n", $rec->{vmid}, $rec->{name},
 385                      $rec->{status},
 386                      ($rec->{maxmem} || 0)/(1024*1024),
 387                      ($rec->{maxdisk} || 0)/(1024*1024*1024),
 388                      $rec->{pid}||0;
 389                  }
 390
 391
 392               } ],
 393
 394     create => [ "PVE::API2::Qemu", 'create_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 395
 396     destroy => [ "PVE::API2::Qemu", 'destroy_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 397
 398     migrate => [ "PVE::API2::Qemu", 'migrate_vm', ['vmid', 'target'], { node => $nodename }, $upid_exit ],
 399
 400     set => [ "PVE::API2::Qemu", 'update_vm', ['vmid'], { node => $nodename } ],
 401
 402     unlink => [ "PVE::API2::Qemu", 'unlink', ['vmid', 'idlist'], { node => $nodename } ],
 403
 404     config => [ "PVE::API2::Qemu", 'vm_config', ['vmid'],
 405                 { node => $nodename }, sub {
 406                     my $config = shift;
 407                     foreach my $k (sort (keys %$config)) {
 408                         next if $k eq 'digest';
 409                         my $v = $config->{$k};
 410                         if ($k eq 'description') {
 411                             $v = PVE::Tools::encode_text($v);
 412                         }
 413                         print "$k: $v\n";
 414                     }
 415                 }],
 416
 417     showcmd => [ __PACKAGE__, 'showcmd', ['vmid']],
 418
 419     status => [ __PACKAGE__, 'status', ['vmid']],
 420
 421     start => [ "PVE::API2::Qemu", 'vm_start', ['vmid'], { node => $nodename } , $upid_exit ],
 422
 423     stop => [ "PVE::API2::Qemu", 'vm_stop', ['vmid'], { node => $nodename }, $upid_exit ],
 424
 425     reset => [ "PVE::API2::Qemu", 'vm_reset', ['vmid'], { node => $nodename }, $upid_exit ],
 426
 427     shutdown => [ "PVE::API2::Qemu", 'vm_shutdown', ['vmid'], { node => $nodename }, $upid_exit ],
 428
 429     suspend => [ "PVE::API2::Qemu", 'vm_suspend', ['vmid'], { node => $nodename }, $upid_exit ],
 430
 431     resume => [ "PVE::API2::Qemu", 'vm_resume', ['vmid'], { node => $nodename }, $upid_exit ],
 432
 433     sendkey => [ "PVE::API2::Qemu", 'vm_sendkey', ['vmid', 'key'], { node => $nodename } ],
 434
 435     vncproxy => [ __PACKAGE__, 'vncproxy', ['vmid']],
 436
 437     wait => [ __PACKAGE__, 'wait', ['vmid']],
 438
 439     unlock => [ __PACKAGE__, 'unlock', ['vmid']],
 440
 441     monitor  => [ __PACKAGE__, 'monitor', ['vmid']],
 442
 443     startall => [ __PACKAGE__, 'startall', []],
 444
 445     stopall => [ __PACKAGE__, 'stopall', []],
 446
 447     mtunnel => [ __PACKAGE__, 'mtunnel', []],
 448 };
 449
 450 my $cmd = shift;
 451
 452 PVE::CLIHandler::handle_cmd($cmddef, "qm", $cmd, \@ARGV, undef, $0);
 453
 454 exit 0;
 455
 456 __END__
 457
 458 =head1 NAME
 459
 460 qm - qemu/kvm virtual machine manager
 461
 462 =head1 SYNOPSIS
 463
 464 =include synopsis
 465
 466 =head1 DESCRIPTION
 467
 468 qm is a script to manage virtual machines with qemu/kvm. You can
 469 create and destroy virtual machines, and control execution
 470 (start/stop/suspend/resume). Besides that, you can use qm to set
 471 parameters in the associated config file. It is also possible to
 472 create and delete virtual disks.
 473
 474 =head1 CONFIGURATION
 475
 476 All configuration files consists of lines in the form
 477
 478        PARAMETER: value
 479
 480 See L<vm.conf|vm.conf> for a complete list of options.
 481
 482 Configuration files are stored inside the Proxmox configuration file system, and can be access at F</etc/pve/qemu-server/C<VMID>.conf>.
 483
 484 The default for option 'keyboard' is read from
 485 F</etc/pve/datacenter.conf>.
 486
 487 =head1 Locks
 488
 489 Online migration and backups (vzdump) set a lock to prevent
 490 unintentional action on such VMs. Sometimes you need remove such lock
 491 manually (power failure).
 492
 493  qm unlock <vmid>
 494
 495 =head1 EXAMPLES
 496
 497  # create a new VM with 4 GB ide disk
 498  qm create 300 -ide0 4 -net0 e1000 -cdrom proxmox-mailgateway_2.1.iso
 499
 500  # start the new VM
 501  qm start 300
 502
 503  # send shutdown, then wait until VM is stopped
 504  qm shutdown 300 && qm wait 300
 505
 506  # same as above, but only wait for 40 seconds
 507  qm shutdown 300 && qm wait 300 -timeout 40
 508
 509
 510 =include pve_copyright