add missing import of 'agent_cmd'

[qemu-server.git] / PVE / API2 / Qemu / Agent.pm

diff --git a/PVE/API2/Qemu/Agent.pm b/PVE/API2/Qemu/Agent.pm
index 5dbce8b12abb465e04e754f1c77bb15b3168755d..d985b70f37999d7acf2ffe24b5d57ad9696ad0ab 100644 (file)
--- a/PVE/API2/Qemu/Agent.pm
+++ b/PVE/API2/Qemu/Agent.pm
@@ -6,12 +6,15 @@ use warnings;
 use PVE::RESTHandler;
 use PVE::JSONSchema qw(get_standard_option);
 use PVE::QemuServer;
-use PVE::QemuServer::Agent qw(agent_available);
+use PVE::QemuServer::Agent qw(agent_available agent_cmd);
 use MIME::Base64 qw(encode_base64 decode_base64);
 use JSON;
 
 use base qw(PVE::RESTHandler);
 
+# max size for file-read over the api
+my $MAX_READ_SIZE = 16 * 1024 * 1024; # 16 MiB
+
 # list of commands
 # will generate one api endpoint per command
 # needs a 'method' property and optionally a 'perms' property (default VM.Monitor)
@@ -114,6 +117,8 @@ __PACKAGE__->register_method({
        push @$cmds, qw(
            exec
            exec-status
+           file-read
+           file-write
            set-user-password
        );
 
@@ -362,4 +367,115 @@ __PACKAGE__->register_method({
        return $res;
     }});
 
+__PACKAGE__->register_method({
+    name => 'file-read',
+    path => 'file-read',
+    method => 'GET',
+    protected => 1,
+    proxyto => 'node',
+    description => "Reads the given file via guest agent. Is limited to $MAX_READ_SIZE bytes.",
+    permissions => { check => [ 'perm', '/vms/{vmid}', [ 'VM.Monitor' ]]},
+    parameters => {
+       additionalProperties => 0,
+       properties => {
+           node => get_standard_option('pve-node'),
+           vmid => get_standard_option('pve-vmid', {
+                   completion => \&PVE::QemuServer::complete_vmid_running }),
+           file => {
+               type => 'string',
+               description => 'The path to the file'
+           },
+       },
+    },
+    returns => {
+       type => 'object',
+       description => "Returns an object with a `content` property.",
+       properties => {
+           content => {
+               type => 'string',
+               description => "The content of the file, maximum $MAX_READ_SIZE",
+           },
+           truncated => {
+               type => 'boolean',
+               optional => 1,
+               description => "If set to 1, the output is truncated and not complete"
+           }
+       },
+    },
+    code => sub {
+       my ($param) = @_;
+
+       my $vmid = $param->{vmid};
+
+       my $qgafh = agent_cmd($vmid, "file-open",  { path => $param->{file} }, "can't open file");
+
+       my $bytes_left = $MAX_READ_SIZE;
+       my $eof = 0;
+       my $read_size = 1024*1024;
+       my $content = "";
+
+       while ($bytes_left > 0 && !$eof) {
+           my $read = PVE::QemuServer::vm_mon_cmd($vmid, "guest-file-read", handle => $qgafh, count => int($read_size));
+           check_agent_error($read, "can't read from file");
+
+           $content .= decode_base64($read->{'buf-b64'});
+           $bytes_left -= $read->{count};
+           $eof = $read->{eof} // 0;
+       }
+
+       my $res = PVE::QemuServer::vm_mon_cmd($vmid, "guest-file-close", handle => $qgafh);
+       check_agent_error($res, "can't close file", 1);
+
+       my $result = {
+           content => $content,
+           'bytes-read' => ($MAX_READ_SIZE-$bytes_left),
+       };
+
+       if (!$eof) {
+           warn "agent file-read: reached maximum read size: $MAX_READ_SIZE bytes. output might be truncated.\n";
+           $result->{truncated} = 1;
+       }
+
+       return $result;
+    }});
+
+__PACKAGE__->register_method({
+    name => 'file-write',
+    path => 'file-write',
+    method => 'POST',
+    protected => 1,
+    proxyto => 'node',
+    description => "Writes the given file via guest agent.",
+    permissions => { check => [ 'perm', '/vms/{vmid}', [ 'VM.Monitor' ]]},
+    parameters => {
+       additionalProperties => 0,
+       properties => {
+           node => get_standard_option('pve-node'),
+           vmid => get_standard_option('pve-vmid', {
+                   completion => \&PVE::QemuServer::complete_vmid_running }),
+           file => {
+               type => 'string',
+               description => 'The path to the file.'
+           },
+           content => {
+               type => 'string',
+               maxLength => 60*1024, # 60k, smaller than our 64k POST limit
+               description => "The content to write into the file."
+           }
+       },
+    },
+    returns => { type => 'null' },
+    code => sub {
+       my ($param) = @_;
+
+       my $vmid = $param->{vmid};
+       my $buf = encode_base64($param->{content});
+
+       my $qgafh = agent_cmd($vmid, "file-open",  { path => $param->{file}, mode => 'wb' }, "can't open file");
+       my $write = agent_cmd($vmid, "file-write", { handle => $qgafh, 'buf-b64' => $buf }, "can't write to file");
+       my $res = agent_cmd($vmid, "file-close", { handle => $qgafh }, "can't close file");
+
+       return undef;
+    }});
+
 1;