update ceph source to reef 18.1.2

[ceph.git] / ceph / src / jaegertracing / opentelemetry-cpp / tools / vcpkg / scripts / cmake / vcpkg_internal_get_cmake_vars.cmake

#[===[.md:\r
# vcpkg_internal_get_cmake_vars\r
\r
**Only for internal use in vcpkg helpers. Behavior and arguments will change without notice.**\r
Runs a cmake configure with a dummy project to extract certain cmake variables\r
\r
## Usage\r
```cmake\r
vcpkg_internal_get_cmake_vars(\r
    [OUTPUT_FILE <output_file_with_vars>]\r
    [OPTIONS <-DUSE_THIS_IN_ALL_BUILDS=1>...]\r
)\r
```\r
\r
## Parameters\r
### OPTIONS\r
Additional options to pass to the test configure call \r
\r
### OUTPUT_FILE\r
Variable to return the path to the generated cmake file with the detected `CMAKE_` variables set as `VCKPG_DETECTED_`\r
\r
## Notes\r
If possible avoid usage in portfiles. \r
\r
## Examples\r
\r
* [vcpkg_configure_make](https://github.com/Microsoft/vcpkg/blob/master/scripts/cmake/vcpkg_configure_make.cmake)\r
#]===]\r
\r
function(vcpkg_internal_get_cmake_vars)\r
    cmake_parse_arguments(PARSE_ARGV 0 _gcv "" "OUTPUT_FILE" "OPTIONS")\r
\r
    if(_gcv_UNPARSED_ARGUMENTS)\r
        message(FATAL_ERROR "${CMAKE_CURRENT_FUNCTION} was passed unparsed arguments: '${_gcv_UNPARSED_ARGUMENTS}'")\r
    endif()\r
\r
    if(NOT _gcv_OUTPUT_FILE)\r
        message(FATAL_ERROR "${CMAKE_CURRENT_FUNCTION} requires parameter OUTPUT_FILE!")\r
    endif()\r
\r
    if(${_gcv_OUTPUT_FILE})\r
        debug_message("OUTPUT_FILE ${${_gcv_OUTPUT_FILE}}")\r
    else()\r
        set(DEFAULT_OUT "${CURRENT_BUILDTREES_DIR}/cmake-vars-${TARGET_TRIPLET}.cmake.log") # So that the file gets included in CI artifacts.\r
        set(${_gcv_OUTPUT_FILE} "${DEFAULT_OUT}" PARENT_SCOPE)\r
        set(${_gcv_OUTPUT_FILE} "${DEFAULT_OUT}")\r
    endif()\r
\r
    vcpkg_configure_cmake(\r
        SOURCE_PATH "${SCRIPTS}/get_cmake_vars"\r
        OPTIONS ${_gcv_OPTIONS} "-DVCPKG_BUILD_TYPE=${VCPKG_BUILD_TYPE}"\r
        OPTIONS_DEBUG "-DVCPKG_OUTPUT_FILE:PATH=${CURRENT_BUILDTREES_DIR}/cmake-vars-${TARGET_TRIPLET}-dbg.cmake.log"\r
        OPTIONS_RELEASE "-DVCPKG_OUTPUT_FILE:PATH=${CURRENT_BUILDTREES_DIR}/cmake-vars-${TARGET_TRIPLET}-rel.cmake.log"\r
        PREFER_NINJA\r
        LOGNAME get-cmake-vars-${TARGET_TRIPLET}\r
    )\r
\r
    set(_include_string)\r
    if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "release")\r
        string(APPEND _include_string "include(\"${CURRENT_BUILDTREES_DIR}/cmake-vars-${TARGET_TRIPLET}-rel.cmake.log\")\n")\r
    endif()\r
    if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "debug")\r
        string(APPEND _include_string "include(\"${CURRENT_BUILDTREES_DIR}/cmake-vars-${TARGET_TRIPLET}-dbg.cmake.log\")\n")\r
    endif()\r
    file(WRITE "${${_gcv_OUTPUT_FILE}}" "${_include_string}")\r
\r
endfunction()\r