MdePkg/Library/BaseMemoryLibRepStr/X64/CopyMem.nasm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.Asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   CopyMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     DEFAULT REL
  25     SECTION .text
  26
  27 ;------------------------------------------------------------------------------
  28 ;  VOID *
  29 ;  EFIAPI
  30 ;  InternalMemCopyMem (
  31 ;    IN VOID   *Destination,
  32 ;    IN VOID   *Source,
  33 ;    IN UINTN  Count
  34 ;    )
  35 ;------------------------------------------------------------------------------
  36 global ASM_PFX(InternalMemCopyMem)
  37 ASM_PFX(InternalMemCopyMem):
  38     push    rsi
  39     push    rdi
  40     mov     rsi, rdx                    ; rsi <- Source
  41     mov     rdi, rcx                    ; rdi <- Destination
  42     lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source
  43     cmp     rsi, rdi
  44     mov     rax, rdi                    ; rax <- Destination as return value
  45     jae     .0
  46     cmp     r9, rdi
  47     jae     @CopyBackward               ; Copy backward if overlapped
  48 .0:
  49     mov     rcx, r8
  50     and     r8, 7
  51     shr     rcx, 3
  52     rep     movsq                       ; Copy as many Qwords as possible
  53     jmp     @CopyBytes
  54 @CopyBackward:
  55     mov     rsi, r9                     ; rsi <- End of Source
  56     lea     rdi, [rdi + r8 - 1]         ; esi <- End of Destination
  57     std                                 ; set direction flag
  58 @CopyBytes:
  59     mov     rcx, r8
  60     rep     movsb                       ; Copy bytes backward
  61     cld
  62     pop     rdi
  63     pop     rsi
  64     ret
  65