ceph/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.5.1)
   2
   3 project(ceph CXX C ASM)
   4 set(VERSION 14.2.8)
   5
   6 if(POLICY CMP0028)
   7   cmake_policy(SET CMP0028 NEW)
   8 endif()
   9 if(POLICY CMP0046)
  10   cmake_policy(SET CMP0046 NEW)
  11 endif()
  12 if(POLICY CMP0054)
  13   cmake_policy(SET CMP0054 NEW)
  14 endif()
  15 if(POLICY CMP0056)
  16   cmake_policy(SET CMP0056 NEW)
  17 endif()
  18 if(POLICY CMP0065)
  19   cmake_policy(SET CMP0065 NEW)
  20 endif()
  21 if(POLICY CMP0051)
  22   cmake_policy(SET CMP0051 NEW)
  23 endif()
  24 if(POLICY CMP0075)
  25   cmake_policy(SET CMP0075 NEW)
  26 endif()
  27 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules/")
  28
  29 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  30   set(LINUX ON)
  31   FIND_PACKAGE(Threads)
  32 elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  33   set(FREEBSD ON)
  34   FIND_PACKAGE(Threads)
  35 endif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  36
  37 if(CMAKE_CXX_COMPILER_ID STREQUAL GNU)
  38   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7)
  39     message(FATAL_ERROR "GCC 7+ required due to C++17 requirements")
  40   endif()
  41 endif()
  42
  43 option(WITH_CCACHE "Build with ccache.")
  44 if(WITH_CCACHE)
  45   find_program(CCACHE_FOUND ccache)
  46   if(CCACHE_FOUND)
  47     message(STATUS "Building with ccache: ${CCACHE_FOUND}, CCACHE_DIR=$ENV{CCACHE_DIR}")
  48     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  49     # ccache does not accelerate link (ld), but let it handle it. by passing it
  50     # along with cc to python's distutils, we are able to workaround
  51     # https://bugs.python.org/issue8027.
  52     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  53   else(CCACHE_FOUND)
  54     message(FATAL_ERROR "Can't find ccache. Is it installed?")
  55   endif(CCACHE_FOUND)
  56 endif(WITH_CCACHE)
  57
  58 option(WITH_MANPAGE "Build man pages." ON)
  59 if(WITH_MANPAGE)
  60   find_program(SPHINX_BUILD
  61     NAMES sphinx-build sphinx-build-3)
  62   if(NOT SPHINX_BUILD)
  63     message(FATAL_ERROR "Can't find sphinx-build.")
  64   endif(NOT SPHINX_BUILD)
  65 endif(WITH_MANPAGE)
  66
  67 include_directories(
  68   ${PROJECT_BINARY_DIR}/src/include
  69   ${PROJECT_SOURCE_DIR}/src)
  70
  71 if(OFED_PREFIX)
  72   include_directories(SYSTEM ${OFED_PREFIX}/include)
  73   link_directories(${OFED_PREFIX}/lib)
  74 endif()
  75
  76 if(FREEBSD)
  77   include_directories(SYSTEM /usr/local/include)
  78   link_directories(/usr/local/lib)
  79   list(APPEND CMAKE_REQUIRED_INCLUDES /usr/local/include)
  80 endif(FREEBSD)
  81
  82 #Check Includes
  83 include(CheckIncludeFiles)
  84 include(CheckIncludeFileCXX)
  85 include(CheckFunctionExists)
  86
  87 #put all the libs and binaries in one place
  88 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  89 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  90 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  91
  92
  93 CHECK_FUNCTION_EXISTS(fallocate CEPH_HAVE_FALLOCATE)
  94 CHECK_FUNCTION_EXISTS(posix_fadvise HAVE_POSIX_FADVISE)
  95 CHECK_FUNCTION_EXISTS(posix_fallocate HAVE_POSIX_FALLOCATE)
  96 CHECK_FUNCTION_EXISTS(syncfs HAVE_SYS_SYNCFS)
  97 CHECK_FUNCTION_EXISTS(sync_file_range HAVE_SYNC_FILE_RANGE)
  98 CHECK_FUNCTION_EXISTS(pwritev HAVE_PWRITEV)
  99 CHECK_FUNCTION_EXISTS(splice CEPH_HAVE_SPLICE)
 100 CHECK_FUNCTION_EXISTS(getgrouplist HAVE_GETGROUPLIST)
 101 if(NOT APPLE)
 102   CHECK_FUNCTION_EXISTS(fdatasync HAVE_FDATASYNC)
 103 endif()
 104 CHECK_FUNCTION_EXISTS(strerror_r HAVE_Strerror_R)
 105 CHECK_FUNCTION_EXISTS(name_to_handle_at HAVE_NAME_TO_HANDLE_AT)
 106 CHECK_FUNCTION_EXISTS(pipe2 HAVE_PIPE2)
 107 CHECK_FUNCTION_EXISTS(accept4 HAVE_ACCEPT4)
 108
 109 include(CMakePushCheckState)
 110 cmake_push_check_state(RESET)
 111 set(CMAKE_REQUIRED_LIBRARIES pthread)
 112 CHECK_FUNCTION_EXISTS(pthread_spin_init HAVE_PTHREAD_SPINLOCK)
 113 CHECK_FUNCTION_EXISTS(pthread_set_name_np HAVE_PTHREAD_SET_NAME_NP)
 114 CHECK_FUNCTION_EXISTS(pthread_get_name_np HAVE_PTHREAD_GET_NAME_NP)
 115 CHECK_FUNCTION_EXISTS(pthread_setname_np HAVE_PTHREAD_SETNAME_NP)
 116 CHECK_FUNCTION_EXISTS(pthread_getname_np HAVE_PTHREAD_GETNAME_NP)
 117 CHECK_FUNCTION_EXISTS(pthread_rwlockattr_setkind_np HAVE_PTHREAD_RWLOCKATTR_SETKIND_NP)
 118 cmake_pop_check_state()
 119
 120 CHECK_FUNCTION_EXISTS(eventfd HAVE_EVENTFD)
 121 CHECK_FUNCTION_EXISTS(getprogname HAVE_GETPROGNAME)
 122
 123 CHECK_INCLUDE_FILES("linux/types.h" HAVE_LINUX_TYPES_H)
 124 CHECK_INCLUDE_FILES("linux/version.h" HAVE_LINUX_VERSION_H)
 125 CHECK_INCLUDE_FILES("arpa/nameser_compat.h" HAVE_ARPA_NAMESER_COMPAT_H)
 126 CHECK_INCLUDE_FILES("sys/mount.h" HAVE_SYS_MOUNT_H)
 127 CHECK_INCLUDE_FILES("sys/param.h" HAVE_SYS_PARAM_H)
 128 CHECK_INCLUDE_FILES("sys/types.h" HAVE_SYS_TYPES_H)
 129 CHECK_INCLUDE_FILES("sys/vfs.h" HAVE_SYS_VFS_H)
 130 CHECK_INCLUDE_FILES("sys/prctl.h" HAVE_SYS_PRCTL_H)
 131 CHECK_INCLUDE_FILES("execinfo.h" HAVE_EXECINFO_H)
 132 if(LINUX)
 133   CHECK_INCLUDE_FILES("sched.h" HAVE_SCHED)
 134 endif(LINUX)
 135 CHECK_INCLUDE_FILES("valgrind/helgrind.h" HAVE_VALGRIND_HELGRIND_H)
 136
 137 include(CheckTypeSize)
 138 set(CMAKE_EXTRA_INCLUDE_FILES "linux/types.h")
 139 CHECK_TYPE_SIZE(__be16 __BE16)
 140 CHECK_TYPE_SIZE(__be32 __BE32)
 141 CHECK_TYPE_SIZE(__be64 __BE64)
 142 CHECK_TYPE_SIZE(__le16 __LE16)
 143 CHECK_TYPE_SIZE(__le32 __LE32)
 144 CHECK_TYPE_SIZE(__le64 __LE64)
 145 CHECK_TYPE_SIZE(__u8 __U8)
 146 CHECK_TYPE_SIZE(__u16 __U16)
 147 CHECK_TYPE_SIZE(__u32 __U32)
 148 CHECK_TYPE_SIZE(__u64 __U64)
 149 CHECK_TYPE_SIZE(__s8 __S8)
 150 CHECK_TYPE_SIZE(__s16 __S16)
 151 CHECK_TYPE_SIZE(__s32 __S32)
 152 CHECK_TYPE_SIZE(__s64 __S64)
 153 unset(CMAKE_EXTRA_INCLUDE_FILES)
 154
 155 include(CheckSymbolExists)
 156 CHECK_SYMBOL_EXISTS(res_nquery "resolv.h" HAVE_RES_NQUERY)
 157 CHECK_SYMBOL_EXISTS(F_SETPIPE_SZ "linux/fcntl.h" CEPH_HAVE_SETPIPE_SZ)
 158 CHECK_SYMBOL_EXISTS(__func__ "" HAVE_FUNC)
 159 CHECK_SYMBOL_EXISTS(__PRETTY_FUNCTION__ "" HAVE_PRETTY_FUNC)
 160 CHECK_SYMBOL_EXISTS(getentropy "unistd.h" HAVE_GETENTROPY)
 161
 162 include(CheckCXXSourceCompiles)
 163 CHECK_CXX_SOURCE_COMPILES("
 164   #include <string.h>
 165   int main() { char x = *strerror_r(0, &x, sizeof(x)); return 0; }
 166   " STRERROR_R_CHAR_P)
 167
 168 include(CheckStructHasMember)
 169 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 170   HAVE_STAT_ST_MTIM_TV_NSEC LANGUAGE C)
 171 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 172   HAVE_STAT_ST_MTIMESPEC_TV_NSEC LANGUAGE C)
 173
 174 set(CEPH_MAN_DIR "share/man" CACHE STRING "Install location for man pages (relative to prefix).")
 175
 176 option(ENABLE_SHARED "build shared libraries" ON)
 177 if(ENABLE_SHARED)
 178   set(CEPH_SHARED SHARED)
 179 else(ENABLE_SHARED)
 180   set(CEPH_SHARED STATIC)
 181 endif(ENABLE_SHARED)
 182 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_SHARED})
 183
 184 option(WITH_STATIC_LIBSTDCXX "Link against libstdc++ statically" OFF)
 185 if(WITH_STATIC_LIBSTDCXX)
 186   if(CMAKE_COMPILER_IS_GNUCXX)
 187     set(static_linker_flags "-static-libstdc++ -static-libgcc")
 188     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${static_linker_flags}")
 189     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${static_linker_flags}")
 190     unset(static_linker_flags)
 191     set(GPERFTOOLS_USE_STATIC_LIBS TRUE)
 192   else()
 193     message(FATAL_ERROR "Please use GCC to enable WITH_STATIC_LIBSTDCXX")
 194   endif()
 195 endif()
 196 include(CheckCxxAtomic)
 197 if(NOT HAVE_CXX11_ATOMIC)
 198   set(CMAKE_CXX_STANDARD_LIBRARIES
 199     "${CMAKE_CXX_STANDARD_LIBRARIES} ${LIBATOMIC_LINK_FLAGS}")
 200 endif()
 201
 202 option(WITH_RDMA "Enable RDMA in async messenger" ON)
 203 if(WITH_RDMA)
 204   find_package(verbs REQUIRED)
 205   set(HAVE_VERBS ${VERBS_FOUND})
 206   find_package(rdmacm REQUIRED)
 207   set(HAVE_RDMACM ${RDMACM_FOUND})
 208   set(HAVE_RDMA TRUE)
 209 endif()
 210
 211 find_package(Backtrace)
 212
 213 # remote block storage
 214 option(WITH_RBD "Remote block storage is here" ON)
 215
 216 if(LINUX)
 217   find_package(udev REQUIRED)
 218   set(HAVE_UDEV ${UDEV_FOUND})
 219   find_package(blkid REQUIRED)
 220   set(HAVE_BLKID ${BLKID_FOUND})
 221   if(WITH_RBD)
 222     find_package(genl REQUIRED)
 223     set(HAVE_GENL $GENL_FOUND)
 224   endif()
 225   find_package(keyutils REQUIRED)
 226   set(HAVE_KEYUTILS ${KEYUTILS_FOUND})
 227 elseif(FREEBSD)
 228   set(HAVE_UDEV OFF)
 229   set(HAVE_LIBAIO OFF)
 230   set(HAVE_BLKID OFF)
 231   set(HAVE_GENL OFF)
 232   set(HAVE_KEYUTILS OFF)
 233 else()
 234   set(HAVE_UDEV OFF)
 235   message(STATUS "Not using udev")
 236   set(HAVE_BLKID OFF)
 237   message(STATUS "Not using BLKID")
 238   set(HAVE_GENL OFF)
 239   message(STATUS "Not using GENL")
 240 endif(LINUX)
 241
 242 option(WITH_OPENLDAP "OPENLDAP is here" ON)
 243 if(WITH_OPENLDAP)
 244   find_package(OpenLdap REQUIRED)
 245   set(HAVE_OPENLDAP ${OPENLDAP_FOUND})
 246 endif()
 247
 248 option(WITH_GSSAPI "GSSAPI/KRB5 is here" OFF)
 249 if(WITH_GSSAPI)
 250   find_package(GSSApi REQUIRED)
 251   set(HAVE_GSSAPI ${GSSApi_FOUND})
 252 endif()
 253
 254 option(WITH_FUSE "Fuse is here" ON)
 255 if(WITH_FUSE)
 256   find_package(fuse)
 257   set(HAVE_LIBFUSE ${FUSE_FOUND})
 258 endif()
 259
 260 option(WITH_XFS "XFS is here" ON)
 261 if(WITH_XFS)
 262   find_package(xfs)
 263   set(HAVE_LIBXFS ${XFS_FOUND})
 264 endif()
 265
 266 option(WITH_ZFS "enable LibZFS if found" OFF)
 267 if(WITH_ZFS)
 268   find_package(zfs)
 269   set(HAVE_LIBZFS ${ZFS_FOUND})
 270 endif()
 271
 272 option(WITH_BLUESTORE "Bluestore OSD backend" ON)
 273 if(WITH_BLUESTORE)
 274   if(LINUX)
 275     find_package(aio)
 276     set(HAVE_LIBAIO ${AIO_FOUND})
 277   elseif(FREEBSD)
 278     # POSIX AIO is integrated into FreeBSD kernel, and exposed by libc.
 279     set(HAVE_POSIXAIO ON)
 280   endif()
 281 endif()
 282
 283 option(WITH_SPDK "Enable SPDK" OFF)
 284 if(WITH_SPDK)
 285   if(NOT WITH_BLUESTORE)
 286     message(SEND_ERROR "Please enable WITH_BLUESTORE for using SPDK")
 287   endif()
 288   include(BuildSPDK)
 289   build_spdk()
 290   set(HAVE_SPDK TRUE)
 291 endif(WITH_SPDK)
 292
 293 option(WITH_PMEM "Enable PMEM" OFF)
 294 if(WITH_PMEM)
 295   set(HAVE_PMEM ON)
 296   if(NOT WITH_BLUESTORE)
 297     message(SEND_ERROR "Please enable WITH_BLUESTORE for using PMEM")
 298   endif()
 299 endif()
 300
 301 if(WITH_BLUESTORE)
 302   if(NOT AIO_FOUND AND NOT HAVE_POSIXAIO AND NOT WITH_SPDK AND NOT WITH_PMEM)
 303     message(SEND_ERROR "WITH_BLUESTORE is ON, "
 304       "but none of the bluestore backends is enabled. "
 305       "Please install libaio, or enable WITH_SPDK or WITH_PMEM (experimental)")
 306   endif()
 307 endif()
 308
 309 option(WITH_BLUEFS "libbluefs library" OFF)
 310
 311 option(WITH_QATZIP "Enable QATZIP" OFF)
 312 if(WITH_QATZIP)
 313   find_package(qatzip REQUIRED)
 314   set(HAVE_QATZIP ${QATZIP_FOUND})
 315 endif(WITH_QATZIP)
 316
 317 # needs mds and? XXX
 318 option(WITH_LIBCEPHFS "libcephfs client library" ON)
 319
 320 # key-value store
 321 option(WITH_KVS "Key value store is here" ON)
 322
 323 # KERNEL remote block storage
 324 option(WITH_KRBD "Kernel Remote block storage is here" ON)
 325
 326 if(WITH_KRBD AND WITHOUT_RBD)
 327   message(FATAL_ERROR "Cannot have WITH_KRBD with WITH_RBD.")
 328 endif()
 329 if(LINUX)
 330   if(WITH_LIBCEPHFS OR WITH_KRBD)
 331     # keyutils is only used when talking to the Linux Kernel key store
 332     find_package(keyutils REQUIRED)
 333     set(HAVE_KEYUTILS ${KEYUTILS_FOUND})
 334   endif()
 335 endif()
 336
 337 option(WITH_LEVELDB "LevelDB is here" ON)
 338 if(WITH_LEVELDB)
 339   if(LEVELDB_PREFIX)
 340     include_directories(SYSTEM ${LEVELDB_PREFIX}/include)
 341     link_directories(${LEVELDB_PREFIX}/lib)
 342   endif()
 343   find_package(leveldb REQUIRED)
 344   find_file(HAVE_LEVELDB_FILTER_POLICY leveldb/filter_policy.h PATHS ${LEVELDB_INCLUDE_DIR})
 345 endif(WITH_LEVELDB)
 346
 347 find_package(snappy REQUIRED)
 348
 349 option(WITH_BROTLI "Brotli compression support" OFF)
 350 if(WITH_BROTLI)
 351   set(HAVE_BROTLI TRUE)
 352 endif()
 353
 354 option(WITH_LZ4 "LZ4 compression support" ON)
 355 if(WITH_LZ4)
 356   find_package(LZ4 1.7 REQUIRED)
 357   set(HAVE_LZ4 ${LZ4_FOUND})
 358 endif(WITH_LZ4)
 359
 360 option(WITH_CEPH_DEBUG_MUTEX "Use debug ceph::mutex with lockdep" OFF)
 361
 362 #if allocator is set on command line make sure it matches below strings
 363 set(ALLOCATOR "" CACHE STRING
 364   "specify memory allocator to use. currently tcmalloc, tcmalloc_minimal, \
 365 jemalloc, and libc is supported. if not specified, will try to find tcmalloc, \
 366 and then jemalloc. If neither of then is found. use the one in libc.")
 367 if(ALLOCATOR)
 368   if(${ALLOCATOR} MATCHES "tcmalloc(_minimal)?")
 369     find_package(gperftools REQUIRED)
 370     set(HAVE_LIBTCMALLOC ON)
 371   elseif(${ALLOCATOR} STREQUAL "jemalloc")
 372     find_package(JeMalloc REQUIRED)
 373     set(HAVE_JEMALLOC 1)
 374   elseif(NOT ALLOCATOR STREQUAL "libc")
 375     message(FATAL_ERROR "Unsupported allocator selected: ${ALLOCATOR}")
 376   endif()
 377 else(ALLOCATOR)
 378   find_package(gperftools)
 379   set(HAVE_LIBTCMALLOC ${gperftools_FOUND})
 380   if(NOT gperftools_FOUND)
 381     find_package(JeMalloc)
 382   endif()
 383   if(gperftools_FOUND)
 384     set(ALLOCATOR tcmalloc)
 385   elseif(JeMalloc_FOUND)
 386     set(ALLOCATOR jemalloc)
 387   else()
 388     if(NOT FREEBSD)
 389       # FreeBSD already has jemalloc as its default allocator
 390       message(WARNING "tcmalloc and jemalloc not found, falling back to libc")
 391     endif()
 392     set(ALLOCATOR "libc")
 393   endif(gperftools_FOUND)
 394 endif(ALLOCATOR)
 395
 396 if(HAVE_LIBTCMALLOC AND WITH_STATIC_LIBSTDCXX)
 397   set(EXE_LINKER_USE_PIE FALSE)
 398 else()
 399   set(EXE_LINKER_USE_PIE ${ENABLE_SHARED})
 400 endif()
 401
 402 find_package(CURL REQUIRED)
 403 set(CMAKE_REQUIRED_INCLUDES ${CURL_INCLUDE_DIRS})
 404 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBRARIES})
 405 CHECK_SYMBOL_EXISTS(curl_multi_wait curl/curl.h HAVE_CURL_MULTI_WAIT)
 406
 407 find_package(NSS REQUIRED)
 408 find_package(NSPR REQUIRED)
 409 find_package(OpenSSL REQUIRED)
 410 # TODO: use NSS only for validation of the OpenSSL-based implementations
 411 set(USE_NSS 1)
 412 set(USE_OPENSSL 1)
 413 set(CRYPTO_LIBS ${NSS_LIBRARIES} ${NSPR_LIBRARIES} OpenSSL::Crypto)
 414
 415 option(WITH_XIO "Enable XIO messaging" OFF)
 416 if(WITH_XIO)
 417   find_package(xio REQUIRED)
 418   set(HAVE_XIO ${XIO_FOUND})
 419 endif()
 420
 421 option(WITH_DPDK "Enable DPDK messaging" OFF)
 422 if(WITH_DPDK)
 423   find_package(dpdk)
 424   if(NOT DPDK_FOUND AND NOT TARGET dpdk-ext)
 425     include(BuildDPDK)
 426     build_dpdk(${CMAKE_BINARY_DIR}/src/dpdk)
 427   endif()
 428   set(HAVE_DPDK TRUE)
 429 endif()
 430
 431 option(WITH_BLKIN "Use blkin to emit LTTng tracepoints for Zipkin" OFF)
 432 if(WITH_BLKIN)
 433   set(BLKIN_LIBRARIES blkin ${LTTNGUST_LIBRARIES} lttng-ust-fork)
 434   include_directories(SYSTEM src/blkin/blkin-lib)
 435 endif(WITH_BLKIN)
 436
 437 option(WITH_BOOST_CONTEXT "Enable boost::asio stackful coroutines" ON)
 438 if(WITH_BOOST_CONTEXT)
 439   set(HAVE_BOOST_CONTEXT ON)
 440 endif()
 441
 442 #option for RGW
 443 option(WITH_RADOSGW "Rados Gateway is enabled" ON)
 444 option(WITH_RADOSGW_FCGI_FRONTEND "Rados Gateway's FCGI frontend is enabled" OFF)
 445 option(WITH_RADOSGW_BEAST_FRONTEND "Rados Gateway's Beast frontend is enabled" ON)
 446 option(WITH_RADOSGW_BEAST_OPENSSL "Rados Gateway's Beast frontend uses OpenSSL" ON)
 447 option(WITH_RADOSGW_AMQP_ENDPOINT "Rados Gateway's pubsub support for AMQP push endpoint" ON)
 448
 449 if(WITH_RADOSGW)
 450   find_package(EXPAT REQUIRED)
 451   if(WITH_RADOSGW_FCGI_FRONTEND)
 452     find_package(fcgi REQUIRED)
 453   endif()
 454   if(WITH_RADOSGW_BEAST_FRONTEND AND NOT WITH_BOOST_CONTEXT)
 455     message(WARNING "disabling WITH_RADOSGW_BEAST_FRONTEND, which depends on WITH_BOOST_CONTEXT")
 456     set(WITH_RADOSGW_BEAST_FRONTEND OFF)
 457   endif()
 458   find_package(OATH REQUIRED)
 459
 460 # https://curl.haxx.se/docs/install.html mentions the
 461 # configure flags for various ssl backends
 462   execute_process(
 463     COMMAND
 464   "sh" "-c"
 465   "curl-config --configure | grep with-ssl"
 466   RESULT_VARIABLE NO_CURL_SSL_LINK
 467   ERROR_VARIABLE CURL_CONFIG_ERRORS
 468   )
 469   if (CURL_CONFIG_ERRORS)
 470     message(WARNING "unable to run curl-config; rgw cannot make ssl requests to external systems reliably")
 471   endif()
 472
 473   if (WITH_RADOSGW_BEAST_FRONTEND AND WITH_RADOSGW_BEAST_OPENSSL)
 474     find_package(OpenSSL REQUIRED)
 475   else()
 476     find_package(OpenSSL)
 477   endif()
 478
 479   if (OPENSSL_FOUND)
 480     if (NOT NO_CURL_SSL_LINK)
 481       message(STATUS "libcurl is linked with openssl: explicitly setting locks")
 482       set(WITH_CURL_OPENSSL ON)
 483     endif() # CURL_SSL_LINK
 484     execute_process(
 485       COMMAND
 486         "sh" "-c"
 487         "objdump -p ${OPENSSL_SSL_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 488       OUTPUT_VARIABLE LIBSSL_SONAME
 489       ERROR_VARIABLE OBJDUMP_ERRORS
 490       RESULT_VARIABLE OBJDUMP_RESULTS
 491       OUTPUT_STRIP_TRAILING_WHITESPACE)
 492     if (OBJDUMP_RESULTS)
 493       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 494     endif()
 495     if (NOT OBJDUMP_ERRORS STREQUAL "")
 496       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 497     endif()
 498     execute_process(
 499       COMMAND
 500         "sh" "-c"
 501         "objdump -p ${OPENSSL_CRYPTO_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 502       OUTPUT_VARIABLE LIBCRYPTO_SONAME
 503       ERROR_VARIABLE OBJDUMP_ERRORS
 504       RESULT_VARIABLE OBJDUMP_RESULTS
 505       OUTPUT_STRIP_TRAILING_WHITESPACE)
 506     if (OBJDUMP_RESULTS)
 507       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 508     endif()
 509     if (NOT OBJDUMP_ERRORS STREQUAL "")
 510       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 511     endif()
 512     message(STATUS "ssl soname: ${LIBSSL_SONAME}")
 513     message(STATUS "crypto soname: ${LIBCRYPTO_SONAME}")
 514   else()
 515     message(WARNING "ssl not found: rgw civetweb may fail to dlopen libssl libcrypto")
 516   endif()  # OPENSSL_FOUND
 517 endif (WITH_RADOSGW)
 518
 519 #option for CephFS
 520 option(WITH_CEPHFS "CephFS is enabled" ON)
 521
 522 #option for Mgr
 523 option(WITH_MGR "ceph-mgr is enabled" ON)
 524 if(WITH_MGR)
 525   # Please specify 3 or 3.[0-7] if you want to build with python3 support.
 526   # FindPyhonInterp and FindPythonLibs think they belong to different families.
 527   set(MGR_PYTHON_VERSION "2.7" CACHE
 528     STRING "minimal required version of python runtime for running mgr plugins. ")
 529   find_package(PythonInterp ${MGR_PYTHON_VERSION} REQUIRED)
 530   find_package(PythonLibs ${MGR_PYTHON_VERSION} REQUIRED)
 531   set(MGR_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 532   set(MGR_PYTHON_LIBRARIES ${PYTHON_LIBRARIES})
 533   set(MGR_PYTHON_VERSION_MAJOR ${PYTHON_VERSION_MAJOR})
 534   set(MGR_PYTHON_VERSION_MINOR ${PYTHON_VERSION_MINOR})
 535   # Boost dependency check deferred to Boost section
 536 endif(WITH_MGR)
 537
 538 option(WITH_THREAD_SAFE_RES_QUERY "res_query is thread safe" OFF)
 539 if(WITH_THREAD_SAFE_RES_QUERY)
 540   set(HAVE_THREAD_SAFE_RES_QUERY 1 CACHE INTERNAL "Thread safe res_query supported.")
 541 endif()
 542
 543 option(WITH_REENTRANT_STRSIGNAL "strsignal is reentrant" OFF)
 544 if(WITH_REENTRANT_STRSIGNAL)
 545   set(HAVE_REENTRANT_STRSIGNAL 1 CACHE INTERNAL "Reentrant strsignal is supported.")
 546 endif()
 547
 548 set(HAVE_LIBROCKSDB 1)
 549
 550 # -lz link into kv
 551 find_package(ZLIB REQUIRED)
 552
 553 #option for EventTrace
 554 option(WITH_EVENTTRACE "Event tracing support" OFF)
 555
 556 #option for LTTng
 557 option(WITH_LTTNG "LTTng tracing is enabled" ON)
 558 if(${WITH_LTTNG})
 559   find_package(LTTngUST REQUIRED)
 560   find_program(LTTNG_GEN_TP
 561     lttng-gen-tp)
 562   if(NOT LTTNG_GEN_TP)
 563     message(FATAL_ERROR "Can't find lttng-gen-tp.")
 564   endif()
 565 endif(${WITH_LTTNG})
 566
 567 option(WITH_OSD_INSTRUMENT_FUNCTIONS OFF)
 568
 569 #option for Babeltrace
 570 option(WITH_BABELTRACE "Babeltrace libraries are enabled" ON)
 571 if(WITH_BABELTRACE)
 572   set(HAVE_BABELTRACE ON)
 573   find_package(babeltrace REQUIRED)
 574   set(HAVE_BABELTRACE_BABELTRACE_H ${BABELTRACE_FOUND})
 575   set(HAVE_BABELTRACE_CTF_EVENTS_H ${BABELTRACE_FOUND})
 576   set(HAVE_BABELTRACE_CTF_ITERATOR_H ${BABELTRACE_FOUND})
 577 endif(WITH_BABELTRACE)
 578
 579 option(DEBUG_GATHER "C_Gather debugging is enabled" ON)
 580 option(ENABLE_COVERAGE "Coverage is enabled" OFF)
 581 option(PG_DEBUG_REFS "PG Ref debugging is enabled" OFF)
 582
 583 option(WITH_TESTS "enable the build of ceph-test package scripts/binaries" ON)
 584 set(UNIT_TESTS_BUILT ${WITH_TESTS})
 585 set(CEPH_TEST_TIMEOUT 3600 CACHE STRING
 586   "Maximum time before a CTest gets killed" )
 587
 588 # fio
 589 option(WITH_FIO "build with fio plugin enabled" OFF)
 590 option(WITH_SYSTEM_FIO "require and build with system fio" OFF)
 591 if(WITH_SYSTEM_FIO)
 592   find_package(fio REQUIRED)
 593 elseif(WITH_FIO)
 594   set(FIO_INCLUDE_DIR ${CMAKE_BINARY_DIR}/src/fio)
 595   include(BuildFIO)
 596   build_fio()
 597 endif()
 598
 599 if(LINUX)
 600   add_definitions(-D__linux__)
 601 endif(LINUX)
 602
 603 # ASAN and friends
 604 option(WITH_ASAN "build with ASAN" OFF)
 605 if(WITH_ASAN)
 606   list(APPEND sanitizers "address")
 607 endif()
 608
 609 option(WITH_ASAN_LEAK "explicitly enable ASAN leak detection" OFF)
 610 if(WITH_ASAN_LEAK)
 611   list(APPEND sanitizers "leak")
 612 endif()
 613
 614 option(WITH_TSAN "build with TSAN" OFF)
 615 if(WITH_TSAN)
 616   list(APPEND sanitizers "thread")
 617 endif()
 618
 619 option(WITH_UBSAN "build with UBSAN" OFF)
 620 if(WITH_UBSAN)
 621   list(APPEND sanitizers "undefined-behavior")
 622 endif()
 623
 624 if(sanitizers)
 625   find_package(Sanitizers REQUIRED ${sanitizers})
 626   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 627   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 628   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 629   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 630 endif()
 631
 632 # Rocksdb
 633 option(WITH_SYSTEM_ROCKSDB "require and build with system rocksdb" OFF)
 634 if (WITH_SYSTEM_ROCKSDB)
 635   find_package(RocksDB 5.8 REQUIRED)
 636 endif()
 637
 638 option(WITH_SEASTAR "Build seastar components")
 639 set(HAVE_SEASTAR ${WITH_SEASTAR})
 640
 641 # Boost
 642 option(WITH_SYSTEM_BOOST "require and build with system Boost" OFF)
 643
 644 # Boost::thread depends on Boost::atomic, so list it explicitly.
 645 set(BOOST_COMPONENTS
 646   atomic chrono thread system regex random program_options date_time
 647   iostreams)
 648 set(BOOST_HEADER_COMPONENTS container)
 649
 650 if(WITH_MGR)
 651   list(APPEND BOOST_COMPONENTS
 652     python${MGR_PYTHON_VERSION_MAJOR}${MGR_PYTHON_VERSION_MINOR})
 653 endif()
 654 if(WITH_BOOST_CONTEXT)
 655   list(APPEND BOOST_COMPONENTS context coroutine)
 656 endif()
 657 if(WITH_SEASTAR)
 658   list(APPEND BOOST_COMPONENTS filesystem timer)
 659 endif()
 660
 661 set(Boost_USE_MULTITHREADED ON)
 662 # require minimally the bundled version
 663 if(WITH_SYSTEM_BOOST)
 664   if(ENABLE_SHARED)
 665     set(Boost_USE_STATIC_LIBS OFF)
 666   else()
 667     set(Boost_USE_STATIC_LIBS ON)
 668   endif()
 669   if(BOOST_ROOT AND CMAKE_LIBRARY_ARCHITECTURE)
 670     set(BOOST_LIBRARYDIR "${BOOST_ROOT}/lib/${CMAKE_LIBRARY_ARCHITECTURE}")
 671   endif()
 672   find_package(Boost 1.67 COMPONENTS ${BOOST_COMPONENTS} REQUIRED)
 673 else()
 674   set(BOOST_J 1 CACHE STRING
 675     "max jobs for Boost build") # override w/-DBOOST_J=<n>
 676   set(Boost_USE_STATIC_LIBS ON)
 677   include(BuildBoost)
 678   build_boost(1.67
 679     COMPONENTS ${BOOST_COMPONENTS} ${BOOST_HEADER_COMPONENTS})
 680 endif()
 681 include_directories(BEFORE SYSTEM ${Boost_INCLUDE_DIRS})
 682 set(Boost_USE_MULTITHREADED ON)
 683
 684 # dashboard angular2 frontend
 685 option(WITH_MGR_DASHBOARD_FRONTEND "Build the mgr/dashboard frontend using `npm`" ON)
 686 option(WITH_SYSTEM_NPM "Assume that dashboard build tools already installed through packages" OFF)
 687 if(WITH_SYSTEM_NPM)
 688   find_program(NPM npm)
 689   if(NOT NPM)
 690     message(FATAL_ERROR "Can't find npm.")
 691   endif()
 692 endif()
 693 set(DASHBOARD_FRONTEND_LANGS "" CACHE STRING
 694   "List of comma separated ceph-dashboard frontend languages to build. \
 695   Use value `ALL` to build all languages")
 696
 697 include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)
 698
 699 find_package(Threads REQUIRED)
 700
 701
 702 option(WITH_SELINUX "build SELinux policy" OFF)
 703 if(WITH_SELINUX)
 704   find_file(SELINUX_MAKEFILE selinux/devel/Makefile
 705     PATH /usr/share)
 706   if(NOT SELINUX_MAKEFILE)
 707     message(FATAL_ERROR "Can't find selinux's Makefile")
 708   endif()
 709   add_subdirectory(selinux)
 710 endif(WITH_SELINUX)
 711
 712 # enables testing and creates Make check command
 713 add_custom_target(tests
 714   COMMENT "Building tests")
 715 enable_testing()
 716 set(CMAKE_CTEST_COMMAND ctest)
 717 add_custom_target(check
 718   COMMAND ${CMAKE_CTEST_COMMAND}
 719   DEPENDS tests)
 720
 721 add_subdirectory(src)
 722
 723 add_subdirectory(doc)
 724 if(WITH_MANPAGE)
 725   add_subdirectory(man)
 726 endif(WITH_MANPAGE)
 727
 728 option(WITH_SYSTEMD "install systemd target and service files" ON)
 729 if(WITH_SYSTEMD)
 730   add_subdirectory(systemd)
 731 endif()
 732
 733 if(LINUX)
 734   add_subdirectory(etc/sysctl)
 735 endif()
 736
 737 option(WITH_GRAFANA "install grafana dashboards" OFF)
 738 if(WITH_GRAFANA)
 739   add_subdirectory(monitoring/grafana/dashboards)
 740 endif()
 741
 742 include(CTags)
 743 option(CTAG_EXCLUDES "Exclude files/directories when running ctag.")
 744 add_tags(ctags
 745   SRC_DIR src
 746   TAG_FILE tags
 747   EXCLUDE_OPTS ${CTAG_EXCLUDES}
 748   EXCLUDES "*.js" "*.css")
 749 add_custom_target(tags DEPENDS ctags)