MdePkg/Library/BaseMemoryLibMmx/X64/CopyMem.nasm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
   4 ; SPDX-License-Identifier: BSD-2-Clause-Patent
   5 ;
   6 ; Module Name:
   7 ;
   8 ;   CopyMem.nasm
   9 ;
  10 ; Abstract:
  11 ;
  12 ;   CopyMem function
  13 ;
  14 ; Notes:
  15 ;
  16 ;------------------------------------------------------------------------------
  17
  18     DEFAULT REL
  19     SECTION .text
  20
  21 ;------------------------------------------------------------------------------
  22 ; VOID *
  23 ; EFIAPI
  24 ; InternalMemCopyMem (
  25 ;   OUT     VOID                      *DestinationBuffer,
  26 ;   IN      CONST VOID                *SourceBuffer,
  27 ;   IN      UINTN                     Length
  28 ;   );
  29 ;------------------------------------------------------------------------------
  30 global ASM_PFX(InternalMemCopyMem)
  31 ASM_PFX(InternalMemCopyMem):
  32     push    rsi
  33     push    rdi
  34     mov     rsi, rdx                    ; rsi <- Source
  35     mov     rdi, rcx                    ; rdi <- Destination
  36     lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source
  37     cmp     rsi, rdi
  38     mov     rax, rdi                    ; rax <- Destination as return value
  39     jae     .0
  40     cmp     r9, rdi
  41     jae     @CopyBackward               ; Copy backward if overlapped
  42 .0:
  43     mov     rcx, r8
  44     and     r8, 7
  45     shr     rcx, 3                      ; rcx <- # of Qwords to copy
  46     jz      @CopyBytes
  47     DB      0x49, 0xf, 0x7e, 0xc2         ; movd r10, mm0 (Save mm0 in r10)
  48 .1:
  49     DB      0xf, 0x6f, 0x6               ; movd mm0, [rsi]
  50     DB      0xf, 0xe7, 0x7              ; movntq [rdi], mm0
  51     add     rsi, 8
  52     add     rdi, 8
  53     loop    .1
  54     mfence
  55     DB      0x49, 0xf, 0x6e, 0xc2         ; movd mm0, r10 (Restore mm0)
  56     jmp     @CopyBytes
  57 @CopyBackward:
  58     mov     rsi, r9                     ; rsi <- End of Source
  59     lea     rdi, [rdi + r8 - 1]         ; rdi <- End of Destination
  60     std                                 ; set direction flag
  61 @CopyBytes:
  62     mov     rcx, r8
  63     rep     movsb                       ; Copy bytes backward
  64     cld
  65     pop     rdi
  66     pop     rsi
  67     ret
  68