CryptoPkg/Library/OpensslLib/process_files.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # This script runs the OpenSSL Configure script, then processes the
   4 # resulting file list into our local OpensslLib[Crypto].inf and also
   5 # takes a copy of opensslconf.h.
   6 #
   7 # This only needs to be done once by a developer when updating to a
   8 # new version of OpenSSL (or changing options, etc.). Normal users
   9 # do not need to do this, since the results are stored in the EDK2
  10 # git repository for them.
  11 #
  12 use strict;
  13 use Cwd;
  14 use File::Copy;
  15
  16 #
  17 # Find the openssl directory name for use lib. We have to do this
  18 # inside of BEGIN. The variables we create here, however, don't seem
  19 # to be available to the main script, so we have to repeat the
  20 # exercise.
  21 #
  22 my $inf_file;
  23 my $OPENSSL_PATH;
  24 my @inf;
  25
  26 BEGIN {
  27     $inf_file = "OpensslLib.inf";
  28
  29     # Read the contents of the inf file
  30     open( FD, "<" . $inf_file ) ||
  31         die "Cannot open \"" . $inf_file . "\"!";
  32     @inf = (<FD>);
  33     close(FD) ||
  34         die "Cannot close \"" . $inf_file . "\"!";
  35
  36     foreach (@inf) {
  37         if (/DEFINE\s+OPENSSL_PATH\s*=\s*([a-z]+)/) {
  38
  39             # We need to run Configure before we can include its result...
  40             $OPENSSL_PATH = $1;
  41
  42             my $basedir = getcwd();
  43
  44             chdir($OPENSSL_PATH) ||
  45                 die "Cannot change to OpenSSL directory \"" . $OPENSSL_PATH . "\"";
  46
  47             # Configure UEFI
  48             system(
  49                 "./Configure",
  50                 "UEFI",
  51                 "no-afalgeng",
  52                 "no-asm",
  53                 "no-async",
  54                 "no-autoalginit",
  55                 "no-autoerrinit",
  56                 "no-bf",
  57                 "no-blake2",
  58                 "no-camellia",
  59                 "no-capieng",
  60                 "no-cast",
  61                 "no-chacha",
  62                 "no-cms",
  63                 "no-ct",
  64                 "no-deprecated",
  65                 "no-dgram",
  66                 "no-dsa",
  67                 "no-dynamic-engine",
  68                 "no-ec",
  69                 "no-ec2m",
  70                 "no-engine",
  71                 "no-err",
  72                 "no-filenames",
  73                 "no-gost",
  74                 "no-hw",
  75                 "no-idea",
  76                 "no-mdc2",
  77                 "no-pic",
  78                 "no-ocb",
  79                 "no-poly1305",
  80                 "no-posix-io",
  81                 "no-rc2",
  82                 "no-rfc3779",
  83                 "no-rmd160",
  84                 "no-scrypt",
  85                 "no-seed",
  86                 "no-sock",
  87                 "no-srp",
  88                 "no-ssl",
  89                 "no-stdio",
  90                 "no-threads",
  91                 "no-ts",
  92                 "no-ui",
  93                 "no-whirlpool",
  94                 # OpenSSL1_1_1b doesn't support default rand-seed-os for UEFI
  95                 # UEFI only support --with-rand-seed=none
  96                 "--with-rand-seed=none"
  97                 ) == 0 ||
  98                     die "OpenSSL Configure failed!\n";
  99
 100             # Generate opensslconf.h per config data
 101             system(
 102                 "perl -I. -Mconfigdata util/dofile.pl " .
 103                 "include/openssl/opensslconf.h.in " .
 104                 "> include/openssl/opensslconf.h"
 105                 ) == 0 ||
 106                     die "Failed to generate opensslconf.h!\n";
 107
 108             chdir($basedir) ||
 109                 die "Cannot change to base directory \"" . $basedir . "\"";
 110
 111             push @INC, $1;
 112             last;
 113         }
 114     }
 115 }
 116
 117 #
 118 # Retrieve file lists from OpenSSL configdata
 119 #
 120 use configdata qw/%unified_info/;
 121
 122 my @cryptofilelist = ();
 123 my @sslfilelist = ();
 124 foreach my $product ((@{$unified_info{libraries}},
 125                       @{$unified_info{engines}})) {
 126     foreach my $o (@{$unified_info{sources}->{$product}}) {
 127         foreach my $s (@{$unified_info{sources}->{$o}}) {
 128             next if ($unified_info{generate}->{$s});
 129             next if $s =~ "crypto/bio/b_print.c";
 130
 131             # No need to add unused files in UEFI.
 132             # So it can reduce porting time, compile time, library size.
 133             next if $s =~ "crypto/rand/randfile.c";
 134             next if $s =~ "crypto/store/";
 135
 136             if ($product =~ "libssl") {
 137                 push @sslfilelist, '  $(OPENSSL_PATH)/' . $s . "\r\n";
 138                 next;
 139             }
 140             push @cryptofilelist, '  $(OPENSSL_PATH)/' . $s . "\r\n";
 141         }
 142     }
 143 }
 144
 145 #
 146 # Update OpensslLib.inf with autogenerated file list
 147 #
 148 my @new_inf = ();
 149 my $subbing = 0;
 150 print "\n--> Updating OpensslLib.inf ... ";
 151 foreach (@inf) {
 152     if ( $_ =~ "# Autogenerated files list starts here" ) {
 153         push @new_inf, $_, @cryptofilelist, @sslfilelist;
 154         $subbing = 1;
 155         next;
 156     }
 157     if ( $_ =~ "# Autogenerated files list ends here" ) {
 158         push @new_inf, $_;
 159         $subbing = 0;
 160         next;
 161     }
 162
 163     push @new_inf, $_
 164         unless ($subbing);
 165 }
 166
 167 my $new_inf_file = $inf_file . ".new";
 168 open( FD, ">" . $new_inf_file ) ||
 169     die $new_inf_file;
 170 print( FD @new_inf ) ||
 171     die $new_inf_file;
 172 close(FD) ||
 173     die $new_inf_file;
 174 rename( $new_inf_file, $inf_file ) ||
 175     die "rename $inf_file";
 176 print "Done!";
 177
 178 #
 179 # Update OpensslLibCrypto.inf with auto-generated file list (no libssl)
 180 #
 181 $inf_file = "OpensslLibCrypto.inf";
 182
 183 # Read the contents of the inf file
 184 @inf = ();
 185 @new_inf = ();
 186 open( FD, "<" . $inf_file ) ||
 187     die "Cannot open \"" . $inf_file . "\"!";
 188 @inf = (<FD>);
 189 close(FD) ||
 190     die "Cannot close \"" . $inf_file . "\"!";
 191
 192 $subbing = 0;
 193 print "\n--> Updating OpensslLibCrypto.inf ... ";
 194 foreach (@inf) {
 195     if ( $_ =~ "# Autogenerated files list starts here" ) {
 196         push @new_inf, $_, @cryptofilelist;
 197         $subbing = 1;
 198         next;
 199     }
 200     if ( $_ =~ "# Autogenerated files list ends here" ) {
 201         push @new_inf, $_;
 202         $subbing = 0;
 203         next;
 204     }
 205
 206     push @new_inf, $_
 207         unless ($subbing);
 208 }
 209
 210 $new_inf_file = $inf_file . ".new";
 211 open( FD, ">" . $new_inf_file ) ||
 212     die $new_inf_file;
 213 print( FD @new_inf ) ||
 214     die $new_inf_file;
 215 close(FD) ||
 216     die $new_inf_file;
 217 rename( $new_inf_file, $inf_file ) ||
 218     die "rename $inf_file";
 219 print "Done!";
 220
 221 #
 222 # Copy opensslconf.h generated from OpenSSL Configuration
 223 #
 224 print "\n--> Duplicating opensslconf.h into Include/openssl ... ";
 225 copy($OPENSSL_PATH . "/include/openssl/opensslconf.h",
 226      $OPENSSL_PATH . "/../../Include/openssl/") ||
 227    die "Cannot copy opensslconf.h!";
 228 print "Done!\n";
 229
 230 print "\nProcessing Files Done!\n";
 231
 232 exit(0);
 233