MdePkg/Library/BaseLib/Ia32/SetJump.nasm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006 - 2019, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetJump.Asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   Implementation of SetJump() on IA-32.
  19 ;
  20 ;------------------------------------------------------------------------------
  21
  22 %include "Nasm.inc"
  23
  24     SECTION .text
  25
  26 extern ASM_PFX(InternalAssertJumpBuffer)
  27 extern ASM_PFX(PcdGet32 (PcdControlFlowEnforcementPropertyMask))
  28
  29 ;------------------------------------------------------------------------------
  30 ; UINTN
  31 ; EFIAPI
  32 ; SetJump (
  33 ;   OUT     BASE_LIBRARY_JUMP_BUFFER  *JumpBuffer
  34 ;   );
  35 ;------------------------------------------------------------------------------
  36 global ASM_PFX(SetJump)
  37 ASM_PFX(SetJump):
  38     push    DWORD [esp + 4]
  39     call    ASM_PFX(InternalAssertJumpBuffer)    ; To validate JumpBuffer
  40     pop     ecx
  41     pop     ecx                         ; ecx <- return address
  42     mov     edx, [esp]
  43
  44     xor     eax, eax
  45     mov     [edx + 24], eax        ; save 0 to SSP
  46
  47     mov     eax, [ASM_PFX(PcdGet32 (PcdControlFlowEnforcementPropertyMask))]
  48     test    eax, eax
  49     jz      CetDone
  50     mov     eax, cr4
  51     bt      eax, 23                ; check if CET is enabled
  52     jnc     CetDone
  53
  54     mov     eax, 1
  55     INCSSP_EAX                     ; to read original SSP
  56     READSSP_EAX
  57     mov     [edx + 0x24], eax      ; save SSP
  58
  59 CetDone:
  60
  61     mov     [edx], ebx
  62     mov     [edx + 4], esi
  63     mov     [edx + 8], edi
  64     mov     [edx + 12], ebp
  65     mov     [edx + 16], esp
  66     mov     [edx + 20], ecx             ; eip value to restore in LongJump
  67     xor     eax, eax
  68     jmp     ecx
  69