ArmPlatformPkg/Sec/AArch64/Helper.S

   1 #========================================================================================
   2 #  Copyright (c) 2011-2013, ARM Limited. All rights reserved.
   3 #
   4 #  This program and the accompanying materials
   5 #  are licensed and made available under the terms and conditions of the BSD License
   6 #  which accompanies this distribution.  The full text of the license may be found at
   7 #  http:#opensource.org/licenses/bsd-license.php
   8 #
   9 #  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 #  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 #
  12 #=======================================================================================
  13
  14 #include <AsmMacroIoLibV8.h>
  15 #include <Chipset/AArch64.h>
  16
  17 #start of the code section
  18 .text
  19 .align 3
  20
  21 GCC_ASM_EXPORT(SwitchToNSExceptionLevel1)
  22 GCC_ASM_EXPORT(enter_monitor_mode)
  23 GCC_ASM_EXPORT(return_from_exception)
  24 GCC_ASM_EXPORT(copy_cpsr_into_spsr)
  25 GCC_ASM_EXPORT(set_non_secure_mode)
  26
  27 // Switch from EL3 to NS-EL1
  28 ASM_PFX(SwitchToNSExceptionLevel1):
  29    // Now setup our EL1. Controlled by EL2 config on Model
  30    mrs     x0, hcr_el2            // Read EL2 Hypervisor configuration Register
  31    orr     x0, x0, #(1 << 31)     // Set EL1 to be 64bit
  32
  33    // Send all interrupts to their respective Exception levels for EL2
  34    bic     x0, x0, #(1 << 3)      // Disable virtual FIQ
  35    bic     x0, x0, #(1 << 4)      // Disable virtual IRQ
  36    bic     x0, x0, #(1 << 5)      // Disable virtual SError and Abort
  37    msr     hcr_el2, x0            // Write back our settings
  38
  39    msr     cptr_el2, xzr          // Disable copro traps to EL2
  40
  41    msr     sctlr_el2, xzr
  42
  43    // Enable architected timer access
  44    mrs     x0, cnthctl_el2
  45    orr     x0, x0, #3             // Enable EL1 access to timers
  46    msr     cnthctl_el2, x0
  47
  48    mrs     x0, cntkctl_el1
  49    orr     x0, x0, #3             // EL0 access to counters
  50    msr     cntkctl_el1, x0
  51
  52    // Set ID regs
  53    mrs     x0, midr_el1
  54    mrs     x1, mpidr_el1
  55    msr     vpidr_el2, x0
  56    msr     vmpidr_el2, x1
  57
  58    ret
  59
  60
  61 // EL3 on AArch64 is Secure/monitor so this funtion is reduced vs ARMv7
  62 // we don't need a mode switch, just setup the Arguments and jump.
  63 // x0: Monitor World EntryPoint
  64 // x1: MpId
  65 // x2: SecBootMode
  66 // x3: Secure Monitor mode stack
  67 ASM_PFX(enter_monitor_mode):
  68    mov     x4, x0                 // Swap EntryPoint and MpId registers
  69    mov     x0, x1
  70    mov     x1, x2
  71    mov     x2, x3
  72    br      x4
  73
  74 // Put the address in correct ELR_ELx and do a eret.
  75 // We may need to do some config before we change to another Mode.
  76 ASM_PFX(return_from_exception):
  77    msr     elr_el3, x0
  78    eret
  79
  80 // For AArch64 we need to construct the spsr we want from individual bits and pieces.
  81 ASM_PFX(copy_cpsr_into_spsr):
  82    mrs     x0, CurrentEl  // Get the current exception level we  are running at.
  83    mrs     x1, SPSel      // Which Stack are we using
  84    orr     x0, x0, x1
  85    mrs     x1, daif       // Which interrupts are enabled
  86    orr     x0, x0, x1
  87    msr     spsr_el3, x0   // Write to spsr
  88    ret
  89
  90 // Get this from platform file.
  91 ASM_PFX(set_non_secure_mode):
  92    msr     spsr_el3, x0
  93    ret
  94
  95 ASM_FUNCTION_REMOVE_IF_UNREFERENCED