MdePkg/BaseLib: Add bit field population calculating methods

[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibSse2 / Ia32 / ZeroMem.nasm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php.\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
; Module Name:\r
;\r
;   ZeroMem.nasm\r
;\r
; Abstract:\r
;\r
;   ZeroMem function\r
;\r
; Notes:\r
;\r
;------------------------------------------------------------------------------\r
\r
    SECTION .text\r
\r
;------------------------------------------------------------------------------\r
;  VOID *\r
;  EFIAPI\r
;  InternalMemZeroMem (\r
;    IN VOID   *Buffer,\r
;    IN UINTN  Count\r
;    );\r
;------------------------------------------------------------------------------\r
global ASM_PFX(InternalMemZeroMem)\r
ASM_PFX(InternalMemZeroMem):\r
    push    edi\r
    mov     edi, [esp + 8]\r
    mov     edx, [esp + 12]\r
    xor     ecx, ecx\r
    sub     ecx, edi\r
    xor     eax, eax\r
    and     ecx, 15\r
    jz      .0\r
    cmp     ecx, edx\r
    cmova   ecx, edx\r
    sub     edx, ecx\r
    rep     stosb\r
.0:\r
    mov     ecx, edx\r
    and     edx, 15\r
    shr     ecx, 4\r
    jz      @ZeroBytes\r
    pxor    xmm0, xmm0\r
.1:\r
    movntdq [edi], xmm0\r
    add     edi, 16\r
    loop    .1\r
    mfence\r
@ZeroBytes:\r
    mov     ecx, edx\r
    rep     stosb\r
    mov     eax, [esp + 8]\r
    pop     edi\r
    ret\r
\r