BeagleBoardPkg/Sec/Arm/ModuleEntryPoint.S

   1 #------------------------------------------------------------------------------
   2 #
   3 # Copyright (c) 2008-2009 Apple Inc. All rights reserved.
   4 #
   5 # All rights reserved. This program and the accompanying materials
   6 # are licensed and made available under the terms and conditions of the BSD License
   7 # which accompanies this distribution.  The full text of the license may be found at
   8 # http://opensource.org/licenses/bsd-license.php
   9 #
  10 # THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 #
  13 #------------------------------------------------------------------------------
  14
  15 #include <AsmMacroIoLib.h>
  16 #include <Library/PcdLib.h>
  17
  18 .text
  19 .align 3
  20
  21 .globl ASM_PFX(CEntryPoint)
  22 .globl ASM_PFX(_ModuleEntryPoint)
  23
  24 ASM_PFX(_ModuleEntryPoint):
  25
  26   //Disable L2 cache
  27   mrc     p15, 0, r0, c1, c0, 1   // read Auxiliary Control Register
  28   bic     r0, r0, #0x00000002     // disable L2 cache
  29   mcr     p15, 0, r0, c1, c0, 1   // store Auxiliary Control Register
  30
  31   //Enable Strict alignment checking & Instruction cache
  32   mrc     p15, 0, r0, c1, c0, 0
  33   bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
  34   bic     r0, r0, #0x00000005     /* clear bits 0, 2 (---- -C-M) */
  35   orr     r0, r0, #0x00000002     /* set bit 1 (A) Align */
  36   orr     r0, r0, #0x00001000     /* set bit 12 (I) enable I-Cache */
  37   mcr     p15, 0, r0, c1, c0, 0
  38
  39   // Set CPU vectors to start of DRAM
  40   LoadConstantToReg (FixedPcdGet32(PcdCpuVectorBaseAddress) ,r0) // Get vector base
  41   mcr     p15, 0, r0, c12, c0, 0
  42   isb                               // Sync changes to control registers
  43
  44   // Fill vector table with branchs to current pc (jmp $)
  45   ldr     r1, ShouldNeverGetHere
  46   movs    r2, #0
  47 FillVectors:
  48   str     r1, [r0, r2]
  49   adds    r2, r2, #4
  50   cmp     r2, #32
  51   bne     FillVectors
  52
  53   /* before we call C code, lets setup the stack pointer in internal RAM */
  54 stack_pointer_setup:
  55
  56   //
  57   // Set stack based on PCD values. Need to do it this way to make C code work
  58   // when it runs from FLASH.
  59   //
  60   LoadConstantToReg (FixedPcdGet32(PcdPrePiStackBase) ,r2)    /* stack base arg2  */
  61   LoadConstantToReg (FixedPcdGet32(PcdPrePiStackSize) ,r3)    /* stack size arg3  */
  62   add     r4, r2, r3
  63
  64   //Enter SVC mode and set up SVC stack pointer
  65   mov     r0,#0x13|0x80|0x40
  66   msr     CPSR_c,r0
  67   mov     r13,r4
  68
  69   // Call C entry point
  70   LoadConstantToReg (FixedPcdGet32(PcdMemorySize) ,r1)    /* memory size arg1          */
  71   LoadConstantToReg (FixedPcdGet32(PcdMemoryBase) ,r0)    /* memory size arg0         */
  72   blx      ASM_PFX(CEntryPoint) /* Assume C code is thumb    */
  73
  74 ShouldNeverGetHere:
  75   /* _CEntryPoint should never return */
  76   b       ShouldNeverGetHere
  77