EdkCompatibilityPkg/Foundation/Library/CompilerStub/X64/memsetSSE2.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   memset function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID *
  28 ; memset (
  29 ;   OUT     VOID                      *Buffer,    --> rcx
  30 ;   IN      UINT8                     Value,      --> rdx
  31 ;   IN      UINTN                     Length      --> r8
  32 ;   );
  33 ;------------------------------------------------------------------------------
  34 memset   PROC    USES    rdi
  35     mov     rax, rcx
  36     cmp     r8, 0                       ; if Size == 0, do nothing
  37     je      @SetDone
  38     mov     rax, rdx                    ; rdx <-> r8
  39     mov     rdx, r8                     ; rdx <- Length
  40     mov     r8, rax                     ; r8  <- Value
  41
  42     mov     rdi, rcx                    ; rdi <- Buffer
  43     mov     al, r8b                     ; al <- Value
  44     mov     r9, rdi                     ; r9 <- Buffer as return value
  45     xor     rcx, rcx
  46     sub     rcx, rdi
  47     and     rcx, 15                     ; rcx + rdi aligns on 16-byte boundary
  48     jz      @F
  49     cmp     rcx, rdx
  50     cmova   rcx, rdx
  51     sub     rdx, rcx
  52     rep     stosb
  53 @@:
  54     mov     rcx, rdx
  55     and     rdx, 15
  56     shr     rcx, 4
  57     jz      @SetBytes
  58     mov     ah, al                      ; ax <- Value repeats twice
  59     movd    xmm0, eax                   ; xmm0[0..16] <- Value repeats twice
  60     pshuflw xmm0, xmm0, 0               ; xmm0[0..63] <- Value repeats 8 times
  61     movlhps xmm0, xmm0                  ; xmm0 <- Value repeats 16 times
  62 @@:
  63     movdqa  [rdi], xmm0                 ; rdi should be 16-byte aligned
  64     add     rdi, 16
  65     loop    @B
  66 @SetBytes:
  67     mov     ecx, edx                    ; high 32 bits of rcx are always zero
  68     rep     stosb
  69     mov     rax, r9                     ; rax <- Return value
  70 @SetDone:
  71     ret
  72 memset   ENDP
  73
  74     END