ArmPlatformPkg: Changed memory model for the stacks

[mirror_edk2.git] / ArmPlatformPkg / PrePeiCore / PrePeiCoreEntryPoint.asm

//\r
//  Copyright (c) 2011, ARM Limited. All rights reserved.\r
//  \r
//  This program and the accompanying materials                          \r
//  are licensed and made available under the terms and conditions of the BSD License         \r
//  which accompanies this distribution.  The full text of the license may be found at        \r
//  http://opensource.org/licenses/bsd-license.php                                            \r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,                     \r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.             \r
//\r
//\r
\r
#include <AsmMacroIoLib.h>\r
#include <Base.h>\r
#include <Library/PcdLib.h>\r
#include <AutoGen.h>\r
\r
  INCLUDE AsmMacroIoLib.inc\r
  \r
  IMPORT  CEntryPoint\r
  IMPORT  ArmReadMpidr\r
  EXPORT  _ModuleEntryPoint\r
  \r
  PRESERVE8\r
  AREA    PrePeiCoreEntryPoint, CODE, READONLY\r
  \r
StartupAddr        DCD      CEntryPoint\r
\r
_ModuleEntryPoint\r
  // Identify CPU ID\r
  bl    ArmReadMpidr\r
  // Get ID of this CPU in Multicore system\r
  LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)\r
  and   r0, r0, r1\r
\r
  // Calculate the top of the primary stack\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoresStackBase), r1)\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)\r
  add   r2, r2, r1\r
\r
  // Is it the Primary Core ?\r
  LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r1)\r
  cmp   r0, r1\r
  beq   _SetupPrimaryCoreStack\r
\r
_SetupSecondaryCoreStack\r
  // r2 = Top of the primary stack = Base of the Secondary Stacks\r
\r
  // Get the position of the cores (ClusterId * 4) + CoreId\r
  GetCorePositionInStack(r3, r0, r1)\r
  // The stack starts at the top of the stack region. Add '1' to the Core Position to get the top of the stack\r
  add   r3, r3, #1\r
\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r1)\r
  // StackOffset = CorePos * StackSize\r
  mul   r3, r3, r1\r
  // SP = StackBase + StackOffset\r
  add   sp, r2, r3\r
\r
  b     _PrepareArguments\r
\r
_SetupPrimaryCoreStack\r
  // r2 = Top of the primary stack\r
  LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r3)\r
\r
  // The reserved space for global variable must be 8-bytes aligned for pushing\r
  // 64-bit variable on the stack\r
  SetPrimaryStack (r2, r3, r1)\r
\r
  // Set all the PEI global variables to 0\r
  mov   r3, sp\r
  mov   r1, #0x0\r
_InitGlobals\r
  str   r1, [r3], #4\r
  cmp   r3, r2\r
  blt   _InitGlobals\r
\r
_PrepareArguments\r
  // The PEI Core Entry Point has been computed by GenFV and stored in the second entry of the Reset Vector\r
  LoadConstantToReg (FixedPcdGet32(PcdNormalFvBaseAddress), r2)\r
  add   r2, r2, #4\r
  ldr   r1, [r2]\r
\r
  // move sec startup address into a data register\r
  // ensure we're jumping to FV version of the code (not boot remapped alias)\r
  ldr   r2, StartupAddr\r
\r
  // jump to PrePeiCore C code\r
  //    r0 = mp_id\r
  //    r1 = pei_core_address\r
  blx   r2\r
\r
_NeverReturn\r
  b _NeverReturn\r
\r
  END\r