OvmfPkg/ResetVector/Ia32/PageTables64.asm

   1 ;------------------------------------------------------------------------------
   2 ; @file
   3 ; Sets the CR3 register for 64-bit paging
   4 ;
   5 ; Copyright (c) 2008 - 2013, Intel Corporation. All rights reserved.<BR>
   6 ; This program and the accompanying materials
   7 ; are licensed and made available under the terms and conditions of the BSD License
   8 ; which accompanies this distribution.  The full text of the license may be found at
   9 ; http://opensource.org/licenses/bsd-license.php
  10 ;
  11 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  12 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  13 ;
  14 ;------------------------------------------------------------------------------
  15
  16 BITS    32
  17
  18 %define PAGE_PRESENT            0x01
  19 %define PAGE_READ_WRITE         0x02
  20 %define PAGE_USER_SUPERVISOR    0x04
  21 %define PAGE_WRITE_THROUGH      0x08
  22 %define PAGE_CACHE_DISABLE     0x010
  23 %define PAGE_ACCESSED          0x020
  24 %define PAGE_DIRTY             0x040
  25 %define PAGE_PAT               0x080
  26 %define PAGE_GLOBAL           0x0100
  27 %define PAGE_2M_MBO            0x080
  28 %define PAGE_2M_PAT          0x01000
  29
  30 %define PAGE_2M_PDE_ATTR (PAGE_2M_MBO + \
  31                           PAGE_ACCESSED + \
  32                           PAGE_DIRTY + \
  33                           PAGE_READ_WRITE + \
  34                           PAGE_PRESENT)
  35
  36 %define PAGE_PDP_ATTR (PAGE_ACCESSED + \
  37                        PAGE_READ_WRITE + \
  38                        PAGE_PRESENT)
  39
  40
  41 ;
  42 ; Modified:  EAX, ECX
  43 ;
  44 SetCr3ForPageTables64:
  45
  46     ;
  47     ; For OVMF, build some initial page tables at 0x800000-0x806000.
  48     ;
  49     ; This range should match with PcdOvmfSecPageTablesBase and
  50     ; PcdOvmfSecPageTablesSize which are declared in the FDF files.
  51     ;
  52     ; At the end of PEI, the pages tables will be rebuilt into a
  53     ; more permanent location by DxeIpl.
  54     ;
  55
  56     mov     ecx, 6 * 0x1000 / 4
  57     xor     eax, eax
  58 clearPageTablesMemoryLoop:
  59     mov     dword[ecx * 4 + 0x800000 - 4], eax
  60     loop    clearPageTablesMemoryLoop
  61
  62     ;
  63     ; Top level Page Directory Pointers (1 * 512GB entry)
  64     ;
  65     mov     dword[0x800000], 0x801000 + PAGE_PDP_ATTR
  66
  67     ;
  68     ; Next level Page Directory Pointers (4 * 1GB entries => 4GB)
  69     ;
  70     mov     dword[0x801000], 0x802000 + PAGE_PDP_ATTR
  71     mov     dword[0x801008], 0x803000 + PAGE_PDP_ATTR
  72     mov     dword[0x801010], 0x804000 + PAGE_PDP_ATTR
  73     mov     dword[0x801018], 0x805000 + PAGE_PDP_ATTR
  74
  75     ;
  76     ; Page Table Entries (2048 * 2MB entries => 4GB)
  77     ;
  78     mov     ecx, 0x800
  79 pageTableEntriesLoop:
  80     mov     eax, ecx
  81     dec     eax
  82     shl     eax, 21
  83     add     eax, PAGE_2M_PDE_ATTR
  84     mov     [ecx * 8 + 0x802000 - 8], eax
  85     loop    pageTableEntriesLoop
  86
  87     ;
  88     ; Set CR3 now that the paging structures are available
  89     ;
  90     mov     eax, 0x800000
  91     mov     cr3, eax
  92
  93     OneTimeCallRet SetCr3ForPageTables64