MdePkg/Library/BaseMemoryLibSse2/ia32/ZeroMem.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   ZeroMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   ZeroMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .686
  25     .model  flat,C
  26     .xmm
  27     .code
  28
  29 ;------------------------------------------------------------------------------
  30 ;  VOID *
  31 ;  _mem_ZeroMem (
  32 ;    IN VOID   *Buffer,
  33 ;    IN UINTN  Count
  34 ;    )
  35 ;------------------------------------------------------------------------------
  36 InternalMemZeroMem  PROC    USES    edi
  37     mov     edi, [esp + 8]
  38     mov     edx, [esp + 12]
  39     xor     ecx, ecx
  40     sub     ecx, edi
  41     xor     eax, eax
  42     and     ecx, 15
  43     jz      @F
  44     cmp     ecx, edx
  45     cmova   ecx, edx
  46     sub     edx, ecx
  47     rep     stosb
  48 @@:
  49     mov     ecx, edx
  50     and     edx, 15
  51     shr     ecx, 4
  52     jz      @ZeroBytes
  53     pxor    xmm0, xmm0
  54 @@:
  55     movntdq [edi], xmm0
  56     add     edi, 16
  57     loop    @B
  58     mfence
  59 @ZeroBytes:
  60     mov     ecx, edx
  61     rep     stosb
  62     mov     eax, [esp + 8]
  63     ret
  64 InternalMemZeroMem  ENDP
  65
  66     END