ceph/src/boost/libs/numeric/ublas/IDEs/qtcreator/test/configuration.pri

   1 CONFIG -= qt
   2 CONFIG += \
   3     depend_includepath \
   4     debug
   5 win*: CONFIG += console
   6
   7 QMAKE_CXXFLAGS += -fno-inline
   8
   9 # Create a directory for each test.
  10 DESTDIR = $${TARGET}
  11 OBJECTS_DIR = $${TARGET}
  12
  13 UBLAS_TESTSET = \
  14     USE_DOUBLE USE_STD_COMPLEX \
  15     USE_RANGE USE_SLICE \
  16     USE_UNBOUNDED_ARRAY USE_STD_VECTOR USE_BOUNDED_VECTOR USE_MATRIX
  17
  18 UBLAS_TESTSET_SPARSE = \
  19     USE_DOUBLE USE_STD_COMPLEX \
  20     USE_UNBOUNDED_ARRAY \
  21     USE_MAP_ARRAY USE_STD_MAP \
  22     USE_MAPPED_VECTOR USE_COMPRESSED_VECTOR \
  23     USE_MAPPED_MATRIX USE_COMPRESSED_MATRIX
  24     # USE_RANGE USE_SLICE        # Too complex for regression testing
  25
  26 UBLAS_TESTSET_SPARSE_COO = \
  27     USE_DOUBLE USE_STD_COMPLEX \
  28     USE_UNBOUNDED_ARRAY \
  29     USE_COORDINATE_VECTOR \
  30     USE_COORDINATE_MATRIX
  31
  32 DEFINES += BOOST_UBLAS_NO_EXCEPTIONS
  33
  34 win*: DEFINES += _SCL_SECURE_NO_WARNINGS
  35
  36 #Visual age IBM
  37 xlc: DEFINES += BOOST_UBLAS_NO_ELEMENT_PROXIES
  38
  39 # ublas include and test directory are included
  40 INCLUDEPATH += \
  41     ../../../include \
  42     ../../../test
  43
  44 # If ublas tests are build with boost source code then,
  45 # then boost headers and boost libraries should be used.
  46 exists(../../../../../../boost-build.jam) {
  47     INCLUDEPATH += ../../../../../..
  48     LIBS += -L../../../../../../stage/lib
  49     QMAKE_RPATHDIR += ../../../../../../stage/lib
  50 }
  51
  52 # Execute test once compiled.
  53 win*: QMAKE_POST_LINK = .\\$${DESTDIR}\\$${TARGET}.exe
  54 else: QMAKE_POST_LINK = ./$${DESTDIR}/$${TARGET}
  55