ceph/src/rgw/CMakeLists.txt

   1 if(WITH_TESTS)
   2 add_executable(ceph_rgw_jsonparser
   3   rgw_jsonparser.cc)
   4 target_link_libraries(ceph_rgw_jsonparser
   5   rgw_a
   6   global)
   7
   8 add_executable(ceph_rgw_multiparser
   9   rgw_multiparser.cc)
  10 target_link_libraries(ceph_rgw_multiparser
  11   rgw_a
  12   global)
  13
  14 install(TARGETS
  15   ceph_rgw_jsonparser
  16   ceph_rgw_multiparser
  17   DESTINATION bin)
  18 endif(WITH_TESTS)
  19
  20 add_custom_target(civetweb_h
  21   COMMAND ${CMAKE_COMMAND} -E make_directory
  22   "${CMAKE_BINARY_DIR}/src/include/civetweb"
  23   COMMAND ${CMAKE_COMMAND} -E copy_if_different
  24   "${CMAKE_SOURCE_DIR}/src/civetweb/include/civetweb.h"
  25   "${CMAKE_BINARY_DIR}/src/include/civetweb"
  26   COMMENT "keep civetweb.h up-to-date")
  27
  28 find_program(GPERF gperf)
  29 if(NOT GPERF)
  30   message(FATAL_ERROR "Can't find gperf")
  31 endif()
  32 function(gperf_generate input output)
  33   add_custom_command(
  34     OUTPUT ${output}
  35     COMMAND ${GPERF} ${input} > ${output}
  36     DEPENDS ${input}
  37     COMMENT "Generate ${output}"
  38     )
  39 endfunction()
  40
  41 set(rgw_a_srcs
  42   rgw_acl.cc
  43   rgw_acl_s3.cc
  44   rgw_acl_swift.cc
  45   rgw_auth.cc
  46   rgw_auth_keystone.cc
  47   rgw_auth_s3.cc
  48   rgw_basic_types.cc
  49   rgw_bucket.cc
  50   rgw_cache.cc
  51   rgw_client_io.cc
  52   rgw_common.cc
  53   rgw_compression.cc
  54   rgw_cors.cc
  55   rgw_cors_s3.cc
  56   rgw_dencoder.cc
  57   rgw_env.cc
  58   rgw_es_query.cc
  59   rgw_formats.cc
  60   rgw_frontend.cc
  61   rgw_gc.cc
  62   rgw_http_client.cc
  63   rgw_json_enc.cc
  64   rgw_keystone.cc
  65   rgw_ldap.cc
  66   rgw_loadgen.cc
  67   rgw_log.cc
  68   rgw_lc.cc
  69   rgw_lc_s3.cc
  70   rgw_metadata.cc
  71   rgw_multi.cc
  72   rgw_multi_del.cc
  73   rgw_sync.cc
  74   rgw_data_sync.cc
  75   rgw_sync_module.cc
  76   rgw_sync_module_es.cc
  77   rgw_sync_module_es_rest.cc
  78   rgw_sync_module_log.cc
  79   rgw_period_history.cc
  80   rgw_period_puller.cc
  81   rgw_period_pusher.cc
  82   rgw_realm_reloader.cc
  83   rgw_realm_watcher.cc
  84   rgw_reshard.cc
  85   rgw_coroutine.cc
  86   rgw_cr_rados.cc
  87   rgw_object_expirer_core.cc
  88   rgw_op.cc
  89   rgw_os_lib.cc
  90   rgw_policy_s3.cc
  91   rgw_process.cc
  92   rgw_quota.cc
  93   rgw_rados.cc
  94   rgw_replica_log.cc
  95   rgw_request.cc
  96   rgw_resolve.cc
  97   rgw_rest_bucket.cc
  98   rgw_rest.cc
  99   rgw_rest_client.cc
 100   rgw_rest_config.cc
 101   rgw_rest_conn.cc
 102   rgw_rest_log.cc
 103   rgw_rest_metadata.cc
 104   rgw_rest_opstate.cc
 105   rgw_rest_realm.cc
 106   rgw_rest_replica_log.cc
 107   rgw_rest_role.cc
 108   rgw_rest_s3.cc
 109   rgw_rest_swift.cc
 110   rgw_rest_usage.cc
 111   rgw_rest_user.cc
 112   rgw_role.cc
 113   rgw_swift_auth.cc
 114   rgw_tag.cc
 115   rgw_tag_s3.cc
 116   rgw_tools.cc
 117   rgw_usage.cc
 118   rgw_user.cc
 119   rgw_website.cc
 120   rgw_xml.cc
 121   rgw_xml_enc.cc
 122   rgw_torrent.cc
 123   rgw_crypt.cc
 124   rgw_crypt_sanitize.cc
 125   rgw_iam_policy.cc)
 126
 127 gperf_generate(${CMAKE_SOURCE_DIR}/src/rgw/rgw_iam_policy_keywords.gperf
 128   rgw_iam_policy_keywords.frag.cc)
 129 set_source_files_properties(rgw_iam_policy.cc PROPERTIES
 130   OBJECT_DEPENDS ${CMAKE_BINARY_DIR}/src/rgw/rgw_iam_policy_keywords.frag.cc
 131   COMPILE_FLAGS -I${CMAKE_BINARY_DIR}/src/rgw)
 132
 133
 134 if (WITH_RADOSGW_FCGI_FRONTEND)
 135   list(APPEND rgw_a_srcs rgw_fcgi.cc)
 136 endif()
 137
 138 add_library(rgw_a STATIC ${rgw_a_srcs})
 139
 140 add_dependencies(rgw_a civetweb_h)
 141
 142 target_include_directories(rgw_a PUBLIC
 143   "../Beast/include"
 144   ${FCGI_INCLUDE_DIR}
 145   "../rapidjson/include"
 146   )
 147 target_compile_definitions(rgw_a PUBLIC BOOST_COROUTINES_NO_DEPRECATION_WARNING)
 148
 149 target_link_libraries(rgw_a librados cls_lock_client cls_rgw_client cls_refcount_client
 150   cls_log_client cls_statelog_client cls_timeindex_client cls_version_client
 151   cls_replica_log_client cls_user_client ceph-common common_utf8 global
 152   ${CURL_LIBRARIES}
 153   ${EXPAT_LIBRARIES}
 154   ${OPENLDAP_LIBRARIES} ${CRYPTO_LIBS})
 155
 156 set(radosgw_srcs
 157   rgw_loadgen_process.cc
 158   rgw_civetweb.cc
 159   rgw_civetweb_frontend.cc
 160   rgw_civetweb_log.cc)
 161
 162 if (WITH_RADOSGW_FCGI_FRONTEND)
 163   list(APPEND radosgw_srcs rgw_fcgi_process.cc)
 164 endif()
 165
 166 if (WITH_RADOSGW_BEAST_FRONTEND)
 167   list(APPEND radosgw_srcs
 168     rgw_asio_client.cc
 169     rgw_asio_frontend.cc)
 170 endif (WITH_RADOSGW_BEAST_FRONTEND)
 171
 172 add_library(radosgw_a STATIC ${radosgw_srcs}
 173   $<TARGET_OBJECTS:civetweb_common_objs>)
 174 target_link_libraries(radosgw_a rgw_a ${SSL_LIBRARIES})
 175 if(WITH_RADOSGW_BEAST_FRONTEND)
 176   target_link_libraries(radosgw_a
 177     Boost::coroutine
 178     Boost::context)
 179 endif()
 180
 181 add_executable(radosgw rgw_main.cc)
 182 target_link_libraries(radosgw radosgw_a librados
 183   cls_rgw_client cls_lock_client cls_refcount_client
 184   cls_log_client cls_statelog_client cls_timeindex_client
 185   cls_version_client cls_replica_log_client cls_user_client
 186   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 187   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES} ${BLKID_LIBRARIES}
 188   ${ALLOC_LIBS})
 189 # radosgw depends on cls libraries at runtime, but not as link dependencies
 190 add_dependencies(radosgw cls_rgw cls_lock cls_refcount
 191   cls_log cls_statelog cls_timeindex
 192   cls_version cls_replica_log cls_user)
 193 install(TARGETS radosgw DESTINATION bin)
 194
 195 set(radosgw_admin_srcs
 196   rgw_admin.cc
 197   rgw_orphan.cc)
 198 add_executable(radosgw-admin ${radosgw_admin_srcs})
 199 target_link_libraries(radosgw-admin rgw_a librados
 200   cls_rgw_client cls_lock_client cls_refcount_client
 201   cls_log_client cls_statelog_client cls_timeindex_client
 202   cls_version_client cls_replica_log_client cls_user_client
 203   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 204   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES} ${SSL_LIBRARIES} ${BLKID_LIBRARIES})
 205 install(TARGETS radosgw-admin DESTINATION bin)
 206
 207 set(radosgw_es_srcs
 208   rgw_es_main.cc)
 209 add_executable(radosgw-es ${radosgw_es_srcs})
 210 target_link_libraries(radosgw-es rgw_a librados
 211   cls_rgw_client cls_lock_client cls_refcount_client
 212   cls_log_client cls_statelog_client cls_timeindex_client
 213   cls_version_client cls_replica_log_client cls_user_client
 214   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 215   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES} ${SSL_LIBRARIES} ${BLKID_LIBRARIES})
 216 install(TARGETS radosgw-es DESTINATION bin)
 217
 218 set(radosgw_token_srcs
 219   rgw_token.cc)
 220 add_executable(radosgw-token ${radosgw_token_srcs})
 221 target_link_libraries(radosgw-token librados
 222   global ${ALLOC_LIBS})
 223 install(TARGETS radosgw-token DESTINATION bin)
 224
 225 set(radosgw_object_expirer_srcs
 226   rgw_object_expirer.cc)
 227 add_executable(radosgw-object-expirer ${radosgw_object_expirer_srcs})
 228 target_link_libraries(radosgw-object-expirer rgw_a librados
 229   cls_rgw_client cls_lock_client cls_refcount_client
 230   cls_log_client cls_statelog_client cls_timeindex_client
 231   cls_version_client cls_replica_log_client cls_user_client
 232   global ${FCGI_LIBRARY} ${LIB_RESOLV}
 233   ${CURL_LIBRARIES} ${EXPAT_LIBRARIES})
 234 install(TARGETS radosgw-object-expirer DESTINATION bin)
 235
 236 set(librgw_srcs
 237   librgw.cc
 238   rgw_file.cc)
 239 add_library(rgw SHARED ${librgw_srcs})
 240 target_link_libraries(rgw LINK_PRIVATE
 241   rgw_a
 242   librados
 243   cls_rgw_client
 244   cls_lock_client
 245   cls_refcount_client
 246   cls_log_client
 247   cls_statelog_client
 248   cls_timeindex_client
 249   cls_version_client
 250   cls_replica_log_client
 251   cls_user_client
 252   global
 253   ${LIB_RESOLV}
 254   ${CURL_LIBRARIES}
 255   ${EXPAT_LIBRARIES})
 256 set_target_properties(rgw PROPERTIES OUTPUT_NAME rgw VERSION 2.0.0
 257   SOVERSION 2)
 258 install(TARGETS rgw DESTINATION ${CMAKE_INSTALL_LIBDIR})
 259
 260 if(WITH_EMBEDDED)
 261   include(MergeStaticLibraries)
 262   add_library(cephd_rgw_base STATIC rgw_main.cc ${radosgw_admin_srcs})
 263   if(WITH_RADOSGW_FCGI_FRONTEND)
 264     target_include_directories(cephd_rgw_base PUBLIC ${FCGI_INCLUDE_DIR})
 265   endif()
 266   set_target_properties(cephd_rgw_base PROPERTIES COMPILE_DEFINITIONS BUILDING_FOR_EMBEDDED)
 267   merge_static_libraries(cephd_rgw cephd_rgw_base rgw_a radosgw_a)
 268   if(WITH_RADOSGW_FCGI_FRONTEND)
 269     target_link_libraries(cephd_rgw ${FCGI_LIBRARY})
 270   endif()
 271 endif()