MdePkg/Library/BaseMemoryLibOptDxe/X64/SetMem.nasm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem.Asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   SetMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     DEFAULT REL
  25     SECTION .text
  26
  27 ;------------------------------------------------------------------------------
  28 ;  VOID *
  29 ;  EFIAPI
  30 ;  InternalMemSetMem (
  31 ;    IN VOID   *Buffer,
  32 ;    IN UINTN  Count,
  33 ;    IN UINT8  Value
  34 ;    )
  35 ;------------------------------------------------------------------------------
  36 global ASM_PFX(InternalMemSetMem)
  37 ASM_PFX(InternalMemSetMem):
  38     push    rdi
  39     push    rbx
  40     push    rcx       ; push Buffer
  41     mov     rax, r8   ; rax = Value
  42     and     rax, 0xff ; rax = lower 8 bits of r8, upper 56 bits are 0
  43     mov     ah,  al   ; ah  = al
  44     mov     bx,  ax   ; bx  = ax
  45     shl     rax, 0x10  ; rax = ax << 16
  46     mov     ax,  bx   ; ax  = bx
  47     mov     rbx, rax  ; ebx = eax
  48     shl     rax, 0x20  ; rax = rax << 32
  49     or      rax, rbx  ; eax = ebx
  50     mov     rdi, rcx  ; rdi = Buffer
  51     mov     rcx, rdx  ; rcx = Count
  52     shr     rcx, 3    ; rcx = rcx / 8
  53     cld
  54     rep     stosq
  55     mov     rcx, rdx  ; rcx = rdx
  56     and     rcx, 7    ; rcx = rcx & 7
  57     rep     stosb
  58     pop     rax       ; rax = Buffer
  59     pop     rbx
  60     pop     rdi
  61     ret
  62