EdkCompatibilityPkg/Foundation/Library/CompilerStub/Ia32/memsetSSE2.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   memset function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .686
  25     .model  flat,C
  26     .xmm
  27     .code
  28
  29 ;------------------------------------------------------------------------------
  30 ;  VOID *
  31 ;  memset (
  32 ;    OUT VOID   *Buffer,
  33 ;    IN  UINT8  Value,
  34 ;    IN  UINTN  Count
  35 ;    )
  36 ;------------------------------------------------------------------------------
  37 memset   PROC    USES    edi
  38     mov     edx, [esp + 16]             ; edx <- Count
  39     cmp     edx, 0                      ; if Count == 0, do nothing
  40     je      @SetDone
  41     mov     edi, [esp + 8]              ; edi <- Buffer
  42     mov     al, [esp + 12]              ; al <- Value
  43     xor     ecx, ecx
  44     sub     ecx, edi
  45     and     ecx, 15                     ; ecx + edi aligns on 16-byte boundary
  46     jz      @F
  47     cmp     ecx, edx
  48     cmova   ecx, edx
  49     sub     edx, ecx
  50     rep     stosb
  51 @@:
  52     mov     ecx, edx
  53     and     edx, 15
  54     shr     ecx, 4                      ; ecx <- # of DQwords to set
  55     jz      @SetBytes
  56     mov     ah, al                      ; ax <- Value | (Value << 8)
  57     add     esp, -16
  58     movd    xmm0, eax
  59     pshuflw xmm0, xmm0, 0               ; xmm0[0..63] <- Value repeats 8 times
  60     movlhps xmm0, xmm0                  ; xmm0 <- Value repeats 16 times
  61 @@:
  62     movdqa  [edi], xmm0                 ; edi should be 16-byte aligned
  63     add     edi, 16
  64     loop    @B
  65     add     esp, 16                     ; stack cleanup
  66 @SetBytes:
  67     mov     ecx, edx
  68     rep     stosb
  69 @SetDone:
  70     mov     eax, [esp + 8]              ; eax <- Buffer as return value
  71     ret
  72 memset   ENDP
  73
  74     END