ArmVirtPkg/PrePi/AArch64/ModuleEntryPoint.S

   1 //
   2 //  Copyright (c) 2011-2013, ARM Limited. All rights reserved.
   3 //  Copyright (c) 2015-2016, Linaro Limited. All rights reserved.
   4 //
   5 //  This program and the accompanying materials
   6 //  are licensed and made available under the terms and conditions of the BSD License
   7 //  which accompanies this distribution.  The full text of the license may be found at
   8 //  http://opensource.org/licenses/bsd-license.php
   9 //
  10 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 //
  13 //
  14
  15 #include <AsmMacroIoLibV8.h>
  16
  17 ASM_GLOBAL ASM_PFX(mSystemMemoryEnd)
  18
  19 ASM_FUNC(_ModuleEntryPoint)
  20   //
  21   // We are built as a ET_DYN PIE executable, so we need to process all
  22   // relative relocations regardless of whether or not we are executing from
  23   // the same offset we were linked at. This is only possible if we are
  24   // running from RAM.
  25   //
  26   adr   x8, __reloc_base
  27   adr   x9, __reloc_start
  28   adr   x10, __reloc_end
  29
  30 .Lreloc_loop:
  31   cmp   x9, x10
  32   bhs   .Lreloc_done
  33
  34   //
  35   // AArch64 uses the ELF64 RELA format, which means each entry in the
  36   // relocation table consists of
  37   //
  38   //   UINT64 offset          : the relative offset of the value that needs to
  39   //                            be relocated
  40   //   UINT64 info            : relocation type and symbol index (the latter is
  41   //                            not used for R_AARCH64_RELATIVE relocations)
  42   //   UINT64 addend          : value to be added to the value being relocated
  43   //
  44   ldp   x11, x12, [x9], #24   // read offset into x11 and info into x12
  45   cmp   x12, #0x403           // check info == R_AARCH64_RELATIVE?
  46   bne   .Lreloc_loop          // not a relative relocation? then skip
  47
  48   ldr   x12, [x9, #-8]        // read addend into x12
  49   add   x12, x12, x8          // add reloc base to addend to get relocated value
  50   str   x12, [x11, x8]        // write relocated value at offset
  51   b     .Lreloc_loop
  52 .Lreloc_done:
  53
  54   // Do early platform specific actions
  55   bl    ASM_PFX(ArmPlatformPeiBootAction)
  56
  57   // Get ID of this CPU in Multicore system
  58   bl    ASM_PFX(ArmReadMpidr)
  59   // Keep a copy of the MpId register value
  60   mov   x20, x0
  61
  62 // Check if we can install the stack at the top of the System Memory or if we need
  63 // to install the stacks at the bottom of the Firmware Device (case the FD is located
  64 // at the top of the DRAM)
  65 _SetupStackPosition:
  66   // Compute Top of System Memory
  67   ldr   x1, PcdGet64 (PcdSystemMemoryBase)
  68   ldr   x2, PcdGet64 (PcdSystemMemorySize)
  69   sub   x2, x2, #1
  70   add   x1, x1, x2      // x1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize
  71   adr   x2, mSystemMemoryEnd
  72   str   x1, [x2]
  73
  74   // Calculate Top of the Firmware Device
  75   ldr   x2, PcdGet64 (PcdFdBaseAddress)
  76   MOV32 (w3, FixedPcdGet32 (PcdFdSize) - 1)
  77   add   x3, x3, x2      // x3 = FdTop = PcdFdBaseAddress + PcdFdSize
  78
  79   // UEFI Memory Size (stacks are allocated in this region)
  80   MOV32 (x4, FixedPcdGet32(PcdSystemMemoryUefiRegionSize))
  81
  82   //
  83   // Reserve the memory for the UEFI region (contain stacks on its top)
  84   //
  85
  86   // Calculate how much space there is between the top of the Firmware and the Top of the System Memory
  87   subs  x0, x1, x3   // x0 = SystemMemoryTop - FdTop
  88   b.mi  _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM
  89   cmp   x0, x4
  90   b.ge  _SetupStack
  91
  92   // Case the top of stacks is the FdBaseAddress
  93   mov   x1, x2
  94
  95 _SetupStack:
  96   // x1 contains the top of the stack (and the UEFI Memory)
  97
  98   // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment
  99   // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the
 100   // top of the memory space)
 101   adds  x21, x1, #1
 102   b.cs  _SetupOverflowStack
 103
 104 _SetupAlignedStack:
 105   mov   x1, x21
 106   b     _GetBaseUefiMemory
 107
 108 _SetupOverflowStack:
 109   // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE
 110   // aligned (4KB)
 111   and   x1, x1, ~EFI_PAGE_MASK
 112
 113 _GetBaseUefiMemory:
 114   // Calculate the Base of the UEFI Memory
 115   sub   x21, x1, x4
 116
 117 _GetStackBase:
 118   // r1 = The top of the Mpcore Stacks
 119   // Stack for the primary core = PrimaryCoreStack
 120   MOV32 (x2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))
 121   sub   x22, x1, x2
 122
 123   // Stack for the secondary core = Number of Cores - 1
 124   MOV32 (x1, (FixedPcdGet32(PcdCoreCount) - 1) * FixedPcdGet32(PcdCPUCoreSecondaryStackSize))
 125   sub   x22, x22, x1
 126
 127   // x22 = The base of the MpCore Stacks (primary stack & secondary stacks)
 128   mov   x0, x22
 129   mov   x1, x20
 130   //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)
 131   MOV32 (x2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))
 132   MOV32 (x3, FixedPcdGet32(PcdCPUCoreSecondaryStackSize))
 133   bl    ASM_PFX(ArmPlatformStackSet)
 134
 135   // Is it the Primary Core ?
 136   mov   x0, x10
 137   bl    ASM_PFX(ArmPlatformIsPrimaryCore)
 138   cmp   x0, #1
 139   bne   _PrepareArguments
 140
 141 _PrepareArguments:
 142   mov   x0, x20
 143   mov   x1, x21
 144   mov   x2, x22
 145
 146   // Jump to PrePiCore C code
 147   //    x0 = MpId
 148   //    x1 = UefiMemoryBase
 149   //    x2 = StacksBase
 150   bl    ASM_PFX(CEntryPoint)
 151
 152 _NeverReturn:
 153   b _NeverReturn
 154
 155 ASM_PFX(mSystemMemoryEnd):    .8byte 0