ArmVirtPkg/PrePi: move DRAM discovery code into PrePi

[mirror_edk2.git] / ArmVirtPkg / PrePi / AArch64 / ModuleEntryPoint.S

//\r
//  Copyright (c) 2011-2013, ARM Limited. All rights reserved.\r
//  Copyright (c) 2015-2016, Linaro Limited. All rights reserved.\r
//\r
//  This program and the accompanying materials\r
//  are licensed and made available under the terms and conditions of the BSD License\r
//  which accompanies this distribution.  The full text of the license may be found at\r
//  http://opensource.org/licenses/bsd-license.php\r
//\r
//  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
//  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
//\r
//\r
\r
#include <AsmMacroIoLibV8.h>\r
\r
ASM_FUNC(_ModuleEntryPoint)\r
  //\r
  // We are built as a ET_DYN PIE executable, so we need to process all\r
  // relative relocations regardless of whether or not we are executing from\r
  // the same offset we were linked at. This is only possible if we are\r
  // running from RAM.\r
  //\r
  adr   x8, __reloc_base\r
  adr   x9, __reloc_start\r
  adr   x10, __reloc_end\r
\r
.Lreloc_loop:\r
  cmp   x9, x10\r
  bhs   .Lreloc_done\r
\r
  //\r
  // AArch64 uses the ELF64 RELA format, which means each entry in the\r
  // relocation table consists of\r
  //\r
  //   UINT64 offset          : the relative offset of the value that needs to\r
  //                            be relocated\r
  //   UINT64 info            : relocation type and symbol index (the latter is\r
  //                            not used for R_AARCH64_RELATIVE relocations)\r
  //   UINT64 addend          : value to be added to the value being relocated\r
  //\r
  ldp   x11, x12, [x9], #24   // read offset into x11 and info into x12\r
  cmp   x12, #0x403           // check info == R_AARCH64_RELATIVE?\r
  bne   .Lreloc_loop          // not a relative relocation? then skip\r
\r
  ldr   x12, [x9, #-8]        // read addend into x12\r
  add   x12, x12, x8          // add reloc base to addend to get relocated value\r
  str   x12, [x11, x8]        // write relocated value at offset\r
  b     .Lreloc_loop\r
.Lreloc_done:\r
\r
  bl    ASM_PFX(DiscoverDramFromDt)\r
\r
  // Get ID of this CPU in Multicore system\r
  bl    ASM_PFX(ArmReadMpidr)\r
  // Keep a copy of the MpId register value\r
  mov   x20, x0\r
\r
// Check if we can install the stack at the top of the System Memory or if we need\r
// to install the stacks at the bottom of the Firmware Device (case the FD is located\r
// at the top of the DRAM)\r
_SetupStackPosition:\r
  // Compute Top of System Memory\r
  ldr   x1, PcdGet64 (PcdSystemMemoryBase)\r
  ldr   x2, PcdGet64 (PcdSystemMemorySize)\r
  sub   x2, x2, #1\r
  add   x1, x1, x2      // x1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize\r
\r
  // Calculate Top of the Firmware Device\r
  ldr   x2, PcdGet64 (PcdFdBaseAddress)\r
  MOV32 (w3, FixedPcdGet32 (PcdFdSize) - 1)\r
  add   x3, x3, x2      // x3 = FdTop = PcdFdBaseAddress + PcdFdSize\r
\r
  // UEFI Memory Size (stacks are allocated in this region)\r
  MOV32 (x4, FixedPcdGet32(PcdSystemMemoryUefiRegionSize))\r
\r
  //\r
  // Reserve the memory for the UEFI region (contain stacks on its top)\r
  //\r
\r
  // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r
  subs  x0, x1, x3   // x0 = SystemMemoryTop - FdTop\r
  b.mi  _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM\r
  cmp   x0, x4\r
  b.ge  _SetupStack\r
\r
  // Case the top of stacks is the FdBaseAddress\r
  mov   x1, x2\r
\r
_SetupStack:\r
  // x1 contains the top of the stack (and the UEFI Memory)\r
\r
  // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment\r
  // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the\r
  // top of the memory space)\r
  adds  x21, x1, #1\r
  b.cs  _SetupOverflowStack\r
\r
_SetupAlignedStack:\r
  mov   x1, x21\r
  b     _GetBaseUefiMemory\r
\r
_SetupOverflowStack:\r
  // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE\r
  // aligned (4KB)\r
  and   x1, x1, ~EFI_PAGE_MASK\r
\r
_GetBaseUefiMemory:\r
  // Calculate the Base of the UEFI Memory\r
  sub   x21, x1, x4\r
\r
_GetStackBase:\r
  // r1 = The top of the Mpcore Stacks\r
  // Stack for the primary core = PrimaryCoreStack\r
  MOV32 (x2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))\r
  sub   x22, x1, x2\r
