ArmPlatformPkg/Sec/Helper.asm

   1 //
   2 //  Copyright (c) 2011, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14     EXPORT  monitor_vector_table
  15     EXPORT  return_from_exception
  16     EXPORT  enter_monitor_mode
  17     EXPORT  copy_cpsr_into_spsr
  18     EXPORT  set_non_secure_mode
  19
  20     AREA   Helper, CODE, READONLY
  21
  22     ALIGN 32
  23 monitor_vector_table
  24     ldr pc, dead
  25     ldr pc, dead
  26     ldr pc, dead
  27     ldr pc, dead
  28     ldr pc, dead
  29     ldr pc, dead
  30     ldr pc, dead
  31     ldr pc, dead
  32
  33 // arg0: Secure Monitor mode stack
  34 enter_monitor_mode
  35     mov     r2, lr                      // Save current lr
  36
  37     mrs     r1, cpsr                    // Save current mode (SVC) in r1
  38     bic     r3, r1, #0x1f               // Clear all mode bits
  39     orr     r3, r3, #0x16               // Set bits for Monitor mode
  40     msr     cpsr_cxsf, r3               // We are now in Monitor Mode
  41
  42     mov     sp, r0                      // Use the passed sp
  43     mov     lr, r2                      // Use the same lr as before
  44
  45     msr     spsr_cxsf, r1               // Use saved mode for the MOVS jump to the kernel
  46     bx      lr
  47
  48 // We cannot use the instruction 'movs pc, lr' because the caller can be written either in ARM or Thumb2 assembler.
  49 // When we will jump into this function, we will set the CPSR flag to ARM assembler. By copying directly 'lr' into
  50 // 'pc'; we will not change the CPSR flag and it will crash.
  51 // The way to fix this limitation is to do the movs into the ARM assmbler code and then do a 'bx'.
  52 return_from_exception
  53     adr     lr, returned_exception
  54     movs    pc, lr
  55 returned_exception                           // We are now in non-secure state
  56     bx      r0
  57
  58 // Save the current Program Status Register (PSR) into the Saved PSR
  59 copy_cpsr_into_spsr
  60     mrs     r0, cpsr
  61     msr     spsr_cxsf, r0
  62     bx      lr
  63
  64 // Set the Non Secure Mode
  65 set_non_secure_mode
  66     push    { r1 }
  67     and     r0, r0, #0x1f     // Keep only the mode bits
  68     mrs     r1, spsr          // Read the spsr
  69     bic     r1, r1, #0x1f     // Clear all mode bits
  70     orr     r1, r1, r0
  71     msr     spsr_cxsf, r1     // write back spsr (may have caused a mode switch)
  72     isb
  73     pop     { r1 }
  74     bx      lr                // return (hopefully thumb-safe!)
  75
  76 dead
  77     B       dead
  78
  79     END