ArmPlatformPkg/PrePi/AArch64/ModuleEntryPoint.S

   1 //
   2 //  Copyright (c) 2011-2013, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AsmMacroIoLibV8.h>
  15 #include <Base.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18
  19 #include <Chipset/ArmV7.h>
  20
  21 .text
  22 .align 3
  23
  24 GCC_ASM_IMPORT(ArmPlatformIsPrimaryCore)
  25 GCC_ASM_IMPORT(ArmReadMpidr)
  26 GCC_ASM_IMPORT(ArmPlatformPeiBootAction)
  27 GCC_ASM_IMPORT(ArmPlatformStackSet)
  28 GCC_ASM_EXPORT(_ModuleEntryPoint)
  29
  30 StartupAddr:        .dword       ASM_PFX(CEntryPoint)
  31
  32 ASM_PFX(_ModuleEntryPoint):
  33   // Do early platform specific actions
  34   bl    ASM_PFX(ArmPlatformPeiBootAction)
  35
  36   // Get ID of this CPU in Multicore system
  37   bl    ASM_PFX(ArmReadMpidr)
  38   // Keep a copy of the MpId register value
  39   mov   x10, x0
  40
  41 _SetSVCMode:
  42 // Check if we can install the stack at the top of the System Memory or if we need
  43 // to install the stacks at the bottom of the Firmware Device (case the FD is located
  44 // at the top of the DRAM)
  45 _SetupStackPosition:
  46   // Compute Top of System Memory
  47   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), x1)
  48   LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), x2)
  49   sub   x2, x2, #1
  50   add   x1, x1, x2      // x1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize
  51
  52   // Calculate Top of the Firmware Device
  53   LoadConstantToReg (FixedPcdGet32(PcdFdBaseAddress), x2)
  54   LoadConstantToReg (FixedPcdGet32(PcdFdSize), x3)
  55   sub   x3, x3, #1
  56   add   x3, x3, x2      // x3 = FdTop = PcdFdBaseAddress + PcdFdSize
  57
  58   // UEFI Memory Size (stacks are allocated in this region)
  59   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), x4)
  60
  61   //
  62   // Reserve the memory for the UEFI region (contain stacks on its top)
  63   //
  64
  65   // Calculate how much space there is between the top of the Firmware and the Top of the System Memory
  66   subs  x0, x1, x3   // x0 = SystemMemoryTop - FdTop
  67   b.mi  _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM
  68   cmp   x0, x4
  69   b.ge  _SetupStack
  70
  71   // Case the top of stacks is the FdBaseAddress
  72   mov   x1, x2
  73
  74 _SetupStack:
  75   // x1 contains the top of the stack (and the UEFI Memory)
  76
  77   // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment
  78   // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the
  79   // top of the memory space)
  80   adds  x11, x1, #1
  81   b.cs  _SetupOverflowStack
  82
  83 _SetupAlignedStack:
  84   mov   x1, x11
  85   b     _GetBaseUefiMemory
  86
  87 _SetupOverflowStack:
  88   // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE
  89   // aligned (4KB)
  90   LoadConstantToReg (EFI_PAGE_MASK, x11)
  91   and   x11, x11, x1
  92   sub   x1, x1, x11
  93
  94 _GetBaseUefiMemory:
  95   // Calculate the Base of the UEFI Memory
  96   sub   x11, x1, x4
  97
  98 _GetStackBase:
  99   // r1 = The top of the Mpcore Stacks
 100   // Stack for the primary core = PrimaryCoreStack
 101   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), x2)
 102   sub   x12, x1, x2
 103
 104   // Stack for the secondary core = Number of Cores - 1
 105   LoadConstantToReg (FixedPcdGet32(PcdCoreCount), x0)
 106   sub   x0, x0, #1
 107   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), x1)
 108   mul   x1, x1, x0
 109   sub   x12, x12, x1
 110
 111   // x12 = The base of the MpCore Stacks (primary stack & secondary stacks)
 112   mov   x0, x12
 113   mov   x1, x10
 114   //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)
 115   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), x2)
 116   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), x3)
 117   bl    ASM_PFX(ArmPlatformStackSet)
 118
 119   // Is it the Primary Core ?
 120   mov   x0, x10
 121   bl    ASM_PFX(ArmPlatformIsPrimaryCore)
 122   cmp   x0, #1
 123   bne   _PrepareArguments
 124
 125 _ReserveGlobalVariable:
 126   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), x0)
 127   // InitializePrimaryStack($GlobalVariableSize, $Tmp1, $Tmp2)
 128   InitializePrimaryStack(x0, x1, x2)
 129
 130 _PrepareArguments:
 131   mov   x0, x10
 132   mov   x1, x11
 133   mov   x2, x12
 134   mov   x3, sp
 135
 136   // Move sec startup address into a data register
 137   // Ensure we're jumping to FV version of the code (not boot remapped alias)
 138   ldr   x4, StartupAddr
 139
 140   // Jump to PrePiCore C code
 141   //    x0 = MpId
 142   //    x1 = UefiMemoryBase
 143   //    x2 = StacksBase
 144   //    x3 = GlobalVariableBase
 145   blr   x4
 146
 147 _NeverReturn:
 148   b _NeverReturn