MdePkg/Library/BaseMemoryLibMmx/X64/CopyMem.nasm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.nasm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   CopyMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     DEFAULT REL
  25     SECTION .text
  26
  27 ;------------------------------------------------------------------------------
  28 ; VOID *
  29 ; EFIAPI
  30 ; InternalMemCopyMem (
  31 ;   OUT     VOID                      *DestinationBuffer,
  32 ;   IN      CONST VOID                *SourceBuffer,
  33 ;   IN      UINTN                     Length
  34 ;   );
  35 ;------------------------------------------------------------------------------
  36 global ASM_PFX(InternalMemCopyMem)
  37 ASM_PFX(InternalMemCopyMem):
  38     push    rsi
  39     push    rdi
  40     mov     rsi, rdx                    ; rsi <- Source
  41     mov     rdi, rcx                    ; rdi <- Destination
  42     lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source
  43     cmp     rsi, rdi
  44     mov     rax, rdi                    ; rax <- Destination as return value
  45     jae     .0
  46     cmp     r9, rdi
  47     jae     @CopyBackward               ; Copy backward if overlapped
  48 .0:
  49     mov     rcx, r8
  50     and     r8, 7
  51     shr     rcx, 3                      ; rcx <- # of Qwords to copy
  52     jz      @CopyBytes
  53     DB      0x49, 0xf, 0x7e, 0xc2         ; movd r10, mm0 (Save mm0 in r10)
  54 .1:
  55     DB      0xf, 0x6f, 0x6               ; movd mm0, [rsi]
  56     DB      0xf, 0xe7, 0x7              ; movntq [rdi], mm0
  57     add     rsi, 8
  58     add     rdi, 8
  59     loop    .1
  60     mfence
  61     DB      0x49, 0xf, 0x6e, 0xc2         ; movd mm0, r10 (Restore mm0)
  62     jmp     @CopyBytes
  63 @CopyBackward:
  64     mov     rsi, r9                     ; rsi <- End of Source
  65     lea     rdi, [rdi + r8 - 1]         ; rdi <- End of Destination
  66     std                                 ; set direction flag
  67 @CopyBytes:
  68     mov     rcx, r8
  69     rep     movsb                       ; Copy bytes backward
  70     cld
  71     pop     rdi
  72     pop     rsi
  73     ret
  74