ArmPlatformPkg/PrePeiCore/PrePeiCoreEntryPoint.asm

   1 //
   2 //  Copyright (c) 2011, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AsmMacroIoLib.h>
  15 #include <Base.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18
  19   INCLUDE AsmMacroIoLib.inc
  20
  21   IMPORT  CEntryPoint
  22   IMPORT  ArmReadMpidr
  23   EXPORT  _ModuleEntryPoint
  24
  25   PRESERVE8
  26   AREA    PrePeiCoreEntryPoint, CODE, READONLY
  27
  28 StartupAddr        DCD      CEntryPoint
  29
  30 _ModuleEntryPoint
  31   // Identify CPU ID
  32   bl    ArmReadMpidr
  33   // Get ID of this CPU in Multicore system
  34   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)
  35   and   r5, r0, r1
  36
  37   // Get the top of the primary stacks (and the base of the secondary stacks)
  38   LoadConstantToReg (FixedPcdGet32(PcdCPUCoresStackBase), r1)
  39   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
  40   add   r1, r1, r2
  41
  42   // Is it the Primary Core ?
  43   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r3)
  44   cmp   r5, r3
  45   beq   _SetupPrimaryCoreStack
  46
  47 _SetupSecondaryCoreStack
  48   // r1 contains the base of the secondary stacks
  49
  50   // Get the Core Position (ClusterId * 4) + CoreId
  51   GetCorePositionFromMpId(r0, r5, r2)
  52   // The stack starts at the top of the stack region. Add '1' to the Core Position to get the top of the stack
  53   add   r0, r0, #1
  54
  55   // StackOffset = CorePos * StackSize
  56   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r2)
  57   mul   r0, r0, r2
  58   // SP = StackBase + StackOffset
  59   add   sp, r1, r0
  60
  61 _PrepareArguments
  62   // The PEI Core Entry Point has been computed by GenFV and stored in the second entry of the Reset Vector
  63   LoadConstantToReg (FixedPcdGet32(PcdFvBaseAddress), r2)
  64   add   r2, r2, #4
  65   ldr   r1, [r2]
  66
  67   // Move sec startup address into a data register
  68   // Ensure we're jumping to FV version of the code (not boot remapped alias)
  69   ldr   r3, StartupAddr
  70
  71   // Jump to PrePeiCore C code
  72   //    r0 = mp_id
  73   //    r1 = pei_core_address
  74   mov   r0, r5
  75   blx   r3
  76
  77 _SetupPrimaryCoreStack
  78   // r1 contains the top of the primary stack
  79   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r2)
  80
  81   // The reserved space for global variable must be 8-bytes aligned for pushing
  82   // 64-bit variable on the stack
  83   SetPrimaryStack (r1, r2, r3)
  84   b     _PrepareArguments
  85
  86 _NeverReturn
  87   b _NeverReturn
  88
  89   END