ceph/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11)
   2
   3 project(ceph)
   4 set(VERSION 12.1.1)
   5
   6 if(POLICY CMP0046)
   7   # Tweak policies (this one disables "missing" dependency warning)
   8   cmake_policy(SET CMP0046 OLD)
   9 endif()
  10 # we use LINK_PRIVATE keyword instead of PRIVATE, but do not specify the LINK_PUBLIC
  11 # for target_link_libraries() command when PUBLIC should be used instead, it's just
  12 # for backward compatibility with cmake 2.8.11.
  13 if (POLICY CMP0022)
  14 cmake_policy(SET CMP0022 OLD)
  15 endif (POLICY CMP0022)
  16 if (POLICY CMP0023)
  17 cmake_policy(SET CMP0023 OLD)
  18 endif (POLICY CMP0023)
  19 if(POLICY CMP0056)
  20   cmake_policy(SET CMP0056 NEW)
  21 endif()
  22 if(POLICY CMP0065)
  23   cmake_policy(SET CMP0065 NEW)
  24 endif()
  25 if(POLICY CMP0051)
  26   # cmake 3.1 and higher include generator expressions in SOURCES property.
  27   # in BuildBoost.cmake, get_target_property(<var> <target> SOURCES) is used
  28   # to retrieve the source files of a target. in that case, we are only
  29   # interested in the *source* files. and i don't want to bother stripping off
  30   # the TARGET_OBJECTS elements from the returned SOURCES. so let's stick with
  31   # the old behavior now.
  32   cmake_policy(SET CMP0051 OLD)
  33 endif()
  34 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules/")
  35
  36 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  37   set(LINUX ON)
  38   FIND_PACKAGE(Threads)
  39 elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  40   set(FREEBSD ON)
  41   FIND_PACKAGE(Threads)
  42 elseif(APPLE)
  43   set(OperatingSystem "Mac OS X")
  44 else()
  45   message(STATUS "No systemtype selected for building")
  46 endif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  47
  48 option(WITH_CCACHE "Build with ccache.")
  49 if(WITH_CCACHE)
  50   find_program(CCACHE_FOUND ccache)
  51   if(CCACHE_FOUND)
  52     message(STATUS "Building with ccache: ${CCACHE_FOUND}, CCACHE_DIR=$ENV{CCACHE_DIR}")
  53     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  54     # ccache does not accelerate link (ld), but let it handle it. by passing it
  55     # along with cc to python's distutils, we are able to workaround
  56     # https://bugs.python.org/issue8027.
  57     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  58   else(CCACHE_FOUND)
  59     message(FATAL_ERROR "Can't find ccache. Is it installed?")
  60   endif(CCACHE_FOUND)
  61 endif(WITH_CCACHE)
  62
  63 option(WITH_MANPAGE "Build man pages." ON)
  64 if(WITH_MANPAGE)
  65   find_program(SPHINX_BUILD
  66     sphinx-build)
  67   if(NOT SPHINX_BUILD)
  68     message(FATAL_ERROR "Can't find sphinx-build.")
  69   endif(NOT SPHINX_BUILD)
  70 endif(WITH_MANPAGE)
  71
  72 include_directories(
  73   ${PROJECT_BINARY_DIR}/src/include
  74   ${PROJECT_SOURCE_DIR}/src)
  75
  76 if(OFED_PREFIX)
  77   include_directories(${OFED_PREFIX}/include)
  78   link_directories(${OFED_PREFIX}/lib)
  79 endif()
  80
  81 if(FREEBSD)
  82   include_directories(/usr/local/include)
  83   link_directories(/usr/local/lib)
  84   list(APPEND CMAKE_REQUIRED_INCLUDES /usr/local/include)
  85 endif(FREEBSD)
  86
  87 #Check Includes
  88 include(CheckIncludeFiles)
  89 include(CheckIncludeFileCXX)
  90 include(CheckFunctionExists)
  91
  92 #put all the libs and binaries in one place
  93 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  94 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  95 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  96
  97
  98 CHECK_FUNCTION_EXISTS(fallocate CEPH_HAVE_FALLOCATE)
  99 CHECK_FUNCTION_EXISTS(posix_fadvise HAVE_POSIX_FADVISE)
 100 CHECK_FUNCTION_EXISTS(posix_fallocate HAVE_POSIX_FALLOCATE)
 101 CHECK_FUNCTION_EXISTS(syncfs HAVE_SYS_SYNCFS)
 102 CHECK_FUNCTION_EXISTS(sync_file_range HAVE_SYNC_FILE_RANGE)
 103 CHECK_FUNCTION_EXISTS(pwritev HAVE_PWRITEV)
 104 CHECK_FUNCTION_EXISTS(splice CEPH_HAVE_SPLICE)
 105 CHECK_FUNCTION_EXISTS(getgrouplist HAVE_GETGROUPLIST)
 106 CHECK_FUNCTION_EXISTS(fdatasync HAVE_FDATASYNC)
 107 CHECK_FUNCTION_EXISTS(strerror_r HAVE_STRERROR_R)
 108 CHECK_FUNCTION_EXISTS(name_to_handle_at HAVE_NAME_TO_HANDLE_AT)
 109 CHECK_FUNCTION_EXISTS(pipe2 HAVE_PIPE2)
 110 set(CMAKE_REQUIRED_LIBRARIES pthread)
 111 CHECK_FUNCTION_EXISTS(pthread_spin_init HAVE_PTHREAD_SPINLOCK)
 112 CHECK_FUNCTION_EXISTS(pthread_set_name_np HAVE_PTHREAD_SET_NAME_NP)
 113 CHECK_FUNCTION_EXISTS(pthread_setname_np HAVE_PTHREAD_SETNAME_NP)
 114 CHECK_FUNCTION_EXISTS(pthread_getname_np HAVE_PTHREAD_GETNAME_NP)
 115 CHECK_FUNCTION_EXISTS(eventfd HAVE_EVENTFD)
 116 CHECK_FUNCTION_EXISTS(getprogname HAVE_GETPROGNAME)
 117
 118 CHECK_INCLUDE_FILES("linux/types.h" HAVE_LINUX_TYPES_H)
 119 CHECK_INCLUDE_FILES("linux/version.h" HAVE_LINUX_VERSION_H)
 120 CHECK_INCLUDE_FILES("arpa/nameser_compat.h" HAVE_ARPA_NAMESER_COMPAT_H)
 121 CHECK_INCLUDE_FILES("sys/mount.h" HAVE_SYS_MOUNT_H)
 122 CHECK_INCLUDE_FILES("sys/param.h" HAVE_SYS_PARAM_H)
 123 CHECK_INCLUDE_FILES("sys/types.h" HAVE_SYS_TYPES_H)
 124 CHECK_INCLUDE_FILES("sys/vfs.h" HAVE_SYS_VFS_H)
 125 CHECK_INCLUDE_FILES("sys/prctl.h" HAVE_SYS_PRCTL_H)
 126 CHECK_INCLUDE_FILES("execinfo.h" HAVE_EXECINFO_H)
 127 if(LINUX)
 128   CHECK_INCLUDE_FILES("sched.h" HAVE_SCHED)
 129 endif(LINUX)
 130 CHECK_INCLUDE_FILES("valgrind/helgrind.h" HAVE_VALGRIND_HELGRIND_H)
 131
 132 include(CheckTypeSize)
 133 set(CMAKE_EXTRA_INCLUDE_FILES "linux/types.h")
 134 CHECK_TYPE_SIZE(__be16 __BE16)
 135 CHECK_TYPE_SIZE(__be32 __BE32)
 136 CHECK_TYPE_SIZE(__be64 __BE64)
 137 CHECK_TYPE_SIZE(__le16 __LE16)
 138 CHECK_TYPE_SIZE(__le32 __LE32)
 139 CHECK_TYPE_SIZE(__le64 __LE64)
 140 CHECK_TYPE_SIZE(__u8 __U8)
 141 CHECK_TYPE_SIZE(__u16 __U16)
 142 CHECK_TYPE_SIZE(__u32 __U32)
 143 CHECK_TYPE_SIZE(__u64 __U64)
 144 CHECK_TYPE_SIZE(__s8 __S8)
 145 CHECK_TYPE_SIZE(__s16 __S16)
 146 CHECK_TYPE_SIZE(__s32 __S32)
 147 CHECK_TYPE_SIZE(__s64 __S64)
 148 unset(CMAKE_EXTRA_INCLUDE_FILES)
 149
 150 include(CheckSymbolExists)
 151 CHECK_SYMBOL_EXISTS(res_nquery "resolv.h" HAVE_RES_NQUERY)
 152 CHECK_SYMBOL_EXISTS(F_SETPIPE_SZ "linux/fcntl.h" CEPH_HAVE_SETPIPE_SZ)
 153 CHECK_SYMBOL_EXISTS(__func__ "" HAVE_FUNC)
 154 CHECK_SYMBOL_EXISTS(__PRETTY_FUNCTION__ "" HAVE_PRETTY_FUNC)
 155
 156 include(CheckCXXSourceCompiles)
 157 CHECK_CXX_SOURCE_COMPILES("
 158   #include <string.h>
 159   int main() { char x = *strerror_r(0, &x, sizeof(x)); return 0; }
 160   " STRERROR_R_CHAR_P)
 161
 162 include(CheckStructHasMember)
 163 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 164   HAVE_STAT_ST_MTIM_TV_NSEC LANGUAGE C)
 165 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 166   HAVE_STAT_ST_MTIMESPEC_TV_NSEC LANGUAGE C)
 167
 168 set(CEPH_MAN_DIR "share/man" CACHE STRING "Install location for man pages (relative to prefix).")
 169
 170 option(ENABLE_SHARED "build shared libraries" ON)
 171 if(ENABLE_SHARED)
 172   set(CEPH_SHARED SHARED)
 173 else(ENABLE_SHARED)
 174   set(CEPH_SHARED STATIC)
 175 endif(ENABLE_SHARED)
 176 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_SHARED})
 177
 178 option(WITH_RDMA "Enable RDMA in async messenger" ON)
 179 if(WITH_RDMA)
 180   find_package(rdma REQUIRED)
 181   set(HAVE_RDMA ${RDMA_FOUND})
 182 endif(WITH_RDMA)
 183
 184 find_package(Backtrace)
 185
 186 if(LINUX)
 187   find_package(udev REQUIRED)
 188   set(HAVE_UDEV ${UDEV_FOUND})
 189
 190   find_package(aio REQUIRED)
 191   set(HAVE_LIBAIO ${AIO_FOUND})
 192
 193   find_package(blkid REQUIRED)
 194   set(HAVE_BLKID ${BLKID_FOUND})
 195 else()
 196   set(HAVE_UDEV OFF)
 197   message(STATUS "Not using udev")
 198   set(HAVE_LIBAIO OFF)
 199   message(STATUS "Not using AIO")
 200   set(HAVE_BLKID OFF)
 201   message(STATUS "Not using BLKID")
 202 endif(LINUX)
 203
 204 option(WITH_OPENLDAP "OPENLDAP is here" ON)
 205 if(${WITH_OPENLDAP})
 206 find_package(OpenLdap REQUIRED)
 207 set(HAVE_OPENLDAP ${OPENLDAP_FOUND})
 208 endif(${WITH_OPENLDAP})
 209
 210 option(WITH_FUSE "Fuse is here" ON)
 211 if(${WITH_FUSE})
 212 find_package(fuse)
 213 set(HAVE_LIBFUSE ${FUSE_FOUND})
 214 endif(${WITH_FUSE})
 215
 216 option(WITH_XFS "XFS is here" ON)
 217 if(WITH_XFS)
 218   find_package(xfs)
 219   set(HAVE_LIBXFS ${XFS_FOUND})
 220 endif()
 221
 222 option(WITH_ZFS "enable LibZFS if found" OFF)
 223 if(WITH_ZFS)
 224   find_package(zfs)
 225   set(HAVE_LIBZFS ${ZFS_FOUND})
 226 endif()
 227
 228 option(WITH_SPDK "Enable SPDK" OFF)
 229 if(WITH_SPDK)
 230   find_package(dpdk REQUIRED)
 231   set(HAVE_SPDK TRUE)
 232 endif(WITH_SPDK)
 233
 234 option(WITH_PMEM "Enable PMEM" OFF)
 235 if(WITH_PMEM)
 236   find_package(pmem REQUIRED)
 237   set(HAVE_PMEM ${PMEM_FOUND})
 238 endif(WITH_PMEM)
 239
 240 # needs mds and? XXX
 241 option(WITH_LIBCEPHFS "libcephfs client library" ON)
 242
 243 # key-value store
 244 option(WITH_KVS "Key value store is here" ON)
 245
 246 # remote block storage
 247 option(WITH_RBD "Remote block storage is here" ON)
 248
 249 # KERNEL remote block storage
 250 option(WITH_KRBD "Kernel Remote block storage is here" ON)
 251
 252 if(WITH_KRBD AND WITHOUT_RBD)
 253   message(FATAL_ERROR "Cannot have WITH_KRBD with WITH_RBD.")
 254 endif()
 255
 256 # embedded ceph daemon static library
 257 # NOTE: Ceph is mostly LGPL (see COPYING), which means that
 258 # static linking brings with it restrictions. Please be sure
 259 # to look at the LGPL license carefully before linking this library to
 260 # your code. See http://www.gnu.org/licenses/gpl-faq.html#LGPLStaticVsDynamic.
 261 option(WITH_EMBEDDED "build the embedded ceph daemon library" ON)
 262
 263 option(WITH_LEVELDB "LevelDB is here" ON)
 264 if(WITH_LEVELDB)
 265   if(LEVELDB_PREFIX)
 266     include_directories(${LEVELDB_PREFIX}/include)
 267     link_directories(${LEVELDB_PREFIX}/lib)
 268   endif()
 269   find_package(leveldb REQUIRED)
 270   find_file(HAVE_LEVELDB_FILTER_POLICY leveldb/filter_policy.h PATHS ${LEVELDB_INCLUDE_DIR})
 271 endif(WITH_LEVELDB)
 272
 273 find_package(snappy REQUIRED)
 274
 275 option(WITH_LZ4 "LZ4 compression support" OFF)
 276 if(WITH_LZ4)
 277   find_package(LZ4 REQUIRED)
 278   set(HAVE_LZ4 ${LZ4_FOUND})
 279 endif(WITH_LZ4)
 280
 281 #if allocator is set on command line make sure it matches below strings
 282 if(ALLOCATOR)
 283   if(${ALLOCATOR} MATCHES "tcmalloc(_minimal)?")
 284     find_package(gperftools REQUIRED)
 285     set(HAVE_LIBTCMALLOC ON)
 286   elseif(${ALLOCATOR} STREQUAL "jemalloc")
 287     find_package(JeMalloc REQUIRED)
 288     set(HAVE_LIBJEMALLOC ${JEMALLOC_FOUND})
 289     set(HAVE_JEMALLOC 1)
 290   endif()
 291 else(ALLOCATOR)
 292   find_package(gperftools)
 293   set(HAVE_LIBTCMALLOC ${GPERFTOOLS_FOUND})
 294   if(NOT GPERFTOOLS_FOUND)
 295     find_package(JeMalloc)
 296     set(HAVE_LIBJEMALLOC ${JEMALLOC_FOUND})
 297   endif(NOT GPERFTOOLS_FOUND)
 298   if(GPERFTOOLS_FOUND)
 299     set(ALLOCATOR tcmalloc)
 300   elseif(JEMALLOC_FOUND)
 301     set(ALLOCATOR jemalloc)
 302   else()
 303     if(NOT FREEBSD)
 304       # FreeBSD already has jemalloc as its default allocator
 305       message(WARNING "tcmalloc and jemalloc not found, falling back to libc")
 306     endif()
 307     set(ALLOCATOR "libc")
 308   endif(GPERFTOOLS_FOUND)
 309 endif(ALLOCATOR)
 310
 311
 312 if(WITH_LIBCEPHFS OR WITH_KRBD)
 313   find_package(keyutils REQUIRED)
 314 endif()
 315
 316 find_package(CURL REQUIRED)
 317 set(CMAKE_REQUIRED_INCLUDES ${CURL_INCLUDE_DIRS})
 318 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBRARIES})
 319 CHECK_SYMBOL_EXISTS(curl_multi_wait curl/curl.h HAVE_CURL_MULTI_WAIT)
 320
 321 # nss or cryptopp?
 322 option(WITH_NSS "Use NSS crypto and SSL implementations" ON)
 323 if (${WITH_NSS})
 324   find_package(NSS REQUIRED)
 325     set(USE_NSS 1)
 326     find_package(NSPR REQUIRED)
 327     set(CRYPTO_LIBS ${NSS_LIBRARIES} ${NSPR_LIBRARIES})
 328 else ()
 329   find_package(cryptopp REQUIRED)
 330     set(CRYPTO_LIBS ${CRYPTOPP_LIBRARIES})
 331     set(USE_CRYPTOPP 1)
 332 endif (${WITH_NSS})
 333
 334 option(WITH_SSL "SSL build selected" ON)
 335 if(USE_NSS)
 336   #nss
 337   set(SSL_LIBRARIES ${NSS_LIBRARIES})
 338   message(STATUS "SSL with NSS selected (Libs: ${SSL_LIBRARIES})")
 339 else(USE_NSS)
 340   #openssl
 341   find_package(OpenSSL REQUIRED)
 342   set(USE_OPENSSL ON)
 343   set(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 344   message(STATUS "SSL with OpenSSL selected (Libs: ${SSL_LIBRARIES})")
 345 endif(USE_NSS)
 346
 347 option(WITH_XIO "Enable XIO messaging" OFF)
 348 if(WITH_XIO)
 349   find_package(xio REQUIRED)
 350 set(HAVE_XIO ${XIO_FOUND})
 351 endif(WITH_XIO)
 352
 353 option(WITH_DPDK "Enable DPDK messaging" OFF)
 354 if(WITH_DPDK)
 355 find_package(dpdk)
 356 set(HAVE_DPDK ${DPDK_FOUND})
 357 endif(WITH_DPDK)
 358
 359 option(WITH_BLKIN "Use blkin to emit LTTng tracepoints for Zipkin" OFF)
 360 if(WITH_BLKIN)
 361   set(BLKIN_LIBRARIES blkin lttng-ust)
 362   include_directories(src/blkin/blkin-lib)
 363 endif(WITH_BLKIN)
 364
 365 #option for RGW
 366 option(WITH_RADOSGW "Rados Gateway is enabled" ON)
 367 option(WITH_RADOSGW_FCGI_FRONTEND "Rados Gateway's FCGI frontend is enabled" OFF)
 368 option(WITH_RADOSGW_BEAST_FRONTEND "Rados Gateway's Beast frontend is enabled" ON)
 369 if(WITH_RADOSGW)
 370   find_package(EXPAT REQUIRED)
 371   if(WITH_RADOSGW_FCGI_FRONTEND)
 372     find_package(fcgi REQUIRED)
 373   endif()
 374 endif(WITH_RADOSGW)
 375
 376
 377 if (WITH_RADOSGW)
 378   if (NOT DEFINED OPENSSL_FOUND)
 379     message(STATUS "Looking for openssl anyways, because radosgw selected")
 380     find_package(OpenSSL)
 381   endif()
 382   if (OPENSSL_FOUND)
 383     execute_process(
 384       COMMAND
 385         "sh" "-c"
 386         "objdump -p ${OPENSSL_SSL_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 387       OUTPUT_VARIABLE LIBSSL_SONAME
 388       ERROR_VARIABLE OBJDUMP_ERRORS
 389       RESULT_VARIABLE OBJDUMP_RESULTS
 390       OUTPUT_STRIP_TRAILING_WHITESPACE)
 391     if (OBJDUMP_RESULTS)
 392       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 393     endif()
 394     if (NOT OBJDUMP_ERRORS STREQUAL "")
 395       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 396     endif()
 397     execute_process(
 398       COMMAND
 399         "sh" "-c"
 400         "objdump -p ${OPENSSL_CRYPTO_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 401       OUTPUT_VARIABLE LIBCRYPTO_SONAME
 402       ERROR_VARIABLE OBJDUMP_ERRORS
 403       RESULT_VARIABLE OBJDUMP_RESULTS
 404       OUTPUT_STRIP_TRAILING_WHITESPACE)
 405     if (OBJDUMP_RESULTS)
 406       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 407     endif()
 408     if (NOT OBJDUMP_ERRORS STREQUAL "")
 409       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 410     endif()
 411     message(STATUS "ssl soname: ${LIBSSL_SONAME}")
 412     message(STATUS "crypto soname: ${LIBCRYPTO_SONAME}")
 413   else()
 414     message(WARNING "ssl not found: rgw civetweb may fail to dlopen libssl libcrypto")
 415   endif()
 416 endif (WITH_RADOSGW)
 417
 418 #option for CephFS
 419 option(WITH_CEPHFS "CephFS is enabled" ON)
 420
 421 #option for Mgr
 422 option(WITH_MGR "ceph-mgr is enabled" ON)
 423 if(WITH_MGR)
 424     set(Python_ADDITIONAL_VERSIONS 2.7)
 425     find_package(PythonInterp 2.7 REQUIRED)
 426     find_package(PythonLibs 2.7 REQUIRED)
 427     # Boost dependency check deferred to Boost section
 428 endif(WITH_MGR)
 429
 430 option(WITH_THREAD_SAFE_RES_QUERY "res_query is thread safe" OFF)
 431 if(WITH_THREAD_SAFE_RES_QUERY)
 432     set(HAVE_THREAD_SAFE_RES_QUERY 1 CACHE INTERNAL "Thread safe res_query supported.")
 433 endif(WITH_THREAD_SAFE_RES_QUERY)
 434
 435 option(WITH_REENTRANT_STRSIGNAL "strsignal is reentrant" OFF)
 436 if(WITH_REENTRANT_STRSIGNAL)
 437     set(HAVE_REENTRANT_STRSIGNAL 1 CACHE INTERNAL "Reentrant strsignal is supported.")
 438 endif(WITH_REENTRANT_STRSIGNAL)
 439
 440 set(HAVE_LIBROCKSDB 1)
 441
 442 # -lz link into kv
 443 find_package(ZLIB REQUIRED)
 444
 445 #option for EventTrace
 446 option(WITH_EVENTTRACE "Event tracing support" OFF)
 447
 448 #option for LTTng
 449 option(WITH_LTTNG "LTTng tracing is enabled" ON)
 450 if(${WITH_LTTNG})
 451   find_package(LTTngUST REQUIRED)
 452   find_program(LTTNG_GEN_TP
 453     lttng-gen-tp)
 454   if(NOT LTTNG_GEN_TP)
 455     message(FATAL_ERROR "Can't find lttng-gen-tp.")
 456   endif()
 457 endif(${WITH_LTTNG})
 458
 459 option(WITH_OSD_INSTRUMENT_FUNCTIONS OFF)
 460
 461 #option for Babeltrace
 462 option(WITH_BABELTRACE "Babeltrace libraries are enabled" ON)
 463 if(WITH_BABELTRACE)
 464   set(HAVE_BABELTRACE ON)
 465   find_package(babeltrace REQUIRED)
 466   set(HAVE_BABELTRACE_BABELTRACE_H ${BABELTRACE_FOUND})
 467   set(HAVE_BABELTRACE_CTF_EVENTS_H ${BABELTRACE_FOUND})
 468   set(HAVE_BABELTRACE_CTF_ITERATOR_H ${BABELTRACE_FOUND})
 469 endif(WITH_BABELTRACE)
 470
 471 option(DEBUG_GATHER "C_Gather debugging is enabled" ON)
 472 option(ENABLE_COVERAGE "Coverage is enabled" OFF)
 473 option(PG_DEBUG_REFS "PG Ref debugging is enabled" OFF)
 474
 475 option(WITH_TESTS "enable the build of ceph-test package scripts/binaries" ON)
 476
 477 option(WITH_FIO "Support for fio engines" OFF)
 478 if(WITH_FIO)
 479   find_package(fio REQUIRED)
 480 endif(WITH_FIO)
 481
 482 if(LINUX)
 483   add_definitions(-D__linux__)
 484 endif(LINUX)
 485
 486 # ASAN and friends
 487 option(WITH_ASAN "build with ASAN" OFF)
 488 option(WITH_ASAN_LEAK "explicitly enable ASAN leak detection" OFF)
 489
 490 if(WITH_ASAN)
 491   set(ASAN_CFLAGS "-fsanitize=address -fno-omit-frame-pointer")
 492   if(WITH_ASAN_LEAK)
 493     set(ASAN_CFLAGS "${ASAN_CFLAGS} -fsanitize=leak")
 494   endif()
 495   set(ASAN_LFLAGS "${CMAKE_EXE_LINKER_FLAGS} ${ASAN_CFLAGS} -lasan")
 496   set(CMAKE_EXE_LINKER_FLAGS "${ASAN_LFLAGS}")
 497   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ASAN_CFLAGS}")
 498   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${ASAN_CFLAGS}")
 499   if(HAVE_JEMALLOC)
 500     message(FATAL "ASAN does not work well with JeMalloc")
 501   endif()
 502 endif()
 503
 504 option(WITH_TSAN "build with TSAN" OFF)
 505 if(WITH_TSAN)
 506   if (WITH_ASAN AND WITH_ASAN_LEAK)
 507     message(FATAL_ERROR "Cannot combine -fsanitize-leak w/-fsanitize-thread")
 508   endif()
 509   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -pie -ltsan ")
 510   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -fPIC")
 511   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -fPIC")
 512   if(HAVE_JEMALLOC)
 513     message(FATAL "TSAN does not work well with JeMalloc")
 514   endif()
 515 endif()
 516
 517 option(WITH_UBSAN "build with UBSAN" OFF)
 518 if(WITH_UBSAN)
 519   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=undefined")
 520   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined")
 521   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=undefined")
 522   if(HAVE_JEMALLOC)
 523     message(FATAL "UBSAN does not work well with JeMalloc")
 524   endif()
 525 endif()
 526
 527 # Rocksdb
 528 option(WITH_SYSTEM_ROCKSDB "require and build with system rocksdb" OFF)
 529 if (WITH_SYSTEM_ROCKSDB)
 530   find_package(rocksdb REQUIRED)
 531 endif()
 532
 533 # Boost
 534 option(WITH_SYSTEM_BOOST "require and build with system Boost" OFF)
 535
 536 # Boost::thread depends on Boost::atomic, so list it explicitly.
 537 set(BOOST_COMPONENTS
 538   atomic thread system regex random program_options date_time iostreams
 539   filesystem)
 540 set(BOOST_HEADER_COMPONENTS container)
 541
 542 if(WITH_MGR)
 543         list(APPEND BOOST_COMPONENTS python)
 544 endif()
 545
 546 if(WITH_RADOSGW_BEAST_FRONTEND)
 547         list(APPEND BOOST_COMPONENTS coroutine context)
 548 endif()
 549
 550 set(Boost_USE_MULTITHREADED ON)
 551 # require minimally the bundled version
 552 if(WITH_SYSTEM_BOOST)
 553   if(ENABLE_SHARED)
 554     set(Boost_USE_STATIC_LIBS OFF)
 555   else()
 556     set(Boost_USE_STATIC_LIBS ON)
 557   endif()
 558   find_package(Boost 1.61 COMPONENTS ${BOOST_COMPONENTS} REQUIRED)
 559 else()
 560   set(BOOST_J 1 CACHE STRING
 561     "max jobs for Boost build") # override w/-DBOOST_J=<n>
 562   set(Boost_USE_STATIC_LIBS ON)
 563   include(BuildBoost)
 564   build_boost(1.63
 565     COMPONENTS ${BOOST_COMPONENTS} ${BOOST_HEADER_COMPONENTS})
 566   include_directories(BEFORE SYSTEM ${Boost_INCLUDE_DIRS})
 567 endif()
 568 set(Boost_USE_MULTITHREADED ON)
 569
 570 include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)
 571
 572 find_package(Threads REQUIRED)
 573
 574 option(WITH_SELINUX "build SELinux policy" OFF)
 575 if(WITH_SELINUX)
 576   find_file(SELINUX_MAKEFILE selinux/devel/Makefile
 577     PATH /usr/share)
 578   if(NOT SELINUX_MAKEFILE)
 579     message(FATAL_ERROR "Can't find selinux's Makefile")
 580   endif()
 581   add_subdirectory(selinux)
 582 endif(WITH_SELINUX)
 583
 584 # enables testing and creates Make check command
 585 add_custom_target(tests
 586   COMMENT "Building tests")
 587 enable_testing()
 588 set(CMAKE_CTEST_COMMAND ctest)
 589 add_custom_target(check
 590   COMMAND ${CMAKE_CTEST_COMMAND}
 591   DEPENDS tests)
 592
 593 add_subdirectory(src)
 594
 595 add_subdirectory(doc)
 596 if(WITH_MANPAGE)
 597   add_subdirectory(man)
 598 endif(WITH_MANPAGE)
 599
 600 option(WITH_SYSTEMD "install systemd target and service files" OFF)
 601 if(WITH_SYSTEMD)
 602   add_subdirectory(systemd)
 603 endif()
 604
 605 include(CTags)
 606 option(CTAG_EXCLUDES "Exclude files/directories when running ctag.")
 607 add_tags(ctags
 608   SRC_DIR src
 609   TAG_FILE tags
 610   EXCLUDE_OPTS ${CTAG_EXCLUDES}
 611   EXCLUDES "*.js" "*.css")
 612 add_custom_target(tags DEPENDS ctags)