OpenZFS 9185 - Enable testing over NFS in ZFS performance tests

[mirror_zfs.git] / config / kernel-acl.m4

diff --git a/config/kernel-acl.m4 b/config/kernel-acl.m4
index d2a1821c57d4d298de809a64b83588cf100c7890..02cc020e5c90554e364f117e7cf5034cc98daca6 100644 (file)
--- a/config/kernel-acl.m4
+++ b/config/kernel-acl.m4
@@ -40,6 +40,35 @@ AC_DEFUN([ZFS_AC_KERNEL_POSIX_ACL_RELEASE], [
        ])
 ])
 
+dnl #
+dnl # 3.14 API change,
+dnl # set_cached_acl() and forget_cached_acl() changed from inline to
+dnl # EXPORT_SYMBOL. In the former case, they may not be usable because of
+dnl # posix_acl_release. In the latter case, we can always use them.
+dnl #
+AC_DEFUN([ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE], [
+       AC_MSG_CHECKING([whether set_cached_acl() is usable])
+       ZFS_LINUX_TRY_COMPILE([
+               #include <linux/module.h>
+               #include <linux/cred.h>
+               #include <linux/fs.h>
+               #include <linux/posix_acl.h>
+
+               MODULE_LICENSE("$ZFS_META_LICENSE");
+       ],[
+               struct inode *ip = NULL;
+               struct posix_acl *acl = posix_acl_alloc(1, 0);
+               set_cached_acl(ip, ACL_TYPE_ACCESS, acl);
+               forget_cached_acl(ip, ACL_TYPE_ACCESS);
+       ],[
+               AC_MSG_RESULT(yes)
+               AC_DEFINE(HAVE_SET_CACHED_ACL_USABLE, 1,
+                   [posix_acl_release() is usable])
+       ],[
+               AC_MSG_RESULT(no)
+       ])
+])
+
 dnl #
 dnl # 3.1 API change,
 dnl # posix_acl_chmod_masq() is not exported anymore and posix_acl_chmod()
@@ -155,6 +184,7 @@ AC_DEFUN([ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA], [
        AC_MSG_CHECKING([whether iops->permission() wants nameidata])
        ZFS_LINUX_TRY_COMPILE([
                #include <linux/fs.h>
+               #include <linux/sched.h>
 
                int permission_fn(struct inode *inode, int mask,
                    struct nameidata *nd) { return 0; }
@@ -249,3 +279,48 @@ AC_DEFUN([ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL], [
                AC_MSG_RESULT(no)
        ])
 ])
+
+dnl #
+dnl # 3.14 API change,
+dnl # Check if inode_operations contains the function set_acl
+dnl #
+AC_DEFUN([ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL], [
+       AC_MSG_CHECKING([whether iops->set_acl() exists])
+       ZFS_LINUX_TRY_COMPILE([
+               #include <linux/fs.h>
+
+               int set_acl_fn(struct inode *inode, struct posix_acl *acl, int type)
+                   { return 0; }
+
+               static const struct inode_operations
+                   iops __attribute__ ((unused)) = {
+                       .set_acl = set_acl_fn,
+               };
+       ],[
+       ],[
+               AC_MSG_RESULT(yes)
+               AC_DEFINE(HAVE_SET_ACL, 1, [iops->set_acl() exists])
+       ],[
+               AC_MSG_RESULT(no)
+       ])
+])
+
+dnl #
+dnl # 4.7 API change,
+dnl # The kernel get_acl will now check cache before calling i_op->get_acl and
+dnl # do set_cached_acl after that, so i_op->get_acl don't need to do that
+dnl # anymore.
+dnl #
+AC_DEFUN([ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE], [
+       AC_MSG_CHECKING([whether uncached_acl_sentinel() exists])
+       ZFS_LINUX_TRY_COMPILE([
+               #include <linux/fs.h>
+       ],[
+               void *sentinel __attribute__ ((unused)) = uncached_acl_sentinel(NULL);
+       ],[
+               AC_MSG_RESULT(yes)
+               AC_DEFINE(HAVE_KERNEL_GET_ACL_HANDLE_CACHE, 1, [uncached_acl_sentinel() exists])
+       ],[
+               AC_MSG_RESULT(no)
+       ])
+])