update ceph source to reef 18.1.2

[ceph.git] / ceph / src / jaegertracing / opentelemetry-cpp / tools / vcpkg / scripts / cmake / vcpkg_build_nmake.cmake

#[===[.md:\r
# vcpkg_build_nmake\r
\r
Build a msvc makefile project.\r
\r
## Usage:\r
```cmake\r
vcpkg_build_nmake(\r
    SOURCE_PATH <${SOURCE_PATH}>\r
    [NO_DEBUG]\r
    [TARGET <all>]\r
    [PROJECT_SUBPATH <${SUBPATH}>]\r
    [PROJECT_NAME <${MAKEFILE_NAME}>]\r
    [PRERUN_SHELL <${SHELL_PATH}>]\r
    [PRERUN_SHELL_DEBUG <${SHELL_PATH}>]\r
    [PRERUN_SHELL_RELEASE <${SHELL_PATH}>]\r
    [OPTIONS <-DUSE_THIS_IN_ALL_BUILDS=1>...]\r
    [OPTIONS_RELEASE <-DOPTIMIZE=1>...]\r
    [OPTIONS_DEBUG <-DDEBUGGABLE=1>...]\r
    [TARGET <target>])\r
```\r
\r
## Parameters\r
### SOURCE_PATH\r
Specifies the directory containing the source files.\r
By convention, this is usually set in the portfile as the variable `SOURCE_PATH`.\r
\r
### PROJECT_SUBPATH\r
Specifies the sub directory containing the `makefile.vc`/`makefile.mak`/`makefile.msvc` or other msvc makefile.\r
\r
### PROJECT_NAME\r
Specifies the name of msvc makefile name.\r
Default is `makefile.vc`\r
\r
### NO_DEBUG\r
This port doesn't support debug mode.\r
\r
### ENABLE_INSTALL\r
Install binaries after build.\r
\r
### PRERUN_SHELL\r
Script that needs to be called before build\r
\r
### PRERUN_SHELL_DEBUG\r
Script that needs to be called before debug build\r
\r
### PRERUN_SHELL_RELEASE\r
Script that needs to be called before release build\r
\r
### OPTIONS\r
Additional options passed to generate during the generation.\r
\r
### OPTIONS_RELEASE\r
Additional options passed to generate during the Release generation. These are in addition to `OPTIONS`.\r
\r
### OPTIONS_DEBUG\r
Additional options passed to generate during the Debug generation. These are in addition to `OPTIONS`.\r
\r
### TARGET\r
The target passed to the nmake build command (`nmake/nmake install`). If not specified, no target will\r
be passed.\r
\r
### ADD_BIN_TO_PATH\r
Adds the appropriate Release and Debug `bin\` directories to the path during the build such that executables can run against the in-tree DLLs.\r
\r
## Notes:\r
This command should be preceded by a call to [`vcpkg_configure_nmake()`](vcpkg_configure_nmake.md).\r
You can use the alias [`vcpkg_install_nmake()`](vcpkg_install_nmake.md) function if your makefile supports the\r
"install" target\r
\r
## Examples\r
\r
* [tcl](https://github.com/Microsoft/vcpkg/blob/master/ports/tcl/portfile.cmake)\r
* [freexl](https://github.com/Microsoft/vcpkg/blob/master/ports/freexl/portfile.cmake)\r
#]===]\r
\r
function(vcpkg_build_nmake)\r
    # parse parameters such that semicolons in options arguments to COMMAND don't get erased\r
    cmake_parse_arguments(PARSE_ARGV 0 _bn\r
        "ADD_BIN_TO_PATH;ENABLE_INSTALL;NO_DEBUG"\r
        "SOURCE_PATH;PROJECT_SUBPATH;PROJECT_NAME;LOGFILE_ROOT"\r
        "OPTIONS;OPTIONS_RELEASE;OPTIONS_DEBUG;PRERUN_SHELL;PRERUN_SHELL_DEBUG;PRERUN_SHELL_RELEASE;TARGET"\r
    )\r
    \r
    if (NOT CMAKE_HOST_WIN32)\r
        message(FATAL_ERROR "vcpkg_build_nmake only support windows.")\r
    endif()\r
    \r
    if (_bn_OPTIONS_DEBUG STREQUAL _bn_OPTIONS_RELEASE)\r
        message(FATAL_ERROR "Detected debug configuration is equal to release configuration, please use NO_DEBUG for vcpkg_build_nmake/vcpkg_install_nmake")\r
    endif()\r
\r
    if(NOT _bn_LOGFILE_ROOT)\r
        set(_bn_LOGFILE_ROOT "build")\r
    endif()\r
    \r
    if (NOT _bn_PROJECT_NAME)\r
        set(MAKEFILE_NAME makefile.vc)\r
    else()\r
        set(MAKEFILE_NAME ${_bn_PROJECT_NAME})\r
    endif()\r
    \r
    set(MAKE )\r
    set(MAKE_OPTS_BASE )\r
    \r
    find_program(NMAKE nmake REQUIRED)\r
    get_filename_component(NMAKE_EXE_PATH ${NMAKE} DIRECTORY)\r
    # Load toolchains\r
    if(NOT VCPKG_CHAINLOAD_TOOLCHAIN_FILE)\r
        set(VCPKG_CHAINLOAD_TOOLCHAIN_FILE "${SCRIPTS}/toolchains/windows.cmake")\r
    endif()\r
    include("${VCPKG_CHAINLOAD_TOOLCHAIN_FILE}")\r
    # Set needed env\r
    set(ENV{PATH} "$ENV{PATH};${NMAKE_EXE_PATH}")\r
    set(ENV{INCLUDE} "${CURRENT_INSTALLED_DIR}/include;$ENV{INCLUDE}")\r
    # Set make command and install command\r
    set(MAKE ${NMAKE} /NOLOGO /G /U)\r
    set(MAKE_OPTS_BASE -f ${MAKEFILE_NAME})\r
    if (_bn_ENABLE_INSTALL)\r
        set(INSTALL_COMMAND install)\r
    endif()\r
    if (_bn_TARGET)\r
        set(MAKE_OPTS_BASE ${MAKE_OPTS_BASE} ${_bn_TARGET} ${INSTALL_COMMAND})\r
    else()\r
        set(MAKE_OPTS_BASE ${MAKE_OPTS_BASE} all ${INSTALL_COMMAND})\r
    endif()\r
    # Add subpath to work directory\r
    if (_bn_PROJECT_SUBPATH)\r
        set(_bn_PROJECT_SUBPATH /${_bn_PROJECT_SUBPATH})\r
    else()\r
        set(_bn_PROJECT_SUBPATH )\r
    endif()\r
    \r
    foreach(BUILDTYPE "debug" "release")\r
        if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL BUILDTYPE)\r
            if(BUILDTYPE STREQUAL "debug")\r
                # Skip debug generate\r
                if (_bn_NO_DEBUG)\r
                    continue()\r
                endif()\r
                # Generate obj dir suffix\r
                set(SHORT_BUILDTYPE "-dbg")\r
                set(CONFIG "Debug")\r
                # Add install command and arguments\r
                set(MAKE_OPTS ${MAKE_OPTS_BASE})\r
                if (_bn_ENABLE_INSTALL)\r
                    set(INSTALL_OPTS INSTALLDIR=${CURRENT_PACKAGES_DIR}/debug)\r
                    set(MAKE_OPTS ${MAKE_OPTS} ${INSTALL_OPTS})\r
                endif()\r
                set(MAKE_OPTS ${MAKE_OPTS} ${_bn_OPTIONS} ${_bn_OPTIONS_DEBUG})\r
                \r
                unset(ENV{CL})\r
                set(TMP_CL_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")\r
                string(REPLACE "/" "-" TMP_CL_FLAGS "${TMP_CL_FLAGS}")\r
                set(ENV{CL} "$ENV{CL} ${TMP_CL_FLAGS}")\r
            else()\r
                # In NO_DEBUG mode, we only use ${TARGET_TRIPLET} directory.\r
                if (_bn_NO_DEBUG)\r
                    set(SHORT_BUILDTYPE "")\r
                else()\r
                    set(SHORT_BUILDTYPE "-rel")\r
                endif()\r
                set(CONFIG "Release")\r
                # Add install command and arguments\r
                set(MAKE_OPTS ${MAKE_OPTS_BASE})\r
                if (_bn_ENABLE_INSTALL)\r
                    set(INSTALL_OPTS INSTALLDIR=${CURRENT_PACKAGES_DIR})\r
                    set(MAKE_OPTS ${MAKE_OPTS} ${INSTALL_OPTS})\r
                endif()\r
                set(MAKE_OPTS ${MAKE_OPTS} ${_bn_OPTIONS} ${_bn_OPTIONS_RELEASE})\r
                \r
                unset(ENV{CL})\r
                set(TMP_CL_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")\r
                string(REPLACE "/" "-" TMP_CL_FLAGS "${TMP_CL_FLAGS}")\r
                set(ENV{CL} "$ENV{CL} ${TMP_CL_FLAGS}")\r
            endif()\r
            \r
            set(CURRENT_TRIPLET_NAME ${TARGET_TRIPLET}${SHORT_BUILDTYPE})\r
            set(OBJ_DIR ${CURRENT_BUILDTREES_DIR}/${CURRENT_TRIPLET_NAME})\r
            \r
            file(REMOVE_RECURSE ${OBJ_DIR})\r
            file(MAKE_DIRECTORY ${OBJ_DIR})\r
            file(GLOB_RECURSE SOURCE_FILES ${_bn_SOURCE_PATH}/*)\r
            foreach(ONE_SOUCRCE_FILE ${SOURCE_FILES})\r
                get_filename_component(DST_DIR ${ONE_SOUCRCE_FILE} PATH)\r
                string(REPLACE "${_bn_SOURCE_PATH}" "${OBJ_DIR}" DST_DIR "${DST_DIR}")\r
                file(COPY ${ONE_SOUCRCE_FILE} DESTINATION ${DST_DIR})\r
            endforeach()\r
            \r
            if (_bn_PRERUN_SHELL)\r
                message(STATUS "Prerunning ${CURRENT_TRIPLET_NAME}")\r
                vcpkg_execute_required_process(\r
                    COMMAND ${_bn_PRERUN_SHELL}\r
                    WORKING_DIRECTORY ${OBJ_DIR}${_bn_PROJECT_SUBPATH}\r
                    LOGNAME "$prerun-${CURRENT_TRIPLET_NAME}"\r
                )\r
            endif()\r
            if (BUILDTYPE STREQUAL "debug" AND _bn_PRERUN_SHELL_DEBUG)\r
                message(STATUS "Prerunning ${CURRENT_TRIPLET_NAME}")\r
                vcpkg_execute_required_process(\r
                    COMMAND ${_bn_PRERUN_SHELL_DEBUG}\r
                    WORKING_DIRECTORY ${OBJ_DIR}${_bn_PROJECT_SUBPATH}\r
                    LOGNAME "prerun-${CURRENT_TRIPLET_NAME}-dbg"\r
                )\r
            endif()\r
            if (BUILDTYPE STREQUAL "release" AND _bn_PRERUN_SHELL_RELEASE)\r
                message(STATUS "Prerunning ${CURRENT_TRIPLET_NAME}")\r
                vcpkg_execute_required_process(\r
                    COMMAND ${_bn_PRERUN_SHELL_RELEASE}\r
                    WORKING_DIRECTORY ${OBJ_DIR}${_bn_PROJECT_SUBPATH}\r
                    LOGNAME "prerun-${CURRENT_TRIPLET_NAME}-rel"\r
                )\r
            endif()\r
\r
            if (NOT _bn_ENABLE_INSTALL)\r
                message(STATUS "Building ${CURRENT_TRIPLET_NAME}")\r
            else()\r
                message(STATUS "Building and installing ${CURRENT_TRIPLET_NAME}")\r
            endif()\r
\r
            vcpkg_execute_build_process(\r
                COMMAND ${MAKE} ${MAKE_OPTS}\r
                WORKING_DIRECTORY ${OBJ_DIR}${_bn_PROJECT_SUBPATH}\r
                LOGNAME "${_bn_LOGFILE_ROOT}-${CURRENT_TRIPLET_NAME}"\r
            )\r
\r
            if(_bn_ADD_BIN_TO_PATH)\r
                set(ENV{PATH} "${_BACKUP_ENV_PATH}")\r
            endif()\r
        endif()\r
    endforeach()\r
endfunction()\r