OvmfPkg/ResetVector/Ia32/PageTables64.asm

   1 ;------------------------------------------------------------------------------
   2 ; @file
   3 ; Sets the CR3 register for 64-bit paging
   4 ;
   5 ; Copyright (c) 2008 - 2013, Intel Corporation. All rights reserved.<BR>
   6 ; Copyright (c) 2017 - 2020, Advanced Micro Devices, Inc. All rights reserved.<BR>
   7 ; SPDX-License-Identifier: BSD-2-Clause-Patent
   8 ;
   9 ;------------------------------------------------------------------------------
  10
  11 BITS    32
  12
  13 %define PAGE_PRESENT            0x01
  14 %define PAGE_READ_WRITE         0x02
  15 %define PAGE_USER_SUPERVISOR    0x04
  16 %define PAGE_WRITE_THROUGH      0x08
  17 %define PAGE_CACHE_DISABLE     0x010
  18 %define PAGE_ACCESSED          0x020
  19 %define PAGE_DIRTY             0x040
  20 %define PAGE_PAT               0x080
  21 %define PAGE_GLOBAL           0x0100
  22 %define PAGE_2M_MBO            0x080
  23 %define PAGE_2M_PAT          0x01000
  24
  25 %define PAGE_4K_PDE_ATTR (PAGE_ACCESSED + \
  26                           PAGE_DIRTY + \
  27                           PAGE_READ_WRITE + \
  28                           PAGE_PRESENT)
  29
  30 %define PAGE_2M_PDE_ATTR (PAGE_2M_MBO + \
  31                           PAGE_ACCESSED + \
  32                           PAGE_DIRTY + \
  33                           PAGE_READ_WRITE + \
  34                           PAGE_PRESENT)
  35
  36 %define PAGE_PDP_ATTR (PAGE_ACCESSED + \
  37                        PAGE_READ_WRITE + \
  38                        PAGE_PRESENT)
  39
  40 ;
  41 ; Modified:  EAX, EBX, ECX, EDX
  42 ;
  43 SetCr3ForPageTables64:
  44
  45     ; Clear the WorkArea header. The SEV probe routines will populate the
  46     ; work area when detected.
  47     mov     byte[WORK_AREA_GUEST_TYPE], 0
  48
  49     ; Check whether the SEV is active and populate the SevEsWorkArea
  50     OneTimeCall   CheckSevFeatures
  51
  52     ; If SEV is enabled, the C-bit position is always above 31.
  53     ; The mask will be saved in the EDX and applied during the
  54     ; the page table build below.
  55     OneTimeCall   GetSevCBitMaskAbove31
  56
  57     ;
  58     ; For OVMF, build some initial page tables at
  59     ; PcdOvmfSecPageTablesBase - (PcdOvmfSecPageTablesBase + 0x6000).
  60     ;
  61     ; This range should match with PcdOvmfSecPageTablesSize which is
  62     ; declared in the FDF files.
  63     ;
  64     ; At the end of PEI, the pages tables will be rebuilt into a
  65     ; more permanent location by DxeIpl.
  66     ;
  67
  68     mov     ecx, 6 * 0x1000 / 4
  69     xor     eax, eax
  70 clearPageTablesMemoryLoop:
  71     mov     dword[ecx * 4 + PT_ADDR (0) - 4], eax
  72     loop    clearPageTablesMemoryLoop
  73
  74     ;
  75     ; Top level Page Directory Pointers (1 * 512GB entry)
  76     ;
  77     mov     dword[PT_ADDR (0)], PT_ADDR (0x1000) + PAGE_PDP_ATTR
  78     mov     dword[PT_ADDR (4)], edx
  79
  80     ;
  81     ; Next level Page Directory Pointers (4 * 1GB entries => 4GB)
  82     ;
  83     mov     dword[PT_ADDR (0x1000)], PT_ADDR (0x2000) + PAGE_PDP_ATTR
  84     mov     dword[PT_ADDR (0x1004)], edx
  85     mov     dword[PT_ADDR (0x1008)], PT_ADDR (0x3000) + PAGE_PDP_ATTR
  86     mov     dword[PT_ADDR (0x100C)], edx
  87     mov     dword[PT_ADDR (0x1010)], PT_ADDR (0x4000) + PAGE_PDP_ATTR
  88     mov     dword[PT_ADDR (0x1014)], edx
  89     mov     dword[PT_ADDR (0x1018)], PT_ADDR (0x5000) + PAGE_PDP_ATTR
  90     mov     dword[PT_ADDR (0x101C)], edx
  91
  92     ;
  93     ; Page Table Entries (2048 * 2MB entries => 4GB)
  94     ;
  95     mov     ecx, 0x800
  96 pageTableEntriesLoop:
  97     mov     eax, ecx
  98     dec     eax
  99     shl     eax, 21
 100     add     eax, PAGE_2M_PDE_ATTR
 101     mov     [ecx * 8 + PT_ADDR (0x2000 - 8)], eax
 102     mov     [(ecx * 8 + PT_ADDR (0x2000 - 8)) + 4], edx
 103     loop    pageTableEntriesLoop
 104
 105     ; Clear the C-bit from the GHCB page if the SEV-ES is enabled.
 106     OneTimeCall   SevClearPageEncMaskForGhcbPage
 107
 108 SetCr3:
 109     ;
 110     ; Set CR3 now that the paging structures are available
 111     ;
 112     mov     eax, PT_ADDR (0)
 113     mov     cr3, eax
 114
 115     OneTimeCallRet SetCr3ForPageTables64