ArmPlatformPkg/Sec/SecEntryPoint.asm

   1 //
   2 //  Copyright (c) 2011-2012, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AutoGen.h>
  15 #include <AsmMacroIoLib.h>
  16 #include "SecInternal.h"
  17
  18   INCLUDE AsmMacroIoLib.inc
  19
  20   IMPORT  CEntryPoint
  21   IMPORT  ArmPlatformSecBootAction
  22   IMPORT  ArmPlatformInitializeBootMemory
  23   IMPORT  ArmDisableInterrupts
  24   IMPORT  ArmDisableCachesAndMmu
  25   IMPORT  ArmWriteVBar
  26   IMPORT  ArmReadMpidr
  27   IMPORT  ArmCallWFE
  28   IMPORT  SecVectorTable
  29   EXPORT  _ModuleEntryPoint
  30
  31   PRESERVE8
  32   AREA    SecEntryPoint, CODE, READONLY
  33
  34 StartupAddr        DCD      CEntryPoint
  35
  36 _ModuleEntryPoint
  37   // First ensure all interrupts are disabled
  38   blx   ArmDisableInterrupts
  39
  40   // Ensure that the MMU and caches are off
  41   blx   ArmDisableCachesAndMmu
  42
  43   // Jump to Platform Specific Boot Action function
  44   blx   ArmPlatformSecBootAction
  45
  46   // Set VBAR to the start of the exception vectors in Secure Mode
  47   ldr   r0, =SecVectorTable
  48   blx   ArmWriteVBar
  49
  50 _IdentifyCpu
  51   // Identify CPU ID
  52   bl    ArmReadMpidr
  53   // Get ID of this CPU in Multicore system
  54   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)
  55   and   r5, r0, r1
  56
  57   // Is it the Primary Core ?
  58   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r3)
  59   cmp   r5, r3
  60   // Only the primary core initialize the memory (SMC)
  61   beq   _InitMem
  62
  63 _WaitInitMem
  64   // Wait for the primary core to initialize the initial memory (event: BOOT_MEM_INIT)
  65   bl    ArmCallWFE
  66   // Now the Init Mem is initialized, we setup the secondary core stacks
  67   b     _SetupSecondaryCoreStack
  68
  69 _InitMem
  70   // Initialize Init Boot Memory
  71   bl    ArmPlatformInitializeBootMemory
  72
  73   // Only Primary CPU could run this line (the secondary cores have jumped from _IdentifyCpu to _SetupStack)
  74   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r5)
  75
  76 _SetupPrimaryCoreStack
  77   // Get the top of the primary stacks (and the base of the secondary stacks)
  78   LoadConstantToReg (FixedPcdGet32(PcdCPUCoresSecStackBase), r1)
  79   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecPrimaryStackSize), r2)
  80   add   r1, r1, r2
  81
  82   LoadConstantToReg (FixedPcdGet32(PcdSecGlobalVariableSize), r2)
  83
  84   // The reserved space for global variable must be 8-bytes aligned for pushing
  85   // 64-bit variable on the stack
  86   SetPrimaryStack (r1, r2, r3)
  87   b     _PrepareArguments
  88
  89 _SetupSecondaryCoreStack
  90   // Get the top of the primary stacks (and the base of the secondary stacks)
  91   LoadConstantToReg (FixedPcdGet32(PcdCPUCoresSecStackBase), r1)
  92   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecPrimaryStackSize), r2)
  93   add   r1, r1, r2
  94
  95   // Get the Core Position (ClusterId * 4) + CoreId
  96   GetCorePositionInStack(r0, r5, r2)
  97   // The stack starts at the top of the stack region. Add '1' to the Core Position to get the top of the stack
  98   add   r0, r0, #1
  99
 100   // StackOffset = CorePos * StackSize
 101   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecSecondaryStackSize), r2)
 102   mul   r0, r0, r2
 103   // SP = StackBase + StackOffset
 104   add   sp, r1, r0
 105
 106 _PrepareArguments
 107   // Move sec startup address into a data register
 108   // Ensure we're jumping to FV version of the code (not boot remapped alias)
 109   ldr   r3, StartupAddr
 110
 111   // Jump to SEC C code
 112   //    r0 = mp_id
 113   mov   r0, r5
 114   blx   r3
 115
 116 _NeverReturn
 117   b _NeverReturn
 118   END