ArmPlatformPkg: Change the memory model for the ARM Platform components

[mirror_edk2.git] / ArmPlatformPkg / PrePi / ModuleEntryPoint.S

//\r
//  Copyright (c) 2011, ARM Limited. All rights reserved.\r
//\r
//  This program and the accompanying materials\r
//  are licensed and made available under the terms and conditions of the BSD License\r
//  which accompanies this distribution.  The full text of the license may be found at\r
//  http://opensource.org/licenses/bsd-license.php\r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
//\r
//\r
\r
#include <AsmMacroIoLib.h>\r
#include <Base.h>\r
#include <Library/PcdLib.h>\r
#include <AutoGen.h>\r
\r
.text\r
.align 3\r
\r
# Global symbols referenced by this module\r
GCC_ASM_IMPORT(CEntryPoint)\r
GCC_ASM_EXPORT(_ModuleEntryPoint)\r
\r
StartupAddr: .word    CEntryPoint\r
\r
\r
ASM_PFX(_ModuleEntryPoint):\r
  // Identify CPU ID\r
  mrc   p15, 0, r0, c0, c0, 5\r
  and   r0, #0xf\r
\r
_SetSVCMode:\r
  // Enter SVC mode\r
  mov     r1, #0x13|0x80|0x40\r
  msr     CPSR_c, r1\r
\r
// Check if we can install the size at the top of the System Memory or if we need\r
// to install the stacks at the bottom of the Firmware Device (case the FD is located\r
// at the top of the DRAM)\r
_SetupStackPosition:\r
  // Compute Top of System Memory\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), r1)\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), r2)\r
  add   r1, r1, r2      // r1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize\r
\r
  // Calculate Top of the Firmware Device\r
  LoadConstantToReg (FixedPcdGet32(PcdNormalFdBaseAddress), r2)\r
  LoadConstantToReg (FixedPcdGet32(PcdNormalFdSize), r3)\r
  add   r3, r3, r2      // r4 = FdTop = PcdNormalFdBaseAddress + PcdNormalFdSize\r
\r
  // UEFI Memory Size (stacks are allocated in this region)\r
  LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), r4)\r
\r
  //\r
  // Reserve the memory for the UEFI region (contain stacks on its top)\r
  //\r
\r
  // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r
  subs	r5, r1, r3		// r5 = SystemMemoryTop - FdTop\r
  bmi	_SetupStack		// Jump if negative (FdTop > SystemMemoryTop)\r
  cmp	r5, r4\r
  bge	_SetupStack\r
\r
  // Case the top of stacks is the FdBaseAddress\r
  mov	r1, r2\r
\r
_SetupStack:\r
  // Compute Base of Normal stacks for CPU Cores\r
  LoadConstantToReg (FixedPcdGet32(PcdCPUCoresNonSecStackSize), r5)\r
  mul   r3, r0, r5      // r3 = core_id * stack_size = offset from the stack base\r
  sub   sp, r1, r3      // r3 = (SystemMemoryTop|FdBaseAddress) - StackOffset = TopOfStack\r
\r
  // Calculate the Base of the UEFI Memory\r
  sub	r1, r1, r4\r
\r
  // Only allocate memory for global variables at top of the primary core stack\r
  cmp   r0, #0\r
  bne   _PrepareArguments\r
\r
_AllocateGlobalPrePiVariables:\r
  // Reserve top of the stack for Global PEI Variables (eg: PeiServicesTablePointer)\r
  LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r4)\r
  // The reserved place must be 8-bytes aligned for pushing 64-bit variable on the stack\r
  and   r5, r4, #7\r
  rsb   r5, r5, #8\r
  add   r4, r4, r5\r
  sub   sp, sp, r4\r
\r
_PrepareArguments:\r
  // Move sec startup address into a data register\r
  // Ensure we're jumping to FV version of the code (not boot remapped alias)\r
  ldr   r2, StartupAddr\r
\r
  // Jump to PrePiCore C code\r
  //    r0 = core_id\r
  //    r1 = UefiMemoryBase\r
  blx   r2\r
\r