ArmPlatformPkg/PrePi/ModuleEntryPoint.asm

   1 //
   2 //  Copyright (c) 2011, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AsmMacroIoLib.h>
  15 #include <Base.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18
  19   INCLUDE AsmMacroIoLib.inc
  20
  21   IMPORT  CEntryPoint
  22   IMPORT  ArmReadMpidr
  23   IMPORT  ArmIsMPCore
  24   EXPORT  _ModuleEntryPoint
  25
  26   PRESERVE8
  27   AREA    PrePiCoreEntryPoint, CODE, READONLY
  28
  29 StartupAddr        DCD      CEntryPoint
  30
  31 _ModuleEntryPoint
  32   // Get ID of this CPU in Multicore system
  33   bl    ArmReadMpidr
  34   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)
  35   and   r5, r0, r1
  36
  37 _SetSVCMode
  38   // Enter SVC mode
  39   mov     r1, #0x13|0x80|0x40
  40   msr     CPSR_c, r1
  41
  42 // Check if we can install the stack at the top of the System Memory or if we need
  43 // to install the stacks at the bottom of the Firmware Device (case the FD is located
  44 // at the top of the DRAM)
  45 _SetupStackPosition
  46   // Compute Top of System Memory
  47   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), r1)
  48   LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), r2)
  49   add   r1, r1, r2      // r1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize
  50
  51   // Calculate Top of the Firmware Device
  52   LoadConstantToReg (FixedPcdGet32(PcdNormalFdBaseAddress), r2)
  53   LoadConstantToReg (FixedPcdGet32(PcdNormalFdSize), r3)
  54   add   r3, r3, r2      // r4 = FdTop = PcdNormalFdBaseAddress + PcdNormalFdSize
  55
  56   // UEFI Memory Size (stacks are allocated in this region)
  57   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), r4)
  58
  59   //
  60   // Reserve the memory for the UEFI region (contain stacks on its top)
  61   //
  62
  63   // Calculate how much space there is between the top of the Firmware and the Top of the System Memory
  64   subs  r0, r1, r3      // r0 = SystemMemoryTop - FdTop
  65   bmi   _SetupStack     // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM
  66   cmp   r0, r4
  67   bge   _SetupStack
  68
  69   // Case the top of stacks is the FdBaseAddress
  70   mov   r1, r2
  71
  72 _SetupStack
  73   // r1 contains the top of the stack (and the UEFI Memory)
  74
  75   // Calculate the Base of the UEFI Memory
  76   sub   r6, r1, r4
  77
  78 _GetStackBase
  79   // Compute Base of Normal stacks for CPU Cores
  80   // Is it MpCore system
  81   bl    ArmIsMPCore
  82   cmp   r0, #0
  83   // Case it is not an MP Core system. Just setup the primary core
  84   beq   _SetupUnicoreStack
  85
  86 _GetStackBaseMpCore
  87   // Stack for the primary core = PrimaryCoreStack
  88   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
  89   sub   r7, r1, r2
  90   // Stack for the secondary core = Number of Cluster * (4 Core per cluster) * SecondaryStackSize
  91   LoadConstantToReg (FixedPcdGet32(PcdClusterCount), r2)
  92   lsl   r2, r2, #2
  93   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r3)
  94   mul   r2, r2, r3
  95   sub   r7, r7, r2
  96
  97   // The top of the Mpcore Stacks is in r1
  98   // The base of the MpCore Stacks is in r7
  99
 100   // Is it the Primary Core ?
 101   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r4)
 102   cmp   r0, r4
 103   beq   _SetupPrimaryCoreStack
 104
 105 _SetupSecondaryCoreStack
 106   // Base of the stack for the secondary cores is in r7
 107
 108   // Get the position of the cores (ClusterId * 4) + CoreId
 109   GetCorePositionInStack(r0, r5, r4)
 110   // The stack starts at the top of the stack region. Add '1' to the Core Position to get the top of the stack
 111   add   r0, r0, #1
 112   // Get the offset for the Secondary Stack
 113   mul   r0, r0, r3
 114   add   sp, r7, r0
 115
 116   bne   _PrepareArguments
 117
 118 _SetupPrimaryCoreStack
 119   // The top of the Mpcore Stacks is in r1
 120   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r2)
 121
 122   // The reserved space for global variable must be 8-bytes aligned for pushing
 123   // 64-bit variable on the stack
 124   SetPrimaryStack (r1, r2, r3)
 125
 126 _SetGlobals
 127   // Set all the PrePi global variables to 0
 128   mov   r3, sp
 129   mov   r2, #0x0
 130 _InitGlobals
 131   str   r2, [r3], #4
 132   cmp   r3, r1
 133   blt   _InitGlobals
 134
 135
 136 _PrepareArguments
 137   // Move sec startup address into a data register
 138   // Ensure we're jumping to FV version of the code (not boot remapped alias)
 139   ldr   r2, StartupAddr
 140
 141   // Jump to PrePiCore C code
 142   //    r0 = MpId
 143   //    r1 = UefiMemoryBase
 144   blx   r2
 145
 146 _NeverReturn
 147   b _NeverReturn
 148
 149 _SetupUnicoreStack
 150   // The top of the Unicore Stack is in r1
 151   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r2)
 152   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r3)
 153
 154   // Calculate the bottom of the primary stack (StackBase)
 155   sub   r7, r1, r3
 156
 157   // The reserved space for global variable must be 8-bytes aligned for pushing
 158   // 64-bit variable on the stack
 159   SetPrimaryStack (r1, r2, r3)
 160
 161   b _SetGlobals
 162
 163   END