Update the copyright notice format
[mirror_edk2.git] / UefiCpuPkg / ResetVector / Vtf0 / Ia32 / 32FlatTo64Flat.asm
1 ;------------------------------------------------------------------------------
2 ; @file
3 ; Transition from 32 bit flat protected mode into 64 bit flat protected mode
4 ;
5 ; Copyright (c) 2008 - 2009, Intel Corporation. All rights reserved.<BR>
6 ; This program and the accompanying materials
7 ; are licensed and made available under the terms and conditions of the BSD License
8 ; which accompanies this distribution. The full text of the license may be found at
9 ; http://opensource.org/licenses/bsd-license.php
10 ;
11 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
12 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
13 ;
14 ;------------------------------------------------------------------------------
15
16 BITS 32
17
18 ;
19 ; Modified: EAX
20 ;
21 Transition32FlatTo64Flat:
22
23 mov eax, ((ADDR_OF_START_OF_RESET_CODE & ~0xfff) - 0x1000)
24 mov cr3, eax
25
26 mov eax, cr4
27 bts eax, 5 ; enable PAE
28 mov cr4, eax
29
30 mov ecx, 0xc0000080
31 rdmsr
32 bts eax, 8 ; set LME
33 wrmsr
34
35 mov eax, cr0
36 bts eax, 31 ; set PG
37 mov cr0, eax ; enable paging
38
39 jmp LINEAR_CODE64_SEL:ADDR_OF(jumpTo64BitAndLandHere)
40 BITS 64
41 jumpTo64BitAndLandHere:
42
43 debugShowPostCode POSTCODE_64BIT_MODE
44
45 OneTimeCallRet Transition32FlatTo64Flat
46