MdeModulePkg/EbcDxe: Add AARCH64 EBC VM support

[mirror_edk2.git] / MdeModulePkg / Universal / EbcDxe / AArch64 / EbcLowLevel.S

#/** @file\r
#\r
#    This code provides low level routines that support the Virtual Machine\r
#   for option ROMs.\r
#\r
#  Copyright (c) 2015, The Linux Foundation. All rights reserved.\r
#  Copyright (c) 2007 - 2014, Intel Corporation. All rights reserved.<BR>\r
#  This program and the accompanying materials\r
#  are licensed and made available under the terms and conditions of the BSD License\r
#  which accompanies this distribution.  The full text of the license may be found at\r
#  http://opensource.org/licenses/bsd-license.php\r
#\r
#  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
#  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
#**/\r
\r
#---------------------------------------------------------------------------\r
# Equate files needed.\r
#---------------------------------------------------------------------------\r
\r
ASM_GLOBAL ASM_PFX(CopyMem);\r
ASM_GLOBAL ASM_PFX(EbcInterpret);\r
ASM_GLOBAL ASM_PFX(ExecuteEbcImageEntryPoint);\r
\r
#****************************************************************************\r
# EbcLLCALLEX\r
#\r
# This function is called to execute an EBC CALLEX instruction.\r
# This instruction requires that we thunk out to external native\r
# code. For AArch64, we copy the VM stack into the main stack and then pop\r
# the first 8 arguments off according to the AArch64 Procedure Call Standard\r
# On return, we restore the stack pointer to its original location.\r
#\r
#****************************************************************************\r
# UINTN EbcLLCALLEXNative(UINTN FuncAddr, UINTN NewStackPointer, VOID *FramePtr)\r
ASM_GLOBAL ASM_PFX(EbcLLCALLEXNative);\r
ASM_PFX(EbcLLCALLEXNative):\r
      stp  x19, x20, [sp, #-16]!\r
      stp  x29, x30, [sp, #-16]!\r
\r
      mov  x19, x0\r
      mov  x20, sp\r
      sub  x2, x2, x1   // Length = NewStackPointer-FramePtr\r
      sub  sp, sp, x2\r
      sub  sp, sp, #64  // Make sure there is room for at least 8 args in the new stack\r
      mov  x0, sp\r
\r
      bl   CopyMem      // Sp, NewStackPointer, Length\r
\r
      ldp  x0, x1, [sp], #16\r
      ldp  x2, x3, [sp], #16\r
      ldp  x4, x5, [sp], #16\r
      ldp  x6, x7, [sp], #16\r
\r
      blr  x19\r
\r
      mov  sp,  x20\r
      ldp  x29, x30, [sp], #16\r
      ldp  x19, x20, [sp], #16\r
\r
      ret\r
\r
#****************************************************************************\r
# EbcLLEbcInterpret\r
#\r
# This function is called by the thunk code to handle an Native to EBC call\r
# This can handle up to 16 arguments (1-8 on in x0-x7, 9-16 are on the stack)\r
# x9 contains the Entry point that will be the first argument when\r
# EBCInterpret is called.\r
#\r
#****************************************************************************\r
ASM_GLOBAL ASM_PFX(EbcLLEbcInterpret);\r
ASM_PFX(EbcLLEbcInterpret):\r
    stp  x29, x30, [sp, #-16]!\r
\r
    // copy the current arguments 9-16 from old location and add arg 7 to stack\r
    // keeping 16 byte stack alignment\r
    sub sp, sp, #80\r
    str x7, [sp]\r
    ldr x11, [sp, #96]\r
    str x11, [sp, #8]\r
    ldr x11, [sp, #104]\r
    str x11, [sp, #16]\r
    ldr x11, [sp, #112]\r
    str x11, [sp, #24]\r
    ldr x11, [sp, #120]\r
    str x11, [sp, #32]\r
    ldr x11, [sp, #128]\r
    str x11, [sp, #40]\r
    ldr x11, [sp, #136]\r
    str x11, [sp, #48]\r
    ldr x11, [sp, #144]\r
    str x11, [sp, #56]\r
    ldr x11, [sp, #152]\r
    str x11, [sp, #64]\r
\r
    // Shift arguments and add entry point and as argument 1\r
    mov x7, x6\r
    mov x6, x5\r
    mov x5, x4\r
    mov x4, x3\r
    mov x3, x2\r
    mov x2, x1\r
    mov x1, x0\r
    mov x0, x9\r
\r
    # call C-code\r
    bl ASM_PFX(EbcInterpret)\r
    add sp, sp, #80\r
\r
    ldp  x29, x30, [sp], #16\r
\r
    ret\r
\r
#****************************************************************************\r
# EbcLLExecuteEbcImageEntryPoint\r
#\r
# This function is called by the thunk code to handle the image entry point\r
# x9 contains the Entry point that will be the first argument when\r
# ExecuteEbcImageEntryPoint is called.\r
#\r
#****************************************************************************\r
ASM_GLOBAL ASM_PFX(EbcLLExecuteEbcImageEntryPoint);\r
ASM_PFX(EbcLLExecuteEbcImageEntryPoint):\r
    stp  x29, x30, [sp, #-16]!\r
    # build new paramater calling convention\r
    mov  x2, x1\r
    mov  x1, x0\r
    mov  x0, x9\r
\r
    # call C-code\r
    bl ASM_PFX(ExecuteEbcImageEntryPoint)\r
    ldp  x29, x30, [sp], #16\r
    ret\r