BeagleBoardPkg/Sec/Arm/ModuleEntryPoint.asm

   1 //------------------------------------------------------------------------------
   2 //
   3 // Copyright (c) 2008-2009 Apple Inc. All rights reserved.
   4 //
   5 // All rights reserved. This program and the accompanying materials
   6 // are licensed and made available under the terms and conditions of the BSD License
   7 // which accompanies this distribution.  The full text of the license may be found at
   8 // http://opensource.org/licenses/bsd-license.php
   9 //
  10 // THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 // WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 //
  13 //------------------------------------------------------------------------------
  14
  15 #include <AsmMacroIoLib.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18   INCLUDE AsmMacroIoLib.inc
  19
  20   IMPORT  CEntryPoint
  21   EXPORT  _ModuleEntryPoint
  22
  23   PRESERVE8
  24   AREA    ModuleEntryPoint, CODE, READONLY
  25
  26
  27 _ModuleEntryPoint
  28
  29   //Disable L2 cache
  30   mrc     p15, 0, r0, c1, c0, 1   // read Auxiliary Control Register
  31   bic     r0, r0, #0x00000002     // disable L2 cache
  32   mcr     p15, 0, r0, c1, c0, 1   // store Auxiliary Control Register
  33
  34   //Enable Strict alignment checking & Instruction cache
  35   mrc     p15, 0, r0, c1, c0, 0
  36   bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
  37   bic     r0, r0, #0x00000005     /* clear bits 0, 2 (---- -C-M) */
  38   orr     r0, r0, #0x00000002     /* set bit 1 (A) Align */
  39   orr     r0, r0, #0x00001000     /* set bit 12 (I) enable I-Cache */
  40   mcr     p15, 0, r0, c1, c0, 0
  41
  42   // Set CPU vectors to start of DRAM
  43   mov     r0, #0x80000000
  44   mcr     p15, 0, r0, c12, c0, 0
  45   /* before we call C code, lets setup the stack pointer in internal RAM*/
  46 stack_pointer_setup
  47
  48   //
  49   // Set stack based on PCD values. Need to do it this way to make C code work
  50   // when it runs from FLASH.
  51   //
  52   LoadConstantToReg (FixedPcdGet32(PcdPrePiStackBase) ,r2)    /* stack base arg2  */
  53   LoadConstantToReg (FixedPcdGet32(PcdPrePiStackSize) ,r3)    /* stack size arg3  */
  54   add     r4, r2, r3
  55
  56   //Enter IRQ mode and set up IRQ stack pointer
  57   mov     r0,#0x12|0x80|0x40
  58   msr     CPSR_c,r0
  59   mov     r13,r4
  60
  61   //Enter Abort mode and set up Abort stack pointer
  62   mov     r0,#0x17|0x80|0x40
  63   msr     CPSR_c,r0
  64   sub     r4, r4, #0x400
  65   mov     r13,r4
  66
  67   //Enter Undefined mode and set up Undefined stack pointer
  68   mov     r0,#0x1b|0x80|0x40
  69   msr     CPSR_c,r0
  70   sub     r4, r4, #0x400
  71   mov     r13,r4
  72
  73   //Enter SVC mode and set up SVC stack pointer
  74   mov     r0,#0x13|0x80|0x40
  75   msr     CPSR_c,r0
  76   sub     r4, r4, #0x400
  77   mov     r13,r4
  78
  79   //Enter System mode and set up System stack pointer
  80   mov     r0,#0x1f|0x80|0x40
  81   msr     CPSR_c,r0
  82   sub     r4, r4, #0x400
  83   mov     r13,r4
  84
  85   // Call C entry point
  86   mov     r0, #0x80000000   /* memory base arg0          */
  87   mov     r1, #0x08000000   /* memory size arg1          */
  88   blx     CEntryPoint       /* Assume C code is thumb    */
  89
  90 ShouldNeverGetHere
  91   /* _CEntryPoint should never return */
  92   b       ShouldNeverGetHere
  93
  94   END
  95