EdkCompatibilityPkg/Compatibility/MpServicesOnFrameworkMpServicesThunk/X64/MpFuncs.S

   1 #------------------------------------------------------------------------------
   2 # X64 assembly file for AP startup vector.
   3 #
   4 # Copyright (c) 2009, Intel Corporation
   5 # All rights reserved. This program and the accompanying materials
   6 # are licensed and made available under the terms and conditions of the BSD License
   7 # which accompanies this distribution.  The full text of the license may be found at
   8 # http://opensource.org/licenses/bsd-license.php
   9 #
  10 # THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 #
  13 #------------------------------------------------------------------------------
  14
  15
  16 .equ                   VacantFlag,       0x0
  17 .equ                   NotVacantFlag,    0xff
  18
  19 .equ                   LockLocation,              RendezvousFunnelProcEnd - RendezvousFunnelProcStart
  20 .equ                   StackStartAddressLocation, RendezvousFunnelProcEnd - RendezvousFunnelProcStart + 0x08
  21 .equ                   StackSizeLocation,         RendezvousFunnelProcEnd - RendezvousFunnelProcStart + 0x10
  22 .equ                   CProcedureLocation,        RendezvousFunnelProcEnd - RendezvousFunnelProcStart + 0x18
  23 .equ                   GdtrLocation,              RendezvousFunnelProcEnd - RendezvousFunnelProcStart + 0x20
  24 .equ                   BufferStartLocation,       RendezvousFunnelProcEnd - RendezvousFunnelProcStart + 0x2C
  25 .equ                   Cr3OffsetLocation,         RendezvousFunnelProcEnd - RendezvousFunnelProcStart + 0x30
  26
  27 #-------------------------------------------------------------------------------------
  28
  29 #-------------------------------------------------------------------------------------
  30 #RendezvousFunnelProc  procedure follows. All APs execute their procedure. This
  31 #procedure serializes all the AP processors through an Init sequence. It must be
  32 #noted that APs arrive here very raw...ie: real mode, no stack.
  33 #ALSO THIS PROCEDURE IS EXECUTED BY APs ONLY ON 16 BIT MODE. HENCE THIS PROC
  34 #IS IN MACHINE CODE.
  35 #-------------------------------------------------------------------------------------
  36 #RendezvousFunnelProc (&WakeUpBuffer,MemAddress);
  37
  38 .text
  39
  40 ASM_GLOBAL ASM_PFX(RendezvousFunnelProc)
  41 ASM_PFX(RendezvousFunnelProc):
  42 RendezvousFunnelProcStart:
  43
  44 # At this point CS = 0x(vv00) and ip= 0x0.
  45
  46         .byte 0x8c,0xc8               # mov        ax,  cs
  47         .byte 0x8e,0xd8               # mov        ds,  ax
  48         .byte 0x8e,0xc0               # mov        es,  ax
  49         .byte 0x8e,0xd0               # mov        ss,  ax
  50         .byte 0x33,0xc0               # xor        ax,  ax
  51         .byte 0x8e,0xe0               # mov        fs,  ax
  52         .byte 0x8e,0xe8               # mov        gs,  ax
  53
  54 # Switch to flat mode.
  55
  56         .byte 0xBE
  57         .word BufferStartLocation
  58         .byte 0x66,0x8B,0x14          # mov        edx,dword ptr [si]          ; EDX is keeping the start address of wakeup buffer
  59
  60         .byte 0xBE
  61         .word Cr3OffsetLocation
  62         .byte 0x66,0x8B,0xC           # mov        ecx,dword ptr [si]          ; ECX is keeping the value of CR3
  63
  64         .byte 0xBE
  65         .word GdtrLocation
  66         .byte 0x66                    # db         66h
  67         .byte 0x2E,0xF,0x1,0x14       # lgdt       fword ptr cs:[si]
  68
  69         .byte 0x33,0xC0               # xor        ax,  ax
  70         .byte 0x8E,0xD8               # mov        ds,  ax
  71
  72         .byte 0xF,0x20,0xC0           # mov        eax, cr0                    ; Get control register 0
  73         .byte 0x66,0x83,0xC8,0x1      # or         eax, 000000001h             ; Set PE bit (bit #0)
  74         .byte 0xF,0x22,0xC0           # mov        cr0, eax
  75
  76 FLAT32_JUMP:
  77
  78         .byte 0x66,0x67,0xEA          # far jump
  79         .long 0x0                     # 32-bit offset
  80         .word 0x20                    # 16-bit selector
  81
  82 ProtectedModeStart:
  83
  84         .byte 0x66,0xB8,0x18,0x0      # mov        ax,  18h
  85         .byte 0x66,0x8E,0xD8          # mov        ds,  ax
  86         .byte 0x66,0x8E,0xC0          # mov        es,  ax
  87         .byte 0x66,0x8E,0xE0          # mov        fs,  ax
  88         .byte 0x66,0x8E,0xE8          # mov        gs,  ax
  89         .byte 0x66,0x8E,0xD0          # mov        ss,  ax                     ; Flat mode setup.
  90
  91         .byte 0xF,0x20,0xE0           # mov        eax, cr4
  92         .byte 0xF,0xBA,0xE8,0x5       # bts        eax, 5
  93         .byte 0xF,0x22,0xE0           # mov        cr4, eax
  94
  95         .byte 0xF,0x22,0xD9           # mov        cr3, ecx
  96
  97         .byte 0x8B,0xF2               # mov        esi, edx                    ; Save wakeup buffer address
  98
  99         .byte 0xB9
 100         .long 0xC0000080              # mov        ecx, 0c0000080h             ; EFER MSR number.
 101         .byte 0xF,0x32                # rdmsr                                  ; Read EFER.
 102         .byte 0xF,0xBA,0xE8,0x8       # bts        eax, 8                      ; Set LME=1.
 103         .byte 0xF,0x30                # wrmsr                                  ; Write EFER.
 104
 105         .byte 0xF,0x20,0xC0           # mov        eax, cr0                    ; Read CR0.
 106         .byte 0xF,0xBA,0xE8,0x1F      # bts        eax, 31                     ; Set PG=1.
 107         .byte 0xF,0x22,0xC0           # mov        cr0, eax                    ; Write CR0.
 108
 109 LONG_JUMP:
 110
 111         .byte 0x67,0xEA               # far jump
 112         .long 0x0                     # 32-bit offset
 113         .word 0x38                    # 16-bit selector
 114
 115 LongModeStart:
 116
 117         movw        $0x30,%ax
 118         .byte       0x66
 119         movw        %ax,%ds
 120         .byte       0x66
 121         movw        %ax,%es
 122         .byte       0x66
 123         movw        %ax,%ss
 124
 125         movl        %esi, %edi
 126         addl        $LockLocation, %edi
 127         movb        $NotVacantFlag, %al
 128 TestLock:
 129         xchgb       (%edi), %al
 130         cmpb        $NotVacantFlag, %al
 131         jz          TestLock
 132
 133 ProgramStack:
 134
 135         movl        %esi, %edi
 136         addl        $StackSizeLocation, %edi
 137         movq        (%edi), %rax
 138         movl        %esi, %edi
 139         addl        $StackStartAddressLocation, %edi
 140         addq        (%edi), %rax
 141         movq        %rax, %rsp
 142         movq        %rax, (%edi)
 143
 144 Releaselock:
 145
 146         movb        $VacantFlag, %al
 147         movl        %esi, %edi
 148         addl        $LockLocation, %edi
 149         xchgb       (%edi), %al
 150
 151         #
 152         # Call C Function
 153         #
 154         movl        %esi,%edi
 155         addl        $CProcedureLocation, %edi
 156         movq        (%edi), %rax
 157
 158         testq       %rax, %rax
 159         jz          GoToSleep
 160
 161         subq        $0x20, %rsp
 162         call        *%rax
 163         addq        $0x20, %rsp
 164
 165 GoToSleep:
 166
 167         cli
 168         hlt
 169         jmp         .-2
 170
 171 RendezvousFunnelProcEnd:
 172
 173
 174 #-------------------------------------------------------------------------------------
 175 #  AsmGetAddressMap (&AddressMap);
 176 #-------------------------------------------------------------------------------------
 177 # comments here for definition of address map
 178 ASM_GLOBAL ASM_PFX(AsmGetAddressMap)
 179 ASM_PFX(AsmGetAddressMap):
 180
 181         movq         $RendezvousFunnelProcStart, %rax
 182         movq         %rax, (%rcx)
 183         movq         $(ProtectedModeStart - RendezvousFunnelProcStart), 0x08(%rcx)
 184         movq         $(FLAT32_JUMP - RendezvousFunnelProcStart), 0x10(%rcx)
 185         movq         $(LongModeStart - RendezvousFunnelProcStart), 0x18(%rcx)
 186         movq         $(LONG_JUMP - RendezvousFunnelProcStart), 0x20(%rcx)
 187         movq         $(RendezvousFunnelProcEnd - RendezvousFunnelProcStart), 0x28(%rcx)
 188
 189         ret