SecurityPkg/Tcg/Tcg2Smm/Tpm.asl

   1 /** @file
   2   The TPM2 definition block in ACPI table for TCG2 physical presence
   3   and MemoryClear.
   4
   5 Copyright (c) 2015 - 2016, Intel Corporation. All rights reserved.<BR>
   6 (c)Copyright 2016 HP Development Company, L.P.<BR>
   7 This program and the accompanying materials
   8 are licensed and made available under the terms and conditions of the BSD License
   9 which accompanies this distribution.  The full text of the license may be found at
  10 http://opensource.org/licenses/bsd-license.php
  11
  12 THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  13 WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  14
  15 **/
  16
  17 DefinitionBlock (
  18   "Tpm.aml",
  19   "SSDT",
  20   2,
  21   "INTEL ",
  22   "Tpm2Tabl",
  23   0x1000
  24   )
  25 {
  26   Scope (\_SB)
  27   {
  28     Device (TPM)
  29     {
  30       //
  31       // TCG2
  32       //
  33       Name (_HID, "MSFT0101")
  34
  35       //
  36       // Readable name of this device, don't know if this way is correct yet
  37       //
  38       Name (_STR, Unicode ("TPM 2.0 Device"))
  39
  40       //
  41       // Return the resource consumed by TPM device
  42       //
  43       Name (_CRS, ResourceTemplate () {
  44         Memory32Fixed (ReadWrite, 0xfed40000, 0x5000)
  45       })
  46
  47       //
  48       // Operational region for Smi port access
  49       //
  50       OperationRegion (SMIP, SystemIO, 0xB2, 1)
  51       Field (SMIP, ByteAcc, NoLock, Preserve)
  52       {
  53           IOB2, 8
  54       }
  55
  56       //
  57       // Operational region for TPM access
  58       //
  59       OperationRegion (TPMR, SystemMemory, 0xfed40000, 0x5000)
  60       Field (TPMR, AnyAcc, NoLock, Preserve)
  61       {
  62         ACC0, 8,
  63       }
  64
  65       //
  66       // Operational region for TPM support, TPM Physical Presence and TPM Memory Clear
  67       // Region Offset 0xFFFF0000 and Length 0xF0 will be fixed in C code.
  68       //
  69       OperationRegion (TNVS, SystemMemory, 0xFFFF0000, 0xF0)
  70       Field (TNVS, AnyAcc, NoLock, Preserve)
  71       {
  72         PPIN,   8,  //   Software SMI for Physical Presence Interface
  73         PPIP,   32, //   Used for save physical presence paramter
  74         PPRP,   32, //   Physical Presence request operation response
  75         PPRQ,   32, //   Physical Presence request operation
  76         PPRM,   32, //   Physical Presence request operation parameter
  77         LPPR,   32, //   Last Physical Presence request operation
  78         FRET,   32, //   Physical Presence function return code
  79         MCIN,   8,  //   Software SMI for Memory Clear Interface
  80         MCIP,   32, //   Used for save the Mor paramter
  81         MORD,   32, //   Memory Overwrite Request Data
  82         MRET,   32, //   Memory Overwrite function return code
  83         UCRQ,   32  //   Phyical Presence request operation to Get User Confirmation Status
  84       }
  85
  86       Method (PTS, 1, Serialized)
  87       {
  88         //
  89         // Detect Sx state for MOR, only S4, S5 need to handle
  90         //
  91         If (LAnd (LLess (Arg0, 6), LGreater (Arg0, 3)))
  92         {
  93           //
  94           // Bit4 -- DisableAutoDetect. 0 -- Firmware MAY autodetect.
  95           //
  96           If (LNot (And (MORD, 0x10)))
  97           {
  98             //
  99             // Triggle the SMI through ACPI _PTS method.
 100             //
 101             Store (0x02, MCIP)
 102
 103             //
 104             // Triggle the SMI interrupt
 105             //
 106             Store (MCIN, IOB2)
 107           }
 108         }
 109         Return (0)
 110       }
 111
 112       Method (_STA, 0)
 113       {
 114         if (LEqual (ACC0, 0xff))
 115         {
 116             Return (0)
 117         }
 118         Return (0x0f)
 119       }
 120
 121       //
 122       // TCG Hardware Information
 123       //
 124       Method (HINF, 3, Serialized, 0, {BuffObj, PkgObj}, {UnknownObj, UnknownObj, UnknownObj}) // IntObj, IntObj, PkgObj
 125       {
 126         //
 127         // Switch by function index
 128         //
 129         Switch (ToInteger(Arg1))
 130         {
 131           Case (0)
 132           {
 133             //
 134             // Standard query
 135             //
 136             Return (Buffer () {0x03})
 137           }
 138           Case (1)
 139           {
 140             //
 141             // Return failure if no TPM present
 142             //
 143             Name(TPMV, Package () {0x01, Package () {0x2, 0x0}})
 144             if (LEqual (_STA (), 0x00))
 145             {
 146               Return (Package () {0x00})
 147             }
 148
 149             //
 150             // Return TPM version
 151             //
 152             Return (TPMV)
 153           }
 154           Default {BreakPoint}
 155         }
 156         Return (Buffer () {0})
 157       }
 158
 159       Name(TPM2, Package (0x02){
 160         Zero,
 161         Zero
 162       })
 163
 164       Name(TPM3, Package (0x03){
 165         Zero,
 166         Zero,
 167         Zero
 168       })
 169
 170       //
 171       // TCG Physical Presence Interface
 172       //
 173       Method (TPPI, 3, Serialized, 0, {BuffObj, PkgObj, IntObj, StrObj}, {UnknownObj, UnknownObj, UnknownObj}) // IntObj, IntObj, PkgObj
 174       {
 175         //
 176         // Switch by function index
 177         //
 178         Switch (ToInteger(Arg1))
 179         {
 180           Case (0)
 181           {
 182             //
 183             // Standard query, supports function 1-8
 184             //
 185             Return (Buffer () {0xFF, 0x01})
 186           }
 187           Case (1)
 188           {
 189             //
 190             // a) Get Physical Presence Interface Version
 191             //
 192             Return ("$PV")
 193           }
 194           Case (2)
 195           {
 196             //
 197             // b) Submit TPM Operation Request to Pre-OS Environment
 198             //
 199
 200             Store (DerefOf (Index (Arg2, 0x00)), PPRQ)
 201             Store (0, PPRM)
 202             Store (0x02, PPIP)
 203
 204             //
 205             // Triggle the SMI interrupt
 206             //
 207             Store (PPIN, IOB2)
 208             Return (FRET)
 209
 210
 211           }
 212           Case (3)
 213           {
 214             //
 215             // c) Get Pending TPM Operation Requested By the OS
 216             //
 217
 218             Store (PPRQ, Index (TPM2, 0x01))
 219             Return (TPM2)
 220           }
 221           Case (4)
 222           {
 223             //
 224             // d) Get Platform-Specific Action to Transition to Pre-OS Environment
 225             //
 226             Return (2)
 227           }
 228           Case (5)
 229           {
 230             //
 231             // e) Return TPM Operation Response to OS Environment
 232             //
 233             Store (0x05, PPIP)
 234
 235             //
 236             // Triggle the SMI interrupt
 237             //
 238             Store (PPIN, IOB2)
 239
 240             Store (LPPR, Index (TPM3, 0x01))
 241             Store (PPRP, Index (TPM3, 0x02))
 242
 243             Return (TPM3)
 244           }
 245           Case (6)
 246           {
 247
 248             //
 249             // f) Submit preferred user language (Not implemented)
 250             //
 251
 252             Return (3)
 253
 254           }
 255           Case (7)
 256           {
 257             //
 258             // g) Submit TPM Operation Request to Pre-OS Environment 2
 259             //
 260             Store (7, PPIP)
 261             Store (DerefOf (Index (Arg2, 0x00)), PPRQ)
 262             Store (0, PPRM)
 263             If (LEqual (PPRQ, 23)) {
 264               Store (DerefOf (Index (Arg2, 0x01)), PPRM)
 265             }
 266
 267             //
 268             // Triggle the SMI interrupt
 269             //
 270             Store (PPIN, IOB2)
 271             Return (FRET)
 272           }
 273           Case (8)
 274           {
 275             //
 276             // e) Get User Confirmation Status for Operation
 277             //
 278             Store (8, PPIP)
 279             Store (DerefOf (Index (Arg2, 0x00)), UCRQ)
 280
 281             //
 282             // Triggle the SMI interrupt
 283             //
 284             Store (PPIN, IOB2)
 285
 286             Return (FRET)
 287           }
 288
 289           Default {BreakPoint}
 290         }
 291         Return (1)
 292       }
 293
 294       Method (TMCI, 3, Serialized, 0, IntObj, {UnknownObj, UnknownObj, UnknownObj}) // IntObj, IntObj, PkgObj
 295       {
 296         //
 297         // Switch by function index
 298         //
 299         Switch (ToInteger (Arg1))
 300         {
 301           Case (0)
 302           {
 303             //
 304             // Standard query, supports function 1-1
 305             //
 306             Return (Buffer () {0x03})
 307           }
 308           Case (1)
 309           {
 310             //
 311             // Save the Operation Value of the Request to MORD (reserved memory)
 312             //
 313             Store (DerefOf (Index (Arg2, 0x00)), MORD)
 314
 315             //
 316             // Triggle the SMI through ACPI _DSM method.
 317             //
 318             Store (0x01, MCIP)
 319
 320             //
 321             // Triggle the SMI interrupt
 322             //
 323             Store (MCIN, IOB2)
 324             Return (MRET)
 325           }
 326           Default {BreakPoint}
 327         }
 328         Return (1)
 329       }
 330
 331       Method (_DSM, 4, Serialized, 0, UnknownObj, {BuffObj, IntObj, IntObj, PkgObj})
 332       {
 333
 334         //
 335         // TCG Hardware Information
 336         //
 337         If(LEqual(Arg0, ToUUID ("cf8e16a5-c1e8-4e25-b712-4f54a96702c8")))
 338         {
 339           Return (HINF (Arg1, Arg2, Arg3))
 340         }
 341
 342         //
 343         // TCG Physical Presence Interface
 344         //
 345         If(LEqual(Arg0, ToUUID ("3dddfaa6-361b-4eb4-a424-8d10089d1653")))
 346         {
 347           Return (TPPI (Arg1, Arg2, Arg3))
 348         }
 349
 350         //
 351         // TCG Memory Clear Interface
 352         //
 353         If(LEqual(Arg0, ToUUID ("376054ed-cc13-4675-901c-4756d7f2d45d")))
 354         {
 355           Return (TMCI (Arg1, Arg2, Arg3))
 356         }
 357
 358         Return (Buffer () {0})
 359       }
 360     }
 361   }
 362 }