EdkCompatibilityPkg/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/Thunk16.asm

   1 ; Copyright (c) 2004 - 2011, Intel Corporation. All rights reserved.<BR>
   2 ; This program and the accompanying materials
   3 ; are licensed and made available under the terms and conditions of the BSD License
   4 ; which accompanies this distribution.  The full text of the license may be found at
   5 ; http://opensource.org/licenses/bsd-license.php
   6 ;
   7 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
   8 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
   9 ;
  10 ; Module Name:
  11 ;
  12 ;   Thunk.asm
  13 ;
  14 ; Abstract:
  15 ;
  16 ;   Real mode thunk
  17 ;
  18 ;------------------------------------------------------------------------------
  19
  20     .686p
  21     .model  flat,C
  22
  23 EXTERNDEF   C   m16Start:BYTE
  24 EXTERNDEF   C   m16Size:WORD
  25 EXTERNDEF   C   mThunk16Attr:WORD
  26 EXTERNDEF   C   m16Gdt:WORD
  27 EXTERNDEF   C   m16GdtrBase:WORD
  28 EXTERNDEF   C   mTransition:WORD
  29
  30 THUNK_ATTRIBUTE_BIG_REAL_MODE               EQU 1
  31 THUNK_ATTRIBUTE_DISABLE_A20_MASK_INT_15     EQU 2
  32 THUNK_ATTRIBUTE_DISABLE_A20_MASK_KBD_CTRL   EQU 4
  33
  34 ;
  35 ; Here is the layout of the real mode stack. _ToUserCode() is responsible for
  36 ; loading all these registers from real mode stack.
  37 ;
  38 IA32_REGS   STRUC   4t
  39 _EDI        DD      ?
  40 _ESI        DD      ?
  41 _EBP        DD      ?
  42 _ESP        DD      ?
  43 _EBX        DD      ?
  44 _EDX        DD      ?
  45 _ECX        DD      ?
  46 _EAX        DD      ?
  47 _DS         DW      ?
  48 _ES         DW      ?
  49 _FS         DW      ?
  50 _GS         DW      ?
  51 _EFLAGS     DD      ?
  52 _EIP        DD      ?
  53 _CS         DW      ?
  54 _SS         DW      ?
  55 IA32_REGS   ENDS
  56
  57     .const
  58
  59 ;
  60 ; These are global constant to convey information to C code.
  61 ;
  62 m16Size         DW      InternalAsmThunk16 - m16Start
  63 mThunk16Attr    DW      _ThunkAttr - m16Start
  64 m16Gdt          DW      _NullSegDesc - m16Start
  65 m16GdtrBase     DW      _16GdtrBase - m16Start
  66 mTransition     DW      _EntryPoint - m16Start
  67
  68     .code
  69
  70 m16Start    LABEL   BYTE
  71
  72 SavedGdt    LABEL   FWORD
  73             DW      ?
  74             DD      ?
  75 ;------------------------------------------------------------------------------
  76 ; _BackFromUserCode() takes control in real mode after 'retf' has been executed
  77 ; by user code. It will be shadowed to somewhere in memory below 1MB.
  78 ;------------------------------------------------------------------------------
  79 _BackFromUserCode   PROC
  80     ;
  81     ; The order of saved registers on the stack matches the order they appears
  82     ; in IA32_REGS structure. This facilitates wrapper function to extract them
  83     ; into that structure.
  84     ;
  85     push    ss
  86     push    cs
  87     DB      66h
  88     call    @Base                       ; push eip
  89 @Base:
  90     pushf                               ; pushfd actually
  91     cli                                 ; disable interrupts
  92     push    gs
  93     push    fs
  94     push    es
  95     push    ds
  96     pushaw                              ; pushad actually
  97     DB      66h, 0bah                   ; mov edx, imm32
  98 _ThunkAttr  DD      ?
  99     test    dl, THUNK_ATTRIBUTE_DISABLE_A20_MASK_INT_15
 100     jz      @1
 101     mov     eax, 15cd2401h              ; mov ax, 2401h & int 15h
 102     cli                                 ; disable interrupts
 103     jnc     @2
 104 @1:
 105     test    dl, THUNK_ATTRIBUTE_DISABLE_A20_MASK_KBD_CTRL
 106     jz      @2
 107     in      al, 92h
 108     or      al, 2
 109     out     92h, al                     ; deactivate A20M#
 110 @2:
 111     xor     ax, ax                      ; xor eax, eax
 112     mov     eax, ss                     ; mov ax, ss
 113     DB      67h
 114     lea     bp, [esp + sizeof (IA32_REGS)]
 115     ;
 116     ; esi's in the following 2 instructions are indeed bp in 16-bit code. Fact
 117     ; is "esi" in 32-bit addressing mode has the same encoding of "bp" in 16-
 118     ; bit addressing mode.
 119     ;
 120     mov     word ptr (IA32_REGS ptr [esi - sizeof (IA32_REGS)])._ESP, bp
 121     mov     ebx, (IA32_REGS ptr [esi - sizeof (IA32_REGS)])._EIP
 122     shl     ax, 4                       ; shl eax, 4
 123     add     bp, ax                      ; add ebp, eax
 124     DB      66h, 0b8h                   ; mov eax, imm32
 125 SavedCr4    DD      ?
 126     mov     cr4, eax
 127     DB      66h
 128     lgdt    fword ptr cs:[edi + (SavedGdt - @Base)]
 129     DB      66h, 0b8h                   ; mov eax, imm32
 130 SavedCr0    DD      ?
 131     mov     cr0, eax
 132     DB      0b8h                        ; mov ax, imm16
 133 SavedSs     DW      ?
 134     mov     ss, eax
 135     DB      66h, 0bch                   ; mov esp, imm32
 136 SavedEsp    DD      ?
 137     DB      66h
 138     retf                                ; return to protected mode
 139 _BackFromUserCode   ENDP
 140
 141 _EntryPoint DD      _ToUserCode - m16Start
 142             DW      8h
 143 _16Idtr     FWORD   (1 SHL 10) - 1
 144 _16Gdtr     LABEL   FWORD
 145             DW      GdtEnd - _NullSegDesc - 1
 146 _16GdtrBase DD      _NullSegDesc
 147
 148 ;------------------------------------------------------------------------------
 149 ; _ToUserCode() takes control in real mode before passing control to user code.
 150 ; It will be shadowed to somewhere in memory below 1MB.
 151 ;------------------------------------------------------------------------------
 152 _ToUserCode PROC
 153     mov     edx, ss
 154     mov     ss, ecx                     ; set new segment selectors
 155     mov     ds, ecx
 156     mov     es, ecx
 157     mov     fs, ecx
 158     mov     gs, ecx
 159     mov     cr0, eax
 160     mov     cr4, ebp                    ; real mode starts at next instruction
 161     mov     ss, esi                     ; set up 16-bit stack segment
 162     xchg    sp, bx                      ; set up 16-bit stack pointer
 163     DB      66h
 164     call    @Base                       ; push eip
 165 @Base:
 166     pop     bp                          ; ebp <- address of @Base
 167     DB      67h                         ; address size override
 168     push    [esp + sizeof (IA32_REGS) + 2]
 169     lea     eax, [esi + (@RealMode - @Base)]
 170     push    eax
 171     retf
 172 @RealMode:
 173     mov     cs:[esi + (SavedSs - @Base)], edx
 174     mov     cs:[esi + (SavedEsp - @Base)], bx
 175     DB      66h
 176     lidt    fword ptr cs:[esi + (_16Idtr - @Base)]
 177     popaw                               ; popad actually
 178     pop     ds
 179     pop     es
 180     pop     fs
 181     pop     gs
 182     popf                                ; popfd
 183     DB      66h                         ; Use 32-bit addressing for "retf" below
 184     retf                                ; transfer control to user code
 185 _ToUserCode ENDP
 186
 187 _NullSegDesc    DQ      0
 188 _16CsDesc       LABEL   QWORD
 189                 DW      -1
 190                 DW      0
 191                 DB      0
 192                 DB      9bh
 193                 DB      8fh             ; 16-bit segment, 4GB limit
 194                 DB      0
 195 _16DsDesc       LABEL   QWORD
 196                 DW      -1
 197                 DW      0
 198                 DB      0
 199                 DB      93h
 200                 DB      8fh             ; 16-bit segment, 4GB limit
 201                 DB      0
 202 GdtEnd          LABEL   QWORD
 203
 204 ;------------------------------------------------------------------------------
 205 ; IA32_REGISTER_SET *
 206 ; EFIAPI
 207 ; InternalAsmThunk16 (
 208 ;   IN      IA32_REGISTER_SET         *RegisterSet,
 209 ;   IN OUT  VOID                      *Transition
 210 ;   );
 211 ;------------------------------------------------------------------------------
 212 InternalAsmThunk16  PROC    USES    ebp ebx esi edi ds  es  fs  gs
 213     mov     esi, [esp + 36]             ; esi <- RegSet, the 1st parameter
 214     movzx   edx, (IA32_REGS ptr [esi])._SS
 215     mov     edi, (IA32_REGS ptr [esi])._ESP
 216     add     edi, - (sizeof (IA32_REGS) + 4) ; reserve stack space
 217     mov     ebx, edi                    ; ebx <- stack offset
 218     imul    eax, edx, 16                ; eax <- edx * 16
 219     push    sizeof (IA32_REGS) / 4
 220     add     edi, eax                    ; edi <- linear address of 16-bit stack
 221     pop     ecx
 222     rep     movsd                       ; copy RegSet
 223     mov     eax, [esp + 40]             ; eax <- address of transition code
 224     mov     esi, edx                    ; esi <- 16-bit stack segment
 225     lea     edx, [eax + (SavedCr0 - m16Start)]
 226     mov     ecx, eax
 227     and     ecx, 0fh
 228     shl     eax, 12
 229     lea     ecx, [ecx + (_BackFromUserCode - m16Start)]
 230     mov     ax, cx
 231     stosd                               ; [edi] <- return address of user code
 232     sgdt    fword ptr [edx + (SavedGdt - SavedCr0)]
 233     sidt    fword ptr [esp + 36]        ; save IDT stack in argument space
 234     mov     eax, cr0
 235     mov     [edx], eax                  ; save CR0 in SavedCr0
 236     and     eax, 7ffffffeh              ; clear PE, PG bits
 237     mov     ebp, cr4
 238     mov     [edx + (SavedCr4 - SavedCr0)], ebp
 239     and     ebp, 300h                   ; clear all but PCE and OSFXSR bits
 240     push    10h
 241     pop     ecx                         ; ecx <- selector for data segments
 242     lgdt    fword ptr [edx + (_16Gdtr - SavedCr0)]
 243     pushfd                              ; Save df/if indeed
 244     call    fword ptr [edx + (_EntryPoint - SavedCr0)]
 245     popfd
 246     lidt    fword ptr [esp + 36]        ; restore protected mode IDTR
 247     lea     eax, [ebp - sizeof (IA32_REGS)] ; eax <- the address of IA32_REGS
 248     ret
 249 InternalAsmThunk16  ENDP
 250
 251     END