MdePkg/Library/BaseMemoryLibRepStr/x64/CopyMem.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.Asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   CopyMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 InternalMemCopyMem  PROC    USES    rsi rdi
  27     mov     rsi, rdx                    ; rsi <- Source
  28     mov     rdi, rcx                    ; rdi <- Destination
  29     lea     r9, [rdi + r8 - 1]          ; r9 <- End of Destination
  30     cmp     rsi, rdi
  31     mov     rax, rdi                    ; rax <- Destination as return value
  32     jae     @F
  33     cmp     r9, rsi
  34     jae     @CopyBackward               ; Copy backward if overlapped
  35 @@:
  36     mov     rcx, r8
  37     and     r8, 7
  38     shr     rcx, 3
  39     rep     movsq                       ; Copy as many Qwords as possible
  40     jmp     @CopyBytes
  41 @CopyBackward:
  42     mov     rdi, r9                     ; rdi <- End of Destination
  43     lea     rsi, [rsi + r8 - 1]         ; esi <- End of Source
  44     std                                 ; set direction flag
  45 @CopyBytes:
  46     mov     rcx, r8
  47     rep     movsb                       ; Copy bytes backward
  48     cld
  49     ret
  50 InternalMemCopyMem  ENDP
  51
  52     END