\r
  // Stack for the secondary core = Number of Cores - 1\r
  MOV32 (x1, (FixedPcdGet32(PcdCoreCount) - 1) * FixedPcdGet32(PcdCPUCoreSecondaryStackSize))\r
  sub   x22, x22, x1\r
\r
  // x22 = The base of the MpCore Stacks (primary stack & secondary stacks)\r
  mov   x0, x22\r
  mov   x1, x20\r
  //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)\r
  MOV32 (x2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))\r
  MOV32 (x3, FixedPcdGet32(PcdCPUCoreSecondaryStackSize))\r
  bl    ASM_PFX(ArmPlatformStackSet)\r
\r
  mov   x0, x20\r
  mov   x1, x21\r
  mov   x2, x22\r
\r
  // Jump to PrePiCore C code\r
  //    x0 = MpId\r
  //    x1 = UefiMemoryBase\r
  //    x2 = StacksBase\r
  bl    ASM_PFX(CEntryPoint)\r
\r
_NeverReturn:\r
  b _NeverReturn\r
\r
// VOID\r
// DiscoverDramFromDt (\r
//   VOID   *DeviceTreeBaseAddress,   // passed by loader in x0\r
//   VOID   *ImageBase                // passed by FDF trampoline in x1\r
//   );\r
ASM_PFX(DiscoverDramFromDt):\r
  //\r
  // If we are booting from RAM using the Linux kernel boot protocol, x0 will\r
  // point to the DTB image in memory. Otherwise, use the default value defined\r
  // by the platform.\r
  //\r
  cbnz  x0, 0f\r
  ldr   x0, PcdGet64 (PcdDeviceTreeInitialBaseAddress)\r
\r
0:mov   x29, x30            // preserve LR\r
  mov   x28, x0             // preserve DTB pointer\r
  mov   x27, x1             // preserve base of image pointer\r
\r
  //\r
  // The base of the runtime image has been preserved in x1. Check whether\r
  // the expected magic number can be found in the header.\r
  //\r
  ldr   w8, .LArm64LinuxMagic\r
  ldr   w9, [x1, #0x38]\r
  cmp   w8, w9\r
  bne   .Lout\r
\r
  //\r
  //\r
  // OK, so far so good. We have confirmed that we likely have a DTB and are\r
  // booting via the arm64 Linux boot protocol. Update the base-of-image PCD\r
  // to the actual relocated value, and add the shift of PcdFdBaseAddress to\r
  // PcdFvBaseAddress as well\r
  //\r
  adr   x8, PcdGet64 (PcdFdBaseAddress)\r
  adr   x9, PcdGet64 (PcdFvBaseAddress)\r
  ldr   x6, [x8]\r
  ldr   x7, [x9]\r
  sub   x7, x7, x6\r
  add   x7, x7, x1\r
  str   x1, [x8]\r
  str   x7, [x9]\r
\r
  //\r
  // Discover the memory size and offset from the DTB, and record in the\r
  // respective PCDs. This will also return false if a corrupt DTB is\r
  // encountered. Since we are calling a C function, use the window at the\r
  // beginning of the FD image as a temp stack.\r
  //\r
  adr   x1, PcdGet64 (PcdSystemMemoryBase)\r
  adr   x2, PcdGet64 (PcdSystemMemorySize)\r
  mov   sp, x7\r
  bl    FindMemnode\r
  cbz   x0, .Lout\r
\r
  //\r
  // Copy the DTB to the slack space right after the 64 byte arm64/Linux style\r
  // image header at the base of this image (defined in the FDF), and record the\r
  // pointer in PcdDeviceTreeInitialBaseAddress.\r
  //\r
  adr   x8, PcdGet64 (PcdDeviceTreeInitialBaseAddress)\r
  add   x27, x27, #0x40\r
  str   x27, [x8]\r
\r
  mov   x0, x27\r
  mov   x1, x28\r
  bl    CopyFdt\r
\r
.Lout:\r
  ret    x29\r
\r
.LArm64LinuxMagic:\r
  .byte   0x41, 0x52, 0x4d, 0x64\r