ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/libxml2/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.8)
   2 project(libxml2 C)
   3 include(GNUInstallDirs)
   4 set(WITH_TRIO 0 CACHE BOOL "Add trio support")
   5 set(WITH_THREADS 1 CACHE BOOL "Add multithread support")
   6 set(WITH_THREAD_ALLOC 0 CACHE BOOL "Add per-thread memory")
   7 set(WITH_TREE 1 CACHE BOOL "Add the DOM like tree manipulation APIs")
   8 set(WITH_OUTPUT 1 CACHE BOOL "Add the serialization support")
   9 set(WITH_PUSH 1 CACHE BOOL "Add the PUSH parser interfaces")
  10 set(WITH_READER 1 CACHE BOOL "Add the xmlReader parsing interface")
  11 set(WITH_PATTERN 1 CACHE BOOL "Add the xmlPattern selection interface")
  12 set(WITH_WRITER 1 CACHE BOOL "Add the xmlWriter saving interface")
  13 set(WITH_SAX1 1 CACHE BOOL "Add the older SAX1 interface")
  14 set(WITH_VALID 1 CACHE BOOL "Add the DTD validation support")
  15 set(WITH_HTML 1 CACHE BOOL "Add the HTML support")
  16 set(WITH_LEGACY 1 CACHE BOOL "Add deprecated APIs for compatibility")
  17 set(WITH_C14N 1 CACHE BOOL "Add the Canonicalization support")
  18 set(WITH_CATALOG 1 CACHE BOOL "Add the Catalog support")
  19 set(WITH_DOCB 1 CACHE BOOL "Add Docbook SGML support")
  20 set(WITH_XPATH 1 CACHE BOOL "Add the XPATH support")
  21 set(WITH_XPTR 1 CACHE BOOL "Add the XPointer support")
  22 set(WITH_XINCLUDE 1 CACHE BOOL "Add the XInclude support")
  23 set(WITH_ICONV 1 CACHE BOOL "Add ICONV support")
  24 set(WITH_ICU 0 CACHE BOOL "Add ICU support")
  25 set(WITH_ISO8859X 1 CACHE BOOL "Add ISO8859X support if no iconv")
  26 set(WITH_DEBUG 1 CACHE BOOL "Add the memory debugging module")
  27 set(WITH_MEM_DEBUG 0 CACHE BOOL "Add the memory debugging module")
  28 set(WITH_RUN_DEBUG 0 CACHE BOOL "Add the runtime debugging module")
  29 set(WITH_REGEXPS 1 CACHE BOOL "Add Regular Expressions support")
  30 set(WITH_SCHEMAS 1 CACHE BOOL "Add Relax-NG and Schemas support")
  31 set(WITH_SCHEMATRON 1 CACHE BOOL "Add Schematron support")
  32 set(WITH_MODULES 1 CACHE BOOL "Add the dynamic modules support")
  33 set(WITH_ZLIB 1 CACHE BOOL "Add zlib support")
  34 set(WITH_LZMA 1 CACHE BOOL "Add liblzma support")
  35 set(WITH_HTTP 1 CACHE BOOL "Add the HTTP support")
  36 set(WITH_FTP 1 CACHE BOOL "Add the FTP support")
  37
  38 option(INSTALL_HEADERS "Install public header files" ON)
  39
  40 set(MODULE_EXTENSION ".so")
  41
  42 set(CMAKE_SHARED_LIBRARY_PREFIX)
  43 set(CMAKE_STATIC_LIBRARY_PREFIX)
  44
  45 find_package(ZLIB REQUIRED)
  46 find_package(LibLZMA REQUIRED)
  47 find_package(Iconv REQUIRED)
  48
  49 file(GLOB SOURCES *.c)
  50 list(FILTER SOURCES EXCLUDE REGEX "/(run|test|trio)[^/]*$")
  51 list(FILTER SOURCES EXCLUDE REGEX "xml(lint|catalog).c$")
  52 list(FILTER SOURCES EXCLUDE REGEX "rngparser\.c$")
  53
  54 # Generate xmlexports with fixed definition of LIBXML_STATIC
  55 file(READ include/libxml/xmlexports.h XMLEXPORTS_H)
  56 if(BUILD_SHARED_LIBS)
  57     string(REPLACE "!defined(LIBXML_STATIC)" "1" XMLEXPORTS_H "${XMLEXPORTS_H}")
  58 else()
  59     string(REPLACE "!defined(LIBXML_STATIC)" "0" XMLEXPORTS_H "${XMLEXPORTS_H}")
  60 endif()
  61 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/xmlexports.h "${XMLEXPORTS_H}")
  62
  63 if(CMAKE_SYSTEM_NAME STREQUAL "Windows" OR CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
  64     configure_file(include/win32config.h config.h COPYONLY)
  65 elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  66     configure_file("${PORT_DIR}/config.osx.h" config.h COPYONLY)
  67 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  68     configure_file("${PORT_DIR}/config.linux.h" config.h COPYONLY)
  69 else()
  70     message(FATAL_ERROR "No config.h checked in for the target platform. Please run ./configure for libxml2 and add the resulting config.h into this port.")
  71 endif()
  72
  73 message(STATUS "Reading version info from configure.ac")
  74
  75 file(STRINGS "configure.ac"
  76     _libxml_version_defines REGEX "LIBXML_(MAJOR|MINOR|MICRO)_VERSION=([0-9]+)$")
  77
  78 foreach(ver ${_libxml_version_defines})
  79     if(ver MATCHES "LIBXML_(MAJOR|MINOR|MICRO)_VERSION=([0-9]+)$")
  80         set(LIBXML_${CMAKE_MATCH_1}_VERSION "${CMAKE_MATCH_2}" CACHE INTERNAL "")
  81     endif()
  82 endforeach()
  83
  84 set(VERSION ${LIBXML_MAJOR_VERSION}.${LIBXML_MINOR_VERSION}.${LIBXML_MICRO_VERSION})
  85 math(EXPR LIBXML_VERSION_NUMBER
  86     "${LIBXML_MAJOR_VERSION} * 10000 + ${LIBXML_MINOR_VERSION} * 100 + ${LIBXML_MICRO_VERSION}")
  87
  88 message(STATUS "LIBXML_MAJOR_VERSION: ${LIBXML_MAJOR_VERSION}")
  89 message(STATUS "LIBXML_MINOR_VERSION: ${LIBXML_MINOR_VERSION}")
  90 message(STATUS "LIBXML_MICRO_VERSION: ${LIBXML_MICRO_VERSION}")
  91 message(STATUS "VERSION: ${VERSION}")
  92 message(STATUS "LIBXML_VERSION_NUMBER: ${LIBXML_VERSION_NUMBER}")
  93
  94 if(CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
  95     set(WITH_CATALOG 0)
  96     set(WITH_MODULES 0)
  97 endif()
  98
  99 message(STATUS "Generating xmlversion.h")
 100
 101 configure_file(include/libxml/xmlversion.h.in include/libxml/xmlversion.h)
 102
 103 add_library(libxml2 ${SOURCES})
 104 if(INSTALL_HEADERS)
 105     file(GLOB PUBLIC_HEADERS include/libxml/*.h ${CMAKE_CURRENT_BINARY_DIR}/include/libxml/xmlversion.h)
 106     list(FILTER PUBLIC_HEADERS EXCLUDE REGEX "xmlexports\\.h$")
 107     list(APPEND PUBLIC_HEADERS ${CMAKE_CURRENT_BINARY_DIR}/xmlexports.h)
 108
 109     set_target_properties(libxml2 PROPERTIES PUBLIC_HEADER "${PUBLIC_HEADERS}")
 110 endif()
 111 target_include_directories(libxml2 PRIVATE ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/include include ${LIBLZMA_INCLUDE_DIRS})
 112 get_property(LIBRARIES TARGET Iconv::Iconv PROPERTY INTERFACE_LINK_LIBRARIES)
 113 if(LIBRARIES)
 114     set_property(TARGET Iconv::Iconv PROPERTY INTERFACE_LINK_LIBRARIES "")
 115     foreach(LIBRARY ${LIBRARIES})
 116         # Since `libc.so` has no SONAME, CMake maps e.g. `/usr/lib/x86_64-linux-gnu/libc.so` to `-llibc`.
 117         # This is not found: it should be mapped to `-lc`.
 118         if(LIBRARY MATCHES "/libc\\.so$")
 119             set_property(TARGET Iconv::Iconv APPEND PROPERTY INTERFACE_LINK_LIBRARIES "c")
 120         else()
 121             set_property(TARGET Iconv::Iconv APPEND PROPERTY INTERFACE_LINK_LIBRARIES "${LIBRARY}")
 122         endif()
 123     endforeach()
 124 endif()
 125 target_link_libraries(libxml2 PRIVATE
 126     Iconv::Iconv
 127     ZLIB::ZLIB
 128     ${LIBLZMA_LIBRARIES}
 129 )
 130 if(CMAKE_SYSTEM_NAME STREQUAL "Windows" OR CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
 131     target_include_directories(libxml2 PRIVATE win32/vc10)
 132     target_link_libraries(libxml2 PRIVATE
 133         wsock32.lib
 134         ws2_32.lib
 135     )
 136     target_compile_definitions(libxml2 PRIVATE
 137         -DHAVE_WIN32_THREADS
 138         _WINSOCK_DEPRECATED_NO_WARNINGS
 139     )
 140     target_sources(libxml2 PRIVATE win32/libxml2.rc)
 141     configure_file(rcVersion.h.in include/rcVersion.h @ONLY)
 142 endif()
 143
 144 target_compile_definitions(libxml2 PRIVATE
 145     -D_CRT_SECURE_NO_DEPRECATE
 146     -D_CRT_NONSTDC_NO_DEPRECATE
 147     -D_REENTRANT
 148     -DNOLIBTOOL
 149     -DHAVE_ZLIB_H
 150     -DHAVE_LZMA_H
 151 )
 152 if(NOT BUILD_SHARED_LIBS)
 153     target_compile_definitions(libxml2 PRIVATE -DLIBXML_STATIC)
 154 endif()
 155
 156 set(TARGET_INSTALL_OPTIONS)
 157 if(INSTALL_HEADERS)
 158     set(TARGET_INSTALL_OPTIONS PUBLIC_HEADER DESTINATION include/libxml)
 159 endif()
 160
 161 install(TARGETS libxml2
 162     RUNTIME DESTINATION bin
 163     LIBRARY DESTINATION lib
 164     ARCHIVE DESTINATION lib
 165     ${TARGET_INSTALL_OPTIONS}
 166 )
 167
 168 # pkgconfig
 169 set(prefix ${CMAKE_INSTALL_PREFIX})
 170 set(exec_prefix "\${prefix}")
 171 set(libdir ${prefix}/${CMAKE_INSTALL_LIBDIR})
 172 set(includedir ${prefix}/${CMAKE_INSTALL_INCLUDEDIR})
 173 set(XML_INCLUDEDIR "-I\"\${includedir}\"")
 174
 175 configure_file(libxml-2.0.pc.in libxml-2.0.pc @ONLY)
 176 install(FILES ${CMAKE_BINARY_DIR}/libxml-2.0.pc DESTINATION lib/pkgconfig)