Add in the 1st version of ECP.

[mirror_edk2.git] / EdkCompatibilityPkg / Foundation / Library / CompilerStub / Ia32 / memsetSSE2.asm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2007, Intel Corporation\r
; All rights reserved. This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
; Module Name:\r
;\r
;   SetMem.asm\r
;\r
; Abstract:\r
;\r
;   memset function\r
;\r
; Notes:\r
;\r
;------------------------------------------------------------------------------\r
\r
    .686\r
    .model  flat,C\r
    .xmm\r
    .code\r
\r
;------------------------------------------------------------------------------\r
;  VOID *\r
;  memset (\r
;    OUT VOID   *Buffer,\r
;    IN  UINT8  Value,\r
;    IN  UINTN  Count\r
;    )\r
;------------------------------------------------------------------------------\r
memset   PROC    USES    edi\r
    mov     edx, [esp + 16]             ; edx <- Count\r
    cmp     edx, 0                      ; if Count == 0, do nothing\r
    je      @SetDone    \r
    mov     edi, [esp + 8]              ; edi <- Buffer\r
    mov     al, [esp + 12]              ; al <- Value\r
    xor     ecx, ecx\r
    sub     ecx, edi\r
    and     ecx, 15                     ; ecx + edi aligns on 16-byte boundary\r
    jz      @F\r
    cmp     ecx, edx\r
    cmova   ecx, edx\r
    sub     edx, ecx\r
    rep     stosb\r
@@:\r
    mov     ecx, edx\r
    and     edx, 15\r
    shr     ecx, 4                      ; ecx <- # of DQwords to set\r
    jz      @SetBytes\r
    mov     ah, al                      ; ax <- Value | (Value << 8)\r
    add     esp, -16\r
    movd    xmm0, eax\r
    pshuflw xmm0, xmm0, 0               ; xmm0[0..63] <- Value repeats 8 times\r
    movlhps xmm0, xmm0                  ; xmm0 <- Value repeats 16 times\r
@@:\r
    movdqa  [edi], xmm0                 ; edi should be 16-byte aligned\r
    add     edi, 16\r
    loop    @B\r
    add     esp, 16                     ; stack cleanup\r
@SetBytes:\r
    mov     ecx, edx\r
    rep     stosb\r
@SetDone:    \r
    mov     eax, [esp + 8]              ; eax <- Buffer as return value\r
    ret\r
memset   ENDP\r
\r
    END\